q4vis2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4vis2    ../engine/source/elements/solid_2d/quad4/q4vis2.F
!||--- called by ------------------------------------------------------
!||    q4forc2   ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||====================================================================
      SUBROUTINE q4vis2(
     1   PM,      OFF,     RHO,     Y1,
     2   Y2,      Y3,      Y4,      Z1,
     3   Z2,      Z3,      Z4,      VY1,
     4   VY2,     VY3,     VY4,     VZ1,
     5   VZ2,     VZ3,     VZ4,     PY1,
     6   PY2,     PZ1,     PZ2,     T11,
     7   T12,     T13,     T14,     T21,
     8   T22,     T23,     T24,     AREA,
     9   CXX,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      my_real
     .   PM(NPROPM,*),OFF(*), RHO(*),
     .   Y1(*),Y2(*),Y3(*),Y4(*),Z1(*),Z2(*),Z3(*),Z4(*),
     .   VY1(*), VY2(*), VY3(*), VY4(*), VZ1(*), VZ2(*), VZ3(*),
     .   PY1(*), PY2(*), PZ1(*), PZ2(*),
     .   T11(*), T12(*), T13(*), T14(*), T21(*), T22(*), T23(*), T24(*),
     .   VZ4(*), AREA(*), CXX(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I
      my_real
     .   CAQ(MVSIZ),FCL(MVSIZ) , 
     .   G11(MVSIZ) , G21(MVSIZ) , G31(MVSIZ) , G41(MVSIZ),
     .   HGY(MVSIZ), HGZ(MVSIZ), 
     .   HY,HZ,FAC,PX1H1,PX2H1, ARE
C-----------------------------------------------
C 
c      will use CAQ if necessary CAQ=0.001 (Quad BELYTSCHKO CAQ=0.1)
C
      DO i=1,nel
       fac = em03*off(i)
       are = max(area(i),em20)
       fcl(i)=half*fac*rho(i)*sqrt(are)*cxx(i)
      END DO 
C
C
C HOURGLASS BELYTSCHKO
C
        DO i=1,nel
         hy=y1(i)-y2(i)+y3(i)-y4(i)
         hz=z1(i)-z2(i)+z3(i)-z4(i)
         fac=one/max(em20,area(i))
         px1h1=fac*(py1(i)*hy+pz1(i)*hz)
         px2h1=fac*(py2(i)*hy+pz2(i)*hz)
         g11(i)= one -px1h1
         g21(i)=-one -px2h1
         g31(i)= one +px1h1
         g41(i)=-one +px2h1 
        END DO 
        DO i=1,nel
         hgy(i)=fcl(i)*(
     &    g11(i)*vy1(i)+g21(i)*vy2(i)+g31(i)*vy3(i)+g41(i)*vy4(i))
         hgz(i)=fcl(i)*(
     &    g11(i)*vz1(i)+g21(i)*vz2(i)+g31(i)*vz3(i)+g41(i)*vz4(i))
        END DO 
        DO i=1,nel
         t11(i) =t11(i) - g11(i)*hgy(i)
         t12(i) =t12(i) - g21(i)*hgy(i)
         t13(i) =t13(i) - g31(i)*hgy(i)
         t14(i) =t14(i) - g41(i)*hgy(i)
         t21(i) =t21(i) - g11(i)*hgz(i)
         t22(i) =t22(i) - g21(i)*hgz(i)
         t23(i) =t23(i) - g31(i)*hgz(i)
         t24(i) =t24(i) - g41(i)*hgz(i)
        END DO 
C
      RETURN
      END