rdtime33.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    rdtime33      ../engine/source/elements/joint/rdtime33.F
!||--- called by ------------------------------------------------------
!||    rgjoint       ../engine/source/elements/joint/rgjoint.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE rdtime33(
     1   JFT,     JLT,     DT2T,    NELTST,
     2   ITYPTST, IXR,     EINT,    STI,
     3   STIR,    OFF,     XKM,     XKR,
     4   XCM,     XCR,     UMAS,    UINER,
     5   FX,      FY,      FZ,      XMOM,
     6   YMOM,    ZMOM,    ROT1,    ROT2,
     7   MSRT,    DMELRT,  NUVAR,   UVAR,
     8   JNTYP,   JSMS)
      use element_mod , only : nixr
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr02_c.inc"
#include      "sms_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JSMS
      INTEGER JFT, JLT, IXR(NIXR,*), NELTST, ITYPTST,
     .   NUVAR,JNTYP
      my_real DT2T, STI(3,*), STIR(3,*), OFF(*), EINT(*) ,  
     .   XKM(*),XKR(*),XCM(*),XCR(*),UMAS(*),UINER(*),
     .   FX(*), FY(*), FZ(*), XMOM(*), YMOM(*),ZMOM(*),
     .   ROT1(*), ROT2(*), MSRT(*), DMELRT(*),
     .   UVAR(NUVAR,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real 
     .   DT(JLT-JFT+1), DTA, DTB, MX2,
     .   MS, IN   
C=======================================================================
C     nodal time step
C--------------------------------------------
      IF((idtmins/=2).AND.(jntyp==33)) nodadt = 1
C
      DO i=jft,jlt
        sti(1,i) = xkm(i) 
        stir(1,i) = xkr(i)
        sti(2,i) = sti(1,i) 
        stir(2,i) = stir(1,i)
 
C-------- Harmonic mass --------------
        ms = (uvar(34,i)*uvar(35,i))/max(em20,uvar(34,i)+uvar(35,i))
        in = (uvar(36,i)*uvar(37,i))/max(em20,uvar(36,i)+uvar(37,i))
 
C-------- Node 1--------------
          IF (ms>em15)
     .    sti(1,i) = ((xcm(i)+sqrt(xcm(i)**2+xkm(i)*ms))**2)/ms
          IF (in>em15)
     .    stir(1,i) = ((xcr(i)+sqrt(xcr(i)**2+xkr(i)*in))**2)/in
     
C-------- Node 2--------------
        sti(2,i) = sti(1,i) 
        stir(2,i) = stir(1,i)
           
      ENDDO
C
      IF(idtmins==2.AND.jsms/=0)THEN
C
        dta=dtmins/dtfacs
        dtb=dta*dta
        DO i=jft,jlt
         IF(off(i)<=zero) cycle
          xkm(i)   = max(em15,xkm(i))
          dmelrt(i)=max(dmelrt(i),
     .      xcm(i)*dta+half*xkm(i)*dtb-half*msrt(i))
C
C         MX2 = 2*(Mn+2*DeltaM)
          mx2 =msrt(i)+two*dmelrt(i)
          dt(i)=dtfacs*
     .      mx2 /max(em15,sqrt(xcm(i)*xcm(i)+mx2*xkm(i))+xcm(i))
          dt(i)=dtmins
        ENDDO
C
        DO i=jft,jlt
         IF(off(i)<=zero) cycle
         IF(dt(i)<dt2t) THEN
          dt2t=dt(i)
          neltst =ixr(nixr,i)
          ityptst=6
         ENDIF
        ENDDO
C
      ENDIF
C-----------------------------------------------
      RETURN
      END