quad_surface_buffer.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    quad_surface_buffer   ../starter/source/model/sets/quad_surface_buffer.F
!||--- called by ------------------------------------------------------
!||    surface_buffer        ../starter/source/model/sets/surface_buffer.F
!||--- calls      -----------------------------------------------------
!||    surf_segment          ../starter/source/model/sets/solid_surface_buffer.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE quad_surface_buffer(
     .                        IXQ     ,IAD_SURF ,BUFTMPSURF ,NSEG  ,KNOD2ELQ ,
     .                        NOD2ELQ ,IEXT     ,X          ,CLAUSE,IPARTQ)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE my_alloc_mod
      USE setdef_mod
      use element_mod , only : nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "com04_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXQ(NIXQ,*),KNOD2ELQ(*),NOD2ELQ(*),BUFTMPSURF(*),IPARTQ(NUMELQ)
      INTEGER IEXT,IAD_SURF
      INTEGER, INTENT(INOUT) :: NSEG
      my_real
     .   x(3,*)
!
      TYPE (SET_) ::  CLAUSE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J, JQ, K, N1, N2, ISEG, KK, KQ, L1, L2, L, TRUEAXE, NQQ1, NQQ2
      INTEGER NODTAG(4),LINES(2,4),NQ(4)
      DATA lines/1,2,
     .           2,3,
     .           3,4,
     .           4,1/
      my_real
     .   y1,z1,y2,z2,y3,z3,y4,z4,
     .   yg,zg,pvect,psca,dy,dz,ny,nz   
      INTEGER, DIMENSION(:), ALLOCATABLE:: PART_TAG
C=======================================================================
C
      IF(iext==1)THEN
C
C       External surface only.
        CALL my_alloc(part_tag,npart)
        part_tag(1:npart)=0
        DO j=1, clause%NB_PART
          part_tag(clause%PART(j))=1
        ENDDO
 
        DO j=1,clause%NB_QUAD
          jq = clause%QUAD(j)
          nodtag(1:4)=1
c         NQ(N) = IXQ(JJ-1,JQ)
          DO l=1,4
            nq(l) = ixq(l+1,jq)
            l1 = lines(1,l)
            l2 = lines(2,l) 
            nqq1 = ixq(l1+1,jq)         
            nqq2 = ixq(l2+1,jq)
            DO k=knod2elq(nqq1)+1,knod2elq(nqq1+1)            
              kq=nod2elq(k)
              IF (kq==jq .OR. kq > numelq) cycle
              IF (part_tag(ipartq(kq))==0) cycle
              DO kk=1,4
                IF (ixq(lines(1,kk)+1,kq)==nqq1.AND.ixq(lines(2,kk)+1,kq)==nqq2) THEN
                  nodtag(l)=0
                ELSEIF (ixq(lines(1,kk)+1,kq)==nqq2.AND.ixq(lines(2,kk)+1,kq)==nqq1) THEN
                  nodtag(l)=0
                ENDIF
              ENDDO
            ENDDO
          ENDDO ! DO L=1,4
C         looks for the center of elements to check normal ext
          y1 = x(2,nq(1))
          z1 = x(3,nq(1))
c
          y2 = x(2,nq(2))
          z2 = x(3,nq(2))
c
          y3 = x(2,nq(3))
          z3 = x(3,nq(3))
c
          y4 = x(2,nq(4))
          z4 = x(3,nq(4))
c        
          yg = (y1+y2+y3+y4)/four
          zg = (z1+z2+z3+z4)/four 
 
          DO l=1,4
             l1 = lines(1,l)
             l2 = lines(2,l)
             trueaxe= 1
             n1 = nq(l1)
             n2 = nq(l2)
             IF (n2d==1.AND.x(2,n1)<=em10.AND.x(2,n2)<=em10) THEN ! Case Axi omit nodes of revolution axe z ( y=0)
               trueaxe= 0
             ENDIF
 
             IF (trueaxe==1) THEN
               IF (nodtag(l)==1) THEN ! nodes of external lines
                 nseg=nseg+1  
C           normal computation
                  dy = x(2,n2)-x(2,n1)
                  dz = x(3,n2)-x(3,n1)
                  ny = -dz
                  nz = dy
                  pvect = dy*dz
                  IF (pvect<zero) THEN
                    ny = dz
                    nz = -dy
                  ENDIF
C           check external normal 
                  psca = ny*(y1-yg)+nz*(z1-zg)
                  iseg = nseg
                  IF (psca<=zero) THEN
                    CALL surf_segment(n1         ,n2       ,0   ,0    ,jq,
     .                                buftmpsurf ,iad_surf ,2   )
                  ELSE
                    CALL surf_segment(n2         ,n1       ,0   ,0    ,jq,
     .                                buftmpsurf ,iad_surf ,2   )
                 ENDIF ! IF (PSCA<=ZERO)
 
               ENDIF
 
             ENDIF
 
           ENDDO
 
 
        ENDDO
        IF(ALLOCATED(part_tag)) DEALLOCATE(part_tag)
      ENDIF
C-----------
      RETURN
      END