r3coork3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r3coork3      ../engine/source/elements/spring/r3coork3.F
!||--- called by ------------------------------------------------------
!||    r12ke3        ../engine/source/elements/spring/r12ke3.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE r3coork3(JFT    ,JLT    ,X      ,NCC   ,PID    ,
     1                    NGL    ,R11    ,R21   ,R31    ,R12    ,
     2                    R22    ,R32   ,BETA   ,OFFG   ,OFF    )
      use element_mod , only : nixr
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "impl1_c.inc"
#include      "comlock.inc"
#include      "units_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT 
      INTEGER NCC(NIXR,*),PID(*),NGL(*)
C     REAL
      my_real
     .   x(3,*),beta(*),offg(*),off(*),
     .   r11(*),r21(*),r31(*),r12(*),r22(*),r32(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,NC1(MVSIZ),NC2(MVSIZ),NC3(MVSIZ)
C     REAL
      my_real
     .   x1(mvsiz), x2(mvsiz),x3(mvsiz),y1(mvsiz), y2(mvsiz),  
     .   y3(mvsiz),z1(mvsiz), z2(mvsiz),z3(mvsiz), 
     .   al1(mvsiz),al2(mvsiz),norm
C-----------------------------------------------
C
      DO i=jft, jlt
       pid(i)=ncc(1,i)
       ngl(i)=ncc(5,i)
       nc1(i)=ncc(2,i)
       nc2(i)=ncc(3,i)
       nc3(i)=ncc(4,i)
      ENDDO 
C----------------------------
C     COORDONNEES
C----------------------------
      DO i=jft, jlt
       x1(i)=x(1,nc1(i))
       y1(i)=x(2,nc1(i))
       z1(i)=x(3,nc1(i))
       x2(i)=x(1,nc2(i))
       y2(i)=x(2,nc2(i))
       z2(i)=x(3,nc2(i))
       x3(i)=x(1,nc3(i))
       y3(i)=x(2,nc3(i))
       z3(i)=x(3,nc3(i))
      ENDDO 
C----------------------------
C     LOCAL SYSTEM
C----------------------------
      DO  i=jft, jlt
       r11(i)=one
       r21(i)=zero
       r31(i)=zero
       r12(i)=one
       r22(i)=zero
       r32(i)=zero
      ENDDO
C 
      DO  i=jft, jlt
       r11(i)=x2(i)-x1(i)
       r21(i)=y2(i)-y1(i)
       r31(i)=z2(i)-z1(i)
       al1(i)=sqrt(r11(i)*r11(i)+r21(i)*r21(i)+r31(i)*r31(i))
       al1(i)=max(em15,al1(i))
      ENDDO 
C
      DO i=jft, jlt
       IF (al1(i)>em15) THEN
        norm=one/al1(i)
        r11(i)=r11(i)*norm
        r21(i)=r21(i)*norm
        r31(i)=r31(i)*norm
       ENDIF 
      ENDDO 
C
      DO  i=jft, jlt
       r12(i)=x2(i)-x3(i)
       r22(i)=y2(i)-y3(i)
       r32(i)=z2(i)-z3(i)
       al2(i)=sqrt(r12(i)*r12(i)+r22(i)*r22(i)+r32(i)*r32(i))
       al2(i)=max(em15,al2(i))
      ENDDO 
C
      DO i=jft, jlt
       IF (al2(i)>em15) THEN
        norm=one/al2(i)
        r12(i)=r12(i)*norm
        r22(i)=r22(i)*norm
        r32(i)=r32(i)*norm
       ENDIF 
      ENDDO 
      IF (imp_chk > 0) THEN
       DO i=jft,jlt
        IF(offg(i)/=zero)THEN
         IF(al1(i)<=em15)THEN
#include "lockon.inc"
            WRITE(iout ,2001) ngl(i)
#include "lockoff.inc"
            idel7nok = 1
            imp_iw = imp_iw + 1
         ENDIF 
         IF(al2(i)<=em15)THEN
#include "lockon.inc"
            WRITE(iout ,2002) ngl(i)
#include "lockoff.inc"
            idel7nok = 1
            imp_iw = imp_iw + 1
         ENDIF 
        ENDIF 
       ENDDO
      ENDIF 
C
      DO i=jft, jlt
       beta(i) = pi - acos(r11(i)*r12(i)+r21(i)*r22(i)+r31(i)*r32(i))
      ENDDO 
C
      DO i=jft,jlt
       off(i)=offg(i)
      ENDDO
C
      RETURN
 2001 FORMAT(/'***WARNING :SPRING TYPE12 ZERO-LENGTH N1N2: ELE. NB:',
     .          i8/)
 2002 FORMAT(/'***WARNING :SPRING TYPE12 ZERO-LENGTH N2N3: ELE. NB:',
     .          i8/)
      END