r2cum3p.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r2cum3p     ../engine/source/elements/spring/r2cum3p.F
!||--- called by ------------------------------------------------------
!||    r23law108   ../engine/source/elements/spring/r23law108.f
!||    rforc3      ../engine/source/elements/spring/rforc3.F
!||====================================================================
      SUBROUTINE r2cum3p(
     1   FORX,    FORY,    FORZ,    XMOM,
     2   YMOM,    ZMOM,    STI,     STIR,
     3   FSKY,    FSKYV,   IADR,    FX1,
     4   FX2,     FY1,     FY2,     FZ1,
     5   FZ2,     MX1,     MX2,     MY1,
     6   MY2,     MZ1,     MZ2,     GEO,
     7   X1,      Y1,      Z1,      X2,
     8   Y2,      Z2,      IEQUIL,  EXX,
     9   EYX,     EZX,     EXY,     EYY,
     A   EZY,     EXZ,     EYZ,     EZZ,
     B   NEL,     NFT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "parit_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: NFT
C     REAL
      my_real
     .   FORX(*), FORY(*), FORZ(*), XMOM(*), YMOM(*),
     .   ZMOM(*),STI(3,*),STIR(3,*),FSKYV(LSKY,8), FSKY(8,LSKY),
     .   FX1(MVSIZ),FY1(MVSIZ),FZ1(MVSIZ),
     .   FX2(MVSIZ),FY2(MVSIZ),FZ2(MVSIZ),
     .   MX1(MVSIZ),MY1(MVSIZ),MZ1(MVSIZ),
     .   MX2(MVSIZ),MY2(MVSIZ),MZ2(MVSIZ),
     .   GEO(NPROPG,*),X1(*),X2(*),Y1(*),Y2(*),
     .   z1(*),z2(*), 
     .   exx(mvsiz), eyx(mvsiz), ezx(mvsiz), exy(mvsiz),
     .   eyy(mvsiz), ezy(mvsiz), exz(mvsiz), eyz(mvsiz), ezz(mvsiz)
      INTEGER IADR(3,*),IEQUIL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, N, J
C     REAL
      my_real
     .   MMX, MMY, MMZ, XX
C-----------------------------------------------
C-------------------------
C     FORCES
C-------------------------
      DO i=1,nel
        fx2(i)=exx(i)*forx(i)+exy(i)*fory(i)+exz(i)*forz(i)
        fy2(i)=eyx(i)*forx(i)+eyy(i)*fory(i)+eyz(i)*forz(i)
        fz2(i)=ezx(i)*forx(i)+ezy(i)*fory(i)+ezz(i)*forz(i)
        fx1(i) = -fx2(i)
        fy1(i) = -fy2(i)
        fz1(i) = -fz2(i)
      ENDDO
C-------------------------
C     ASSEMBLE
C-------------------------
      IF (ivector == 1) THEN
#include "vectorize.inc"
        DO i=1,nel
          ii = i+nft
          n = iadr(1,ii)
          fskyv(n,1)=-fx1(i)
          fskyv(n,2)=-fy1(i)
          fskyv(n,3)=-fz1(i)
          fskyv(n,7)=sti(1,i)
          n = iadr(2,ii)
          fskyv(n,1)=-fx2(i)
          fskyv(n,2)=-fy2(i)
          fskyv(n,3)=-fz2(i)
          fskyv(n,7)=sti(2,i)
        ENDDO
      ELSE
        DO i=1,nel
          ii = i+nft
          n = iadr(1,ii)
          fsky(1,n)=-fx1(i)
          fsky(2,n)=-fy1(i)
          fsky(3,n)=-fz1(i)
          fsky(7,n)=sti(1,i)
          n = iadr(2,ii)
          fsky(1,n)=-fx2(i)
          fsky(2,n)=-fy2(i)
          fsky(3,n)=-fz2(i)
          fsky(7,n)=sti(2,i)
        ENDDO
      ENDIF
C-------------------------
C     MOMENTS
C-------------------------
      DO i=1,nel
        mx2(i)=exx(i)*xmom(i)+exy(i)*ymom(i)+exz(i)*zmom(i)
        my2(i)=eyx(i)*xmom(i)+eyy(i)*ymom(i)+eyz(i)*zmom(i)
        mz2(i)=ezx(i)*xmom(i)+ezy(i)*ymom(i)+ezz(i)*zmom(i)
        mx1(i) = -mx2(i)
        my1(i) = -my2(i)
        mz1(i) = -mz2(i)
      ENDDO
C
      DO i=1,nel
        IF (iequil(i) == 1) THEN
          mmx = half*((y2(i)-y1(i))*fz2(i) - (z2(i)-z1(i))*fy2(i))
          mmy = half*((z2(i)-z1(i))*fx2(i) - (x2(i)-x1(i))*fz2(i))
          mmz = half*((x2(i)-x1(i))*fy2(i) - (y2(i)-y1(i))*fx2(i)) 
          mx1(i) = mx1(i) - mmx
          my1(i) = my1(i) - mmy
          mz1(i) = mz1(i) - mmz
          mx2(i) = mx2(i) - mmx
          my2(i) = my2(i) - mmy
          mz2(i) = mz2(i) - mmz
          xx = (x2(i)-x1(i))*(x2(i)-x1(i)) 
     .       + (y2(i)-y1(i))*(y2(i)-y1(i))
     .       + (z2(i)-z1(i))*(z2(i)-z1(i))
          stir(1,i) = stir(1,i) + sti(2,i)*xx
          stir(2,i) = stir(2,i) + sti(1,i)*xx
        ENDIF
      ENDDO
C-------------------------
C     ASSEMBLE
C-------------------------
      IF (ivector == 1) THEN
#include "vectorize.inc"
        DO i=1,nel
          ii = i+nft
          n = iadr(1,ii)
          fskyv(n,4)=-mx1(i)
          fskyv(n,5)=-my1(i)
          fskyv(n,6)=-mz1(i)
          fskyv(n,8)=stir(1,i)
          n = iadr(2,ii)
          fskyv(n,4)=-mx2(i)
          fskyv(n,5)=-my2(i)
          fskyv(n,6)=-mz2(i)
          fskyv(n,8)=stir(2,i)
        ENDDO
      ELSE
        DO i=1,nel
          ii = i+nft
          n = iadr(1,ii)
          fsky(4,n)=-mx1(i)
          fsky(5,n)=-my1(i)
          fsky(6,n)=-mz1(i)
          fsky(8,n)=stir(1,i)
          n = iadr(2,ii)
          fsky(4,n)=-mx2(i)
          fsky(5,n)=-my2(i)
          fsky(6,n)=-mz2(i)
          fsky(8,n)=stir(2,i)
        ENDDO
      ENDIF
C---
      RETURN
      END