rbilan33.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rbilan33     ../engine/source/elements/joint/rbilan33.F
!||--- called by ------------------------------------------------------
!||    rgjoint      ../engine/source/elements/joint/rgjoint.F
!||--- calls      -----------------------------------------------------
!||    grelem_sav   ../engine/source/output/th/grelem_sav.F
!||====================================================================
      SUBROUTINE rbilan33(
     1   JFT,     JLT,     EINT,    PARTSAV,
     2   UMAS,    V,       IPARTR,  GRESAV,
     3   GRTH,    IGRTH,   NC1,     NC2,
     4   IGRE)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com06_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: IGRE
      INTEGER JFT,JLT, IPARTR(*),GRTH(*),IGRTH(*),NC1(*),NC2(*)
      my_real UMAS(*),EINT(*),PARTSAV(NPSAV,*),V(3,*),GRESAV(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,MX, FLAG
      my_real
     .   VXA, VYA, VZA, XMAS2, VA2, REINTT, 
     .   EK(MVSIZ), XM(MVSIZ), YM(MVSIZ), ZM(MVSIZ),
     .   rbidon(1),off(mvsiz)
C-----------------------------------------------
      flag = 0
      rbidon = zero
      off    = zero
      reintt = zero
      DO i=jft,jlt
        reintt=reintt + eint(i)
      ENDDO
C
!$OMP ATOMIC
        reint = reint + reintt
C
      DO i=jft,jlt
        xmas2=umas(i)*half
        vxa=v(1,nc1(i))+v(1,nc2(i))
        vya=v(2,nc1(i))+v(2,nc2(i))
        vza=v(3,nc1(i))+v(3,nc2(i))
        xm(i)= xmas2*vxa
        ym(i)= xmas2*vya
        zm(i)= xmas2*vza
        va2   =v(1,nc1(i))*v(1,nc1(i))+v(1,nc2(i))*v(1,nc2(i))
     .        +v(2,nc1(i))*v(2,nc1(i))+v(2,nc2(i))*v(2,nc2(i))
     .        +v(3,nc1(i))*v(3,nc1(i))+v(3,nc2(i))*v(3,nc2(i))
        ek(i)= xmas2*va2*half
      ENDDO
C
      IF (igre /= 0) THEN
        flag = 0
        CALL grelem_sav(jft   ,jlt   ,gresav,igrth ,grth  ,
     2                  off   ,eint  ,ek    ,xm    ,ym    ,
     3                  zm    ,umas  ,rbidon,rbidon,rbidon,
     4                  rbidon,rbidon,rbidon,rbidon,rbidon,
     5                  rbidon,rbidon,rbidon,rbidon,rbidon,
     6                  rbidon,flag)
      ENDIF
C
      DO i=jft,jlt
         mx = ipartr(i)
         partsav(1,mx)= partsav(1,mx) + eint(i)
         partsav(2,mx)= partsav(2,mx) + ek(i)
         partsav(3,mx)= partsav(3,mx) + xm(i)
         partsav(4,mx)= partsav(4,mx) + ym(i)
         partsav(5,mx)= partsav(5,mx) + zm(i)
         partsav(6,mx)= partsav(6,mx) + umas(i)
      ENDDO
C
      RETURN
      END