q4defoc2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4defoc2   ../engine/source/elements/solid_2d/quad4/q4defoc2.F
!||--- called by ------------------------------------------------------
!||    q4forc2    ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||====================================================================
      SUBROUTINE q4defoc2(
     1   VY1,     VY2,     VY3,     VY4,
     2   VZ1,     VZ2,     VZ3,     VZ4,
     3   PYC1,    PYC2,    PZC1,    PZC2,
     4   AIRE,    EYZ,     EXX,     DSV,
     5   ICP,     NEL,     JCVT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JCVT
C     REAL
      my_real
     .    VY1(*),VY2(*),VY3(*),VY4(*),
     .    vz1(*),vz2(*),vz3(*),vz4(*),
     .    pyc1(*),pyc2(*),pzc1(*),pzc2(*),aire(*),
     .    eyz(*),exx(*),dsv(*)
      INTEGER ICP
C-----------------------------------------------
c FUNCTION: 
c ARGUMENTS:  (I: input, O: output, IO: input & output, W: workspace)
c TYPE NAME                FUNCTION
c  I   VY1(*)~VZ4(*)      - NODAL VELOCITIES
c  I   PYC1(*)~PZC2(*)    - SHAPE DERIVATIVES AT CENTER
c  I   AY(*)              - Ni/r AT CENTER
c  I   AIRE(*)            - ELEMENT AREA
c  O   EYZ(*)             - RATE OF SHEAR STRAIN AT CENTER
c  O   EXX(*)             - RATE OF X- NORMAL STRAIN AT CENTER
c  O   DSV(*)             - VOLUME STRAIN RATE AT CENTER
c  I   ICP                - FLAG FOR CONSTANT PRESURE
c  I   R22(*)~R33(*)      - TRANSFORMATION MATRIX
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .    VY13(MVSIZ),VY24(MVSIZ),VZ13(MVSIZ),VZ24(MVSIZ),
     .    DYZ(MVSIZ),DZY(MVSIZ),DYY(MVSIZ),DZZ(MVSIZ),
     .    VY,VZ
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      DO i=1,nel
        vy13(i) = vy1(i)-vy3(i)
        vy24(i) = vy2(i)-vy4(i)
        vz13(i) = vz1(i)-vz3(i)
        vz24(i) = vz2(i)-vz4(i)
      ENDDO
C
C     SHEAR STRAIN RATE AND INTRINSIC ROTATION
      DO i=1,nel
        IF(aire(i)>zero) THEN
          dzy(i) = pyc1(i)*vz13(i)+pyc2(i)*vz24(i)
          dyz(i) = pzc1(i)*vy13(i)+pzc2(i)*vy24(i)
          dyy(i) = pyc1(i)*vy13(i)+pyc2(i)*vy24(i)
          dzz(i) = pzc1(i)*vz13(i)+pzc2(i)*vz24(i)
        ELSE
          dzy(i) = zero
          dyz(i) = zero
          dyy(i) = zero
          dzz(i) = zero
        ENDIF
      ENDDO
      IF(jcvt==0) THEN
        DO i=1,nel
c          WXX(I) = HALF*DT1*(DZY(I)-DYZ(I))
          eyz(i) = dzy(i)+dyz(i)
        ENDDO
      ELSE
        DO i=1,nel
c          WXX(I) = ZERO
          eyz(i) = dzy(i)+dyz(i)-dt1*(dyy(i)*dyz(i)+dzy(i)*dzz(i))
        ENDDO
      ENDIF
C
C     X- NORMAL STRAIN RATE
      IF(n2d/=1) THEN
        DO i=1,nel
          exx(i) = zero
        ENDDO
      ENDIF
C
C     VOLUMETRIC STRAIN RATE
      IF(icp>0) THEN
        DO i=1,nel
          dsv(i) = dyy(i)+dzz(i)+exx(i)
        ENDDO
      ENDIF
C
      RETURN
      END