r13sumg3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r13sumg3   ../engine/source/elements/spring/r13sumg3.F
!||--- called by ------------------------------------------------------
!||    r13ke3     ../engine/source/elements/spring/r13ke3.F
!||====================================================================
      SUBROUTINE r13sumg3(JFT    ,JLT    ,AL      ,KX      ,KY     ,
     2                    KZ     ,MX     ,MY      ,MZ      ,R11    ,
     3                    R12    ,R13    ,R21     ,R22     ,R23    ,
     4                    R31    ,R32    ,R33     ,KE11    ,KE12   ,
     5                    KE22   )
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8
#include      "implicit_f.inc"
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D U M M Y   A R G U M E N T S
C-----------------------------------------------
      INTEGER JFT,JLT
      my_real 
     .    AL(*),KX(*),KY(*),KZ(*),
     .    MX(*),MY(*),MZ(*),
     .    r11(*),r12(*),r13(*),
     .    r21(*),r22(*),r23(*),
     .    r31(*),r32(*),r33(*)
       my_real
     .    ke11(6,6,*),ke22(6,6,*),ke12(6,6,*)
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
      INTEGER I, J, EP,IS,IAS,MI,MJ
      my_real 
     .     Q(3,3,MVSIZ),K11(3,MVSIZ),M11(3,MVSIZ),MF32(MVSIZ),
     .     M12(3,MVSIZ),MF23(MVSIZ),ALDEMI,Q1,Q2,Q3,MF11(3,3,MVSIZ)
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8
       DO i=jft,jlt
        k11(1,i)=kx(i)
        k11(2,i)=ky(i)
        k11(3,i)=kz(i)
        aldemi = half*al(i)
        mf23(i)= aldemi*ky(i)
        mf32(i)= aldemi*kz(i)
        m11(1,i)=mx(i)
        m11(2,i)=my(i)+aldemi*mf23(i)
        m11(3,i)=mz(i)+aldemi*mf32(i)
        m12(1,i)=-m11(1,i)
        m12(2,i)=al(i)*mf32(i)-m11(2,i)
        m12(3,i)=al(i)*mf23(i)-m11(3,i)
        mf32(i)=-mf32(i)
       ENDDO 
C---------------------------------------
C   TRANS LOCAL-->GLOBAL 
C---------------------------------------
       DO i=jft,jlt
        q(1,1,i)=r11(i)
        q(1,2,i)=r21(i)
        q(1,3,i)=r31(i)
        q(2,1,i)=r12(i)
        q(2,2,i)=r22(i)
        q(2,3,i)=r32(i)
        q(3,1,i)=r13(i)
        q(3,2,i)=r23(i)
        q(3,3,i)=r33(i)
       ENDDO 
C---------------------------------------
C   ASSEMBLAGE
C---------------------------------------
C---------KII ----Keij=QkiQkj*Kkk---M12 est diag- 
       DO i=1,3 
        mi=i+3
        DO j=i,3 
         mj=j+3
         DO ep=jft,jlt
          q1 =q(1,i,ep)*q(1,j,ep)
          q2 =q(2,i,ep)*q(2,j,ep)
          q3 =q(3,i,ep)*q(3,j,ep)
          ke11(i,j,ep)=q1*k11(1,ep)+q2*k11(2,ep)+q3*k11(3,ep)
          ke11(mi,mj,ep)=q1*m11(1,ep)+q2*m11(2,ep)+q3*m11(3,ep)
          ke12(mi,mj,ep)=q1*m12(1,ep)+q2*m12(2,ep)+q3*m12(3,ep)
          ke22(i,j,ep)=ke11(i,j,ep)
          ke22(mi,mj,ep)=ke11(mi,mj,ep)
         ENDDO
        ENDDO
       ENDDO
C---------K23>0,K32>0-------------------------
       DO i=1,3 
        DO j=1,3 
         DO ep=jft,jlt
          mf11(i,j,ep)=q(2,i,ep)*mf23(ep)*q(3,j,ep)+
     .                 q(3,i,ep)*mf32(ep)*q(2,j,ep)
         ENDDO
        ENDDO
       ENDDO
C
       DO i=1,3 
        DO j=1,3 
         mj=j+3
         DO ep=jft,jlt
          ke11(i,mj,ep)=mf11(i,j,ep)
          ke22(i,mj,ep)=-mf11(i,j,ep)
         ENDDO
        ENDDO
       ENDDO
C
       DO i=1,6 
        DO j=i,6 
         DO ep=jft,jlt
          ke11(j,i,ep)=ke11(i,j,ep)
          ke22(j,i,ep)=ke22(i,j,ep)
         ENDDO
        ENDDO
       ENDDO
C---------KIJ -------- 
       DO i=1,3 
        mi=i+3
        DO j=1,3 
         mj=j+3
         DO ep=jft,jlt
          ke12(i,j,ep)=-ke11(i,j,ep)
          ke12(i,mj,ep)=mf11(i,j,ep)
          ke12(mi,j,ep)=-mf11(j,i,ep)
         ENDDO
        ENDDO
       ENDDO
       DO ep=jft,jlt
          ke12(5,4,ep)=ke12(4,5,ep)
          ke12(6,4,ep)=ke12(4,6,ep)
          ke12(6,5,ep)=ke12(5,6,ep)
       ENDDO
C
      RETURN
      END