q4voli2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4voli2       ../starter/source/elements/solid_2d/quad4/q4voli2.f
!||--- called by ------------------------------------------------------
!||    q4init2       ../starter/source/elements/solid_2d/quad4/q4init2.F
!||--- calls      -----------------------------------------------------
!||    ancmsg        ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE q4voli2(VOLU,IXQ, 
     .     NGL, AIRE, 
     .     Y1, Y2, Y3, Y4, 
     .     Z1, Z2, Z3, Z4,Y234,Y124)
      USE message_mod
      use element_mod , only : nixq
C
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXQ(NIXQ,*), NGL(*)
      my_real
     .   VOLU(*), AIRE(*), 
     .   y1(*), y2(*), y3(*), y4(*),
     .   z1(*), z2(*), z3(*), z4(*),y234(*),y124(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .   A1(MVSIZ), A2(MVSIZ)
C----------------------------------------------------------------------
      DO i=lft,llt
        a1(i) =y2(i)*(z3(i)-z4(i))+
     .         y3(i)*(z4(i)-z2(i))+y4(i)*(z2(i)-z3(i))
        a2(i) =y2(i)*(z4(i)-z1(i))+
     .         y4(i)*(z1(i)-z2(i))+y1(i)*(z2(i)-z4(i))
        aire(i)=(a1(i)+a2(i))* half
        IF (aire(i)==zero) THEN
           CALL ancmsg(msgid=227,
     .                 msgtype=msgerror,
     .                 anmode=aninfo_blind_1,
     .                 i1=ixq(nixq,i))
        ELSEIF(aire(i)<zero.AND.n2d==1) THEN
                     CALL ancmsg(msgid=1228,
     .                 msgtype=msgerror,
     .                 anmode=aninfo_blind_1,
     .                 i1=ngl(i),
     .                 prmod=msg_cumu)
         aire(i) = -aire(i)
        ENDIF
      END DO
 
      IF(n2d==1) THEN
       IF(jcvt==0)THEN
        DO i=lft,llt
         volu(i)=((y2(i)+y3(i)+y4(i))*a1(i)
     .                 +(y1(i)+y2(i)+y4(i))*a2(i))*one_over_6
        END DO
       ELSE
        DO i=lft,llt
         volu(i)=(y234(i)*a1(i)+y124(i)*a2(i))*one_over_6
        END DO
       END IF
      ELSE
        DO i=lft,llt
          volu(i)=aire(i)
          END DO
      ENDIF
 
      DO i=lft,llt
        IF(volu(i)<=0.0)THEN
          CALL ancmsg(msgid=228,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=ngl(i))
            EXIT
        END IF
      END DO
 
      RETURN
 
      END