r5def3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r5def3   ../engine/source/elements/spring/r5def3.F
!||--- called by ------------------------------------------------------
!||    rforc3   ../engine/source/elements/spring/rforc3.F
!||====================================================================
      SUBROUTINE r5def3(
     1   XL,      VX2L,    RY1L,    RZ1L,
     2   RX2L,    RY2L,    RZ2L,    FR_WAVE,
     3   FR_W_E,  EINT,    FX,      XMOM,
     4   YMOM,    ZMOM,    FY,      FZ,
     5   PARTSAV, IPARTR,  EXX,     EYX,
     6   EZX,     EXY,     EYY,     EZY,
     7   EXZ,     EYZ,     EZZ,     RX1,
     8   RY1,     RZ1,     RX2,     RY2,
     9   RZ2,     VX1,     VX2,     VY1,
     A   VY2,     VZ1,     VZ2,     NC1,
     B   NC2,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com08_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER IPARTR(*),NC1(*),NC2(*)
C     REAL
      my_real
     .   XL(*), VX2L(*),RY1L(*), RZ1L(*), RX2L(*), RY2L(*), RZ2L(*),
     .   FR_WAVE(*) ,FR_W_E(*),EINT(*) ,  
     .   FX(*), FY(*), FZ(*), XMOM(*), YMOM(*),ZMOM(*),PARTSAV(NPSAV,*),
     .   EXX(MVSIZ), EYX(MVSIZ), EZX(MVSIZ),
     .   EXY(MVSIZ), EYY(MVSIZ), EZY(MVSIZ),
     .   EXZ(MVSIZ), EYZ(MVSIZ), EZZ(MVSIZ), RX1(MVSIZ), RX2(MVSIZ),
     .   RY1(MVSIZ), RY2(MVSIZ), RZ1(MVSIZ), RZ2(MVSIZ), VX1(MVSIZ),
     .   vx2(mvsiz), vy1(mvsiz), vy2(mvsiz), vz1(mvsiz), vz2(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,MX
C     REAL
      my_real
     .     VX1L, VY1L, VY2L, VZ1L, VZ2L,THETA , XLDEMI,XSIGN
C-----------------------------------------------
C--------------------------------------------
C     VITESSES REPERE CONVECTEE
C--------------------------------------------
      DO I=1,nel
        rx2l(i) = exx(i)*(rx2(i)-rx1(i))
     .          + eyx(i)*(ry2(i)-ry1(i))
     .          + ezx(i)*(rz2(i)-rz1(i))
        ry1l(i) = exy(i)*rx1(i)+eyy(i)*ry1(i)+ezy(i)*rz1(i)
        ry2l(i) = exy(i)*rx2(i)+eyy(i)*ry2(i)+ezy(i)*rz2(i)
        rz1l(i) = exz(i)*rx1(i)+eyz(i)*ry1(i)+ezz(i)*rz1(i)
        rz2l(i) = exz(i)*rx2(i)+eyz(i)*ry2(i)+ezz(i)*rz2(i)
        vx2l(i) = exx(i)*(vx2(i)-vx1(i))
     .          + eyx(i)*(vy2(i)-vy1(i))
     .          + ezx(i)*(vz2(i)-vz1(i))
        vy2l   = exy(i)*(vx2(i)-vx1(i))
     .         + eyy(i)*(vy2(i)-vy1(i))
     .         + ezy(i)*(vz2(i)-vz1(i))
        xsign  = sign(one, xl(i) - half*vx2l(i)*dt1)
        xldemi = xsign/max(em15,abs(xl(i) - half*vx2l(i)*dt1))
        theta  = vy2l * xldemi
        rz1l(i) = rz1l(i) - theta
        rz2l(i) = rz2l(i) - theta
        vz2l   = exz(i)*(vx2(i)-vx1(i))
     .         + eyz(i)*(vy2(i)-vy1(i))
     .         + ezz(i)*(vz2(i)-vz1(i))
        theta  = vz2l * xldemi
        ry1l(i) = ry1l(i) + theta
        ry2l(i) = ry2l(i) + theta
        vx2l(i) = vx2l(i)
     .    - half*dt1*xldemi*(vy2l*vy2l+vz2l*vz2l)
      ENDDO
C--------------------------------------------
C     Energy
C--------------------------------------------
      DO i=1,nel
        eint(i) = eint(i)
     .+ half*dt1 * (vx2l(i) * fx(i) + rx2l(i) * xmom(i) 
     .          + (ry2l(i) - ry1l(i)) * ymom(i) 
     .          + (rz2l(i) - rz1l(i)) * zmom(i)
     .          + half * (ry2l(i) + ry1l(i)) * fz(i) * xl(i)
     .          - half * (rz2l(i) + rz1l(i)) * fy(i) * xl(i) )
      ENDDO
C
      IF (npsav >= 21) THEN
        DO i=1,nel
          mx = ipartr(i)
          partsav(23,mx)=partsav(23,mx)
     .          + half*dt1 * (rx2l(i) * xmom(i)
     .          + (ry2l(i) - ry1l(i)) * ymom(i) 
     .          + (rz2l(i) - rz1l(i)) * zmom(i)
     .          + half * (ry2l(i) + ry1l(i)) * fz(i) * xl(i)
     .          - half * (rz2l(i) + rz1l(i)) * fy(i) * xl(i) )
        ENDDO
      ENDIF
C--------------------------------------------
C     Front wave
C--------------------------------------------
      IF (ifrwv /= 0) THEN
        DO i=1,nel
          fr_w_e(i)=max(fr_wave(nc1(i)),fr_wave(nc2(i)),zero)
        ENDDO
      ENDIF
C---
      RETURN
      END