read_pch_file.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    read_pch_file          ../starter/source/constraints/fxbody/read_pch_file.F
!||--- called by ------------------------------------------------------
!||    hm_read_fxb1           ../starter/source/constraints/fxbody/hm_read_fxb.F
!||    hm_setfxrbyon          ../starter/source/constraints/fxbody/hm_setfxrbyon.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    fxrline                ../starter/source/constraints/fxbody/hm_read_fxb.F
!||    usr2sys                ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE read_pch_file(FLAG,MATRIX,ITAG,MATRIX_ADD,CPT_STIFF,
     .                         CPT_MASS,ITABM1,PCH_FILE,ID,TITR)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE inoutfile_mod
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ID,ITABM1(*),ITAG(*),MATRIX_ADD(4,*), CPT_STIFF,CPT_MASS,FLAG
      my_real matrix(*)
      CHARACTER PCH_FILE*100
      CHARACTER(LEN=NCHARTITLE) :: TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,REF,IFO,TIN,TOUT,POLAR,NCOL,DUM,ID_NOD1,ID_NOD2,J,ISTOP
      my_real rell
      CHARACTER DEBUT*8,NAME*8,MATRIX_TYPE*16,NWLINE*100,MESS*40
 
      INTEGER :: LEN_TMP_NAME,I_ERR
      CHARACTER(len=2148) :: TMP_NAME
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS
      DATA mess/'FLEXIBLE BODY DEF - READ OF PCH FILE '/
C=======================================================================
C
C     FLAG = 0 -> PREREADING FOR NODES DETECTION AND NUMBERING (SETRFXBYON.F)
C     FLAG = 1 -> READING OF NODES AND MATRIX (LECFXB1.F)
C
      ref = 71
      i_err = 0  
C
      len_tmp_name = infile_name_len+len_trim(pch_file)
      tmp_name=infile_name(1:infile_name_len)//pch_file(1:len_trim(pch_file))
      OPEN(unit=ref,file=tmp_name(1:len_tmp_name),
     .      access='SEQUENTIAL',form='FORMATTED',status='UNKNOWN')  
C
      CALL fxrline(ref,nwline,id,titr)
      READ(nwline,'((A,A,5I8,I16))') debut,name,dum,ifo,tin,tout,polar,ncol
C
      IF ((ifo == 6).AND.(tin < 3)) THEN
C
C-------  Symmetric matrix - real (no imaginary part) -----------
C
C       Reading of a new block --
        DO WHILE (i_err == 0)
C
          istop=0
          DO WHILE (istop==0)
            READ(ref,'(A)',END=100) nwline
            IF (nwline(1:5)=='DMIG ') THEN
              READ(nwline,'((A,A,5I8,I16))') debut,name,dum,ifo,tin,tout,polar,ncol
            ELSEIF ((nwline(1:1)/='#').AND.((nwline(1:1)/='$')).AND.((len_trim(nwline)/=0))) THEN
              istop=1
            ENDIF
          ENDDO
C
          READ(nwline,'((A,A,2I16))') debut,matrix_type,id_nod1,i
          id_nod1=usr2sys(id_nod1,itabm1,mess,id)
          IF (id_nod1 /= 0) THEN
            itag(id_nod1) = 1
          ELSE
            RETURN
          ENDIF
C
          CALL fxrline(ref,nwline,id,titr)
C
          IF (adjustl(matrix_type) == 'KAAX') THEN
            DO WHILE (nwline(1:1) == '*')
              READ(nwline,'((A,I16,I16,F16.3))') debut,id_nod2,j,rell
              cpt_stiff = cpt_stiff + 1
              id_nod2=usr2sys(id_nod2,itabm1,mess,id)
              IF (id_nod2 /= 0) THEN
                itag(id_nod2) = 1
                IF (flag == 1) THEN
                  matrix(cpt_stiff-1) = rell
                  matrix_add(1,cpt_stiff-1) = id_nod1   
                  matrix_add(2,cpt_stiff-1) = id_nod2
                  matrix_add(3,cpt_stiff-1) = i 
                  matrix_add(4,cpt_stiff-1) = j 
                ENDIF
              ELSE
                RETURN
              ENDIF   
              READ(ref,'(A)',iostat=i_err,END=100) nwline
            END DO
C
          ELSEIF (adjustl(matrix_type) == 'MAAX') THEN
            DO WHILE (nwline(1:1) == '*')
              READ(nwline,'((A,I16,I16,F16.3))') debut,id_nod2,j,rell
              cpt_mass = cpt_mass + 1
              id_nod2=usr2sys(id_nod2,itabm1,mess,id)
              IF (id_nod2 /= 0) THEN
                IF (flag == 1) THEN
                  matrix(cpt_mass-1) = rell
                  matrix_add(1,cpt_mass-1) = id_nod1   
                  matrix_add(2,cpt_mass-1) = id_nod2
                  matrix_add(3,cpt_mass-1) = i 
                  matrix_add(4,cpt_mass-1) = j 
                ENDIF
              ELSE
                RETURN
              ENDIF   
              READ(ref,'(A)',iostat=i_err,END=100) nwline
            END DO
C
          ELSEIF ((adjustl(matrix_type)=='BAAX').OR.(adjustl(matrix_type)=='PAX').OR.adjustl(matrix_type)=='K4AAX') THEN
C--         Input not compatible
            i_err = 1
            IF (flag == 0) THEN
              CALL ancmsg(msgid=1738,
     .                  msgtype=msgerror,
     .                  anmode=aninfo_blind_1,
     .                  i1=id,
     .                  c1=titr,
     .                  c2=adjustl(matrix_type))
            ENDIF            
C
          ENDIF      
C
          backspace(ref)
C
        END DO
C
100     CONTINUE
C
      ENDIF
C
      CLOSE(unit=ref,status='KEEP')                            
C 
      RETURN     
C
      END SUBROUTINE read_pch_file