r5evec3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    r5evec3   ../engine/source/elements/spring/r5evec3.F
!||--- called by ------------------------------------------------------
!||    rforc3    ../engine/source/elements/spring/rforc3.f
!||====================================================================
      SUBROUTINE r5evec3(
     1   RLOC,    V,       NGL,     AL,
     2   X1,      Y1,      Z1,      X2,
     3   Y2,      Z2,      EXX,     EYX,
     4   EZX,     EXY,     EYY,     EZY,
     5   EXZ,     EYZ,     EZZ,     RX1,
     6   RY1,     RZ1,     RX2,     RY2,
     7   RZ2,     VX1,     VX2,     VY1,
     8   VY2,     VZ1,     VZ2,     NC1,
     9   NC2,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NGL(*),NC1(*),NC2(*)
C     REAL
      my_real
     .   RLOC(6,*),V(3,*),X1(*),X2(*),Y1(*),Y2(*),
     .   Z1(*),Z2(*),
     .   EXX(MVSIZ), EYX(MVSIZ), EZX(MVSIZ),
     .   EXY(MVSIZ), EYY(MVSIZ), EZY(MVSIZ),
     .   EXZ(MVSIZ), EYZ(MVSIZ), EZZ(MVSIZ),
     .   rx1(mvsiz),rx2(mvsiz),ry1(mvsiz),
     .   ry2(mvsiz),rz1(mvsiz),rz2(mvsiz),al(mvsiz),
     .   vx1(mvsiz),vx2(mvsiz),vy1(mvsiz),vy2(mvsiz),
     .   vz1(mvsiz),vz2(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J
C     REAL
      my_real
     .     RX(3),RXX1, RXX2, SINT(MVSIZ), 
     .     SUM(MVSIZ) ,SUM2(MVSIZ), SUM3(MVSIZ) ,THETA(MVSIZ),
     .     COST(MVSIZ)
C-----------------------------------------------
      DO I=1,nel
        exx(i)=(x2(i)-x1(i))
        eyx(i)=(y2(i)-y1(i))
        ezx(i)=(z2(i)-z1(i))
        al(i) =sqrt(exx(i)**2+eyx(i)**2+ezx(i)**2)
      ENDDO
C
      DO i=1,nel
        IF (al(i) <= em15) THEN
          exx(i)= one
          eyx(i)= zero
          ezx(i)= zero
          exy(i)= zero
          eyy(i)= one
          ezy(i)= zero    
        ELSE
          exx(i)=exx(i)/al(i) 
          eyx(i)=eyx(i)/al(i) 
          ezx(i)=ezx(i)/al(i) 
        ENDIF
      ENDDO
C
      DO i=1,nel
        exy(i)=rloc(4,i)
        eyy(i)=rloc(5,i)
        ezy(i)=rloc(6,i)
      ENDDO
C
      DO i=1,nel
        exz(i)=eyx(i)*ezy(i)-ezx(i)*eyy(i)
        eyz(i)=ezx(i)*exy(i)-exx(i)*ezy(i)
        ezz(i)=exx(i)*eyy(i)-eyx(i)*exy(i)
      ENDDO
C
      DO i=1,nel
        exy(i)=eyz(i)*ezx(i)-ezz(i)*eyx(i)
        eyy(i)=ezz(i)*exx(i)-exz(i)*ezx(i)
        ezy(i)=exz(i)*eyx(i)-eyz(i)*exx(i)
      ENDDO
C--------------------------------------------
C     TORSION MOYENNE EN COORDONNEES GLOBALES
C--------------------------------------------
      DO i=1,nel
        rxx1   = exx(i)*rx1(i)+eyx(i)*ry1(i)+ezx(i)*rz1(i)
        rxx2   = exx(i)*rx2(i)+eyx(i)*ry2(i)+ezx(i)*rz2(i)
        theta(i) = (rxx1+rxx2)/two*dt1
        sum2(i)  = max(em15,sqrt(exy(i)**2+eyy(i)**2+ezy(i)**2))
        sum3(i)  = max(em15,sqrt(exz(i)**2+eyz(i)**2+ezz(i)**2))
        cost(i)  = cos(theta(i))/sum2(i)
        sint(i)  = sin(theta(i))/sum3(i)
      ENDDO
C ... it is modified.
      DO i=1,nel
        exy(i)= exy(i)*cost(i)+exz(i)*sint(i)
        eyy(i)= eyy(i)*cost(i)+eyz(i)*sint(i)
        ezy(i)= ezy(i)*cost(i)+ezz(i)*sint(i)
      ENDDO
C
      DO i=1,nel
        sum(i)=max(em15,sqrt(exy(i)**2+eyy(i)**2+ezy(i)**2))
        exy(i)=exy(i)/sum(i) 
        eyy(i)=eyy(i)/sum(i) 
        ezy(i)=ezy(i)/sum(i) 
      ENDDO
C
      DO i=1,nel
        exz(i)=eyx(i)*ezy(i)-ezx(i)*eyy(i)
        eyz(i)=ezx(i)*exy(i)-exx(i)*ezy(i)
        ezz(i)=exx(i)*eyy(i)-eyx(i)*exy(i)
      ENDDO
C
      DO i=1,nel
        sum(i)=max(em15,sqrt(exz(i)**2+eyz(i)**2+ezz(i)**2))
        exz(i)=exz(i)/sum(i) 
        eyz(i)=eyz(i)/sum(i) 
        ezz(i)=ezz(i)/sum(i) 
      ENDDO
C
      DO i=1,nel
        rloc(1,i) = exx(i)
        rloc(2,i) = eyx(i)
        rloc(3,i) = ezx(i)
        rloc(4,i) = exy(i)
        rloc(5,i) = eyy(i)
        rloc(6,i) = ezy(i)
      ENDDO
C
      DO i=1,nel
        vx1(i)=v(1,nc1(i))
        vy1(i)=v(2,nc1(i))
        vz1(i)=v(3,nc1(i))
        vx2(i)=v(1,nc2(i))
        vy2(i)=v(2,nc2(i))
        vz2(i)=v(3,nc2(i))
      ENDDO
C---
      RETURN
      END