read_sensor_gauge.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    read_sensor_gauge          ../starter/source/tools/sensor/read_sensor_gauge.F
!||--- called by ------------------------------------------------------
!||    hm_read_sensors            ../starter/source/tools/sensor/hm_read_sensors.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                     ../starter/source/output/message/message.F
!||    hm_get_float_array_index   ../starter/source/devtools/hm_reader/hm_get_float_array_index.f
!||    hm_get_floatv              ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_int_array_index     ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    hm_get_intv                ../starter/source/devtools/hm_reader/hm_get_intv.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod         ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod                ../starter/share/message_module/message_mod.f
!||    submodel_mod               ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE read_sensor_gauge(SENSOR_PTR ,SENS_ID  ,TITR  ,
     .           LGAUGE   ,UNITAB   ,LSUBMODEL )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------  
      USE unitab_mod
      USE message_mod
      USE submodel_mod
      USE sensor_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: SENS_ID
      INTEGER ,DIMENSION(3,*)    ,INTENT(IN)  :: LGAUGE
      CHARACTER(LEN=NCHARTITLE)::TITR
      TYPE (SENSOR_STR_) :: SENSOR_PTR
      TYPE (SUBMODEL_DATA) ,DIMENSION(NSUBMOD) :: LSUBMODEL
      TYPE (UNIT_TYPE_)    ,INTENT(IN) ::UNITAB 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NGAU,NPARIS,NPARRS,NVAR,SENS_TYPE
      my_real :: tdel
      INTEGER ,DIMENSION(6) :: IGAU,G_ID
      my_real ,DIMENSION(6) :: pres,tmin
      LOGICAL :: IS_AVAILABLE
C--------------------------------
C     SENSOR : PRESSURE GAUGE LIST
C=======================================================================
      is_available = .false.
      sens_type = 10
c--------------------------------------------------
card1
      CALL hm_get_floatv('Tdelay' ,tdel  ,is_available,lsubmodel,unitab)
card2
      CALL hm_get_intv  ('NIP'    ,ngau  ,is_available,lsubmodel)
card3...
      DO i=1,min(ngau,6)
        CALL hm_get_int_array_index  ('GaugeArrayIds',g_id(i),i,is_available,lsubmodel)
        CALL hm_get_float_array_index('Fporp' ,pres(i),i,is_available,lsubmodel,unitab)
        CALL hm_get_float_array_index('Fport' ,tmin(i),i,is_available,lsubmodel,unitab)
      ENDDO
c--------------------------------------------------
      IF (ngau > 6) THEN
         CALL ancmsg(msgid=833, msgtype=msgerror, anmode=aninfo, i1=sens_id,c1=titr)
      ENDIF
c
      DO i=1,ngau
        igau(i) = 0
        DO j = 1,nbgauge
          IF (g_id(i) == lgauge(2,j)) THEN
            igau(i) = j
            EXIT
          ENDIF
        ENDDO
        IF (igau(i) == 0) THEN
          CALL ancmsg(msgid=834, msgtype=msgerror, anmode=aninfo_blind_2,
     .                i1=sens_id, c1=titr)
          EXIT
        END IF
      ENDDO
c--------------------------------------------------
c
      sensor_ptr%TYPE    = sens_type
      sensor_ptr%SENS_ID = sens_id
      sensor_ptr%STATUS  = 0            ! status = deactivated
      sensor_ptr%TSTART  = infinity
      sensor_ptr%TCRIT   = infinity
      sensor_ptr%TMIN    = zero         ! TMIN global
      sensor_ptr%TDELAY  = tdel         ! time delay before activation
      sensor_ptr%VALUE   = zero
 
      nparis = ngau + 1
      nparrs = ngau * 3
      nvar   = 0 
c
      sensor_ptr%NPARI  = nparis
      sensor_ptr%NPARR  = nparrs
      sensor_ptr%NVAR   = nvar
c
      ALLOCATE (sensor_ptr%IPARAM(nparis))
      ALLOCATE (sensor_ptr%RPARAM(nparrs))
      ALLOCATE (sensor_ptr%VAR(nvar))
      sensor_ptr%VAR(:) = zero
c
      sensor_ptr%IPARAM(1) = ngau
      DO i = 1,ngau
        sensor_ptr%IPARAM(i+1) = igau(i)
      END DO
      j = 0
      DO i = 1,ngau
        sensor_ptr%RPARAM(j+1) = pres(i)
        sensor_ptr%RPARAM(j+2) = tmin(i)
        sensor_ptr%RPARAM(j+3) = infinity       
        j = j+3
      END DO    
c------------------------------------------------------------
      WRITE(iout, 1000) sens_id,tdel
      WRITE(iout, 2000) ngau
      DO i = 1,ngau
        WRITE(iout, 3000) g_id(i),pres(i),tmin(i)
      END DO
c------------------------------------------------------------
 1000 FORMAT(
     . 5x,'    sensor TYPE 10: pressure gauge        '/,
     . 5X,'    ------------------------------        '/,
     . 5X,'sensor id. . . . . . . . . . . . . . . . .=',I10/
     . 5X,'time delay before activation . . . . . . .=',E12.4)
 2000 FORMAT(
     . 5X,'number of gauges . . . . . . . . . . . . .=',I10)
 3000 FORMAT(
     . 5X,'   gauge id .  . . . . . . . . . . . . . .=',I10/
     . 5X,'   min pressure for activation . . . . . .=',E12.4/
     . 5X,'   minimum pres. duration for activation .=',E12.4/)
c-----------
      RETURN
      END