rdam24.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rdam24   ../engine/source/materials/mat/mat024/rdam24.F
!||--- called by ------------------------------------------------------
!||    elas24   ../engine/source/materials/mat/mat024/elas24.F
!||====================================================================
      SUBROUTINE rdam24(NEL   ,NBDAMA,DAMAI ,ANG   ,DEPS1 ,
     .                  DEPS2 ,DEPS3 ,DEPS4 ,DEPS5 ,DEPS6 )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NBDAMA,NEL,DAMAI(NEL)
      my_real, DIMENSION(NEL)   , INTENT(INOUT)  :: deps1,deps2,deps3,
     .                                              deps4,deps5,deps6
      my_real, DIMENSION(NEL,6) , INTENT(IN)  :: ang
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,K
      my_real, DIMENSION(NEL) ::  s11,s12,s13,s21,s22,s23,s31,s32,s33,
     .                            a11,a12,a13,a21,a22,a23,a31,a32,a33
C=======================================================================
      DO k=1,nbdama
        i = damai(k)
        s11(i)=ang(i,1)
        s21(i)=ang(i,2)
        s31(i)=ang(i,3)
        s12(i)=ang(i,4)
        s22(i)=ang(i,5)
        s32(i)=ang(i,6)
        s13(i)= s21(i)*s32(i)-s31(i)*s22(i)
        s23(i)= s31(i)*s12(i)-s11(i)*s32(i)
        s33(i)= s11(i)*s22(i)-s21(i)*s12(i)
      ENDDO
C . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
C     TRANSFORME INCREMENTS DE DEFORMATION
C     DANS LE REPERE DES DIRECTIONS DE DOMMAGE
C . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
      DO k=1,nbdama
        i= damai(k)
        deps4(i)=half*deps4(i)
        deps5(i)=half*deps5(i)
        deps6(i)=half*deps6(i)      
        a11(i)=deps1(i)*s11(i)+deps4(i)*s21(i)+deps6(i)*s31(i)
        a12(i)=deps1(i)*s12(i)+deps4(i)*s22(i)+deps6(i)*s32(i)
        a13(i)=deps1(i)*s13(i)+deps4(i)*s23(i)+deps6(i)*s33(i)
        a21(i)=deps4(i)*s11(i)+deps2(i)*s21(i)+deps5(i)*s31(i)
        a22(i)=deps4(i)*s12(i)+deps2(i)*s22(i)+deps5(i)*s32(i)
        a23(i)=deps4(i)*s13(i)+deps2(i)*s23(i)+deps5(i)*s33(i)
        a31(i)=deps6(i)*s11(i)+deps5(i)*s21(i)+deps3(i)*s31(i)
        a32(i)=deps6(i)*s12(i)+deps5(i)*s22(i)+deps3(i)*s32(i)
        a33(i)=deps6(i)*s13(i)+deps5(i)*s23(i)+deps3(i)*s33(i)
      ENDDO
      DO k = 1,nbdama
        i = damai(k)
        deps1(i) = s11(i)*a11(i)+s21(i)*a21(i)+s31(i)*a31(i)
        deps2(i) = s12(i)*a12(i)+s22(i)*a22(i)+s32(i)*a32(i)
        deps3(i) = s13(i)*a13(i)+s23(i)*a23(i)+s33(i)*a33(i)
        deps4(i) = s11(i)*a12(i)+s21(i)*a22(i)+s31(i)*a32(i)
        deps5(i) = s12(i)*a13(i)+s22(i)*a23(i)+s32(i)*a33(i)
        deps6(i) = s11(i)*a13(i)+s21(i)*a23(i)+s31(i)*a33(i)
        deps4(i) = two*deps4(i)
        deps5(i) = two*deps5(i)
        deps6(i) = two*deps6(i)
      ENDDO 
      RETURN
      END