qrota_vect.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    qrota_vect        ../engine/source/output/anim/generate/qrota_vect.F
!||--- called by ------------------------------------------------------
!||    h3d_quad_vector   ../engine/source/output/h3d/h3d_results/h3d_quad_vector.F
!||====================================================================
      SUBROUTINE qrota_vect(X, IXQ, KCVT, VECT, GAMA, NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real
     .   x(3,*),vect(3,*),gama(6,*)
      INTEGER IXQ(NIXQ,*), KCVT, NEL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real
     .   y1(mvsiz), y2(mvsiz), y3(mvsiz), y4(mvsiz),
     .   z1(mvsiz), z2(mvsiz), z3(mvsiz), z4(mvsiz),
     .   r22(mvsiz),r23(mvsiz),r32(mvsiz),r33(mvsiz),
     .   sy(mvsiz),sz(mvsiz),ty(mvsiz),tz(mvsiz),
     .   ct,cs,suma,s1,s2,s3
      INTEGER NC1(MVSIZ), NC2(MVSIZ), NC3(MVSIZ), NC4(MVSIZ)
      INTEGER I
C-----------------------------------------------
      IF (kcvt == 0) THEN
        DO i=1,nel
          nc1(i)=ixq(2,i)
          nc2(i)=ixq(3,i)
          nc3(i)=ixq(4,i)
          nc4(i)=ixq(5,i)
C----------------------------
C     COORDONNEES NODALES
C----------------------------
          y1(i)=x(2,nc1(i))
          z1(i)=x(3,nc1(i))
          y2(i)=x(2,nc2(i))
          z2(i)=x(3,nc2(i))
          y3(i)=x(2,nc3(i))
          z3(i)=x(3,nc3(i))
          y4(i)=x(2,nc4(i))
          z4(i)=x(3,nc4(i))
C---------------------------------------
C     REPERE LOCAL (ISOPARAMETRIQUE)
C---------------------------------------
          sy(i)=half*(y2(i)+y3(i)-y1(i)-y4(i))
          sz(i)=half*(z2(i)+z3(i)-z1(i)-z4(i))
          ty(i)=half*(y3(i)+y4(i)-y1(i)-y2(i))
          tz(i)=half*(z3(i)+z4(i)-z1(i)-z2(i))
        ENDDO
C-----------
C       REPERE CONVECTE
C-----------
        DO i=1,nel
          ct = ty(i)*ty(i)+tz(i)*tz(i)
          cs = sy(i)*sy(i)+sz(i)*sz(i)
          IF(cs /= zero) THEN
            suma = sqrt(ct/max(em20,cs))
            sy(i) = sy(i)*suma + tz(i)
            sz(i) = sz(i)*suma - ty(i)
          ELSEIF(ct /= zero)THEN
            suma = sqrt(cs/max(em20,ct))
            sy(i) = sy(i) + tz(i)*suma
            sz(i) = sz(i) - ty(i)*suma
          END IF 
          suma=one/max(sqrt(sy(i)**2+sz(i)**2),em20)
          sy(i)=sy(i)*suma
          sz(i)=sz(i)*suma
C-----------
C       MATRICE DE PASSAGE GLOBAL -> CONVECTE
C-----------
          r22(i)= sy(i)
          r32(i)=-sz(i)
          r23(i)= sz(i)
          r33(i)= sy(i)
        ENDDO
      END IF
c
      DO i=1,nel
C-----------
C       CHANGEMENT DE REPERE
C-----------
        s1=vect(1,i)
        s2=vect(2,i)
        s3=vect(3,i)
        vect(1,i)=s2*r22(i)+s3*r23(i)
        vect(2,i)=s2*r32(i)+s3*r33(i)
        vect(3,i)=zero
      ENDDO
C-----------
      RETURN
      END