relfram_m1.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    relfram_m1   ../engine/source/tools/skew/relfram_m1.F
!||--- called by ------------------------------------------------------
!||    cfield_1     ../engine/source/loads/general/load_centri/cfield.F
!||    cfield_imp   ../engine/source/loads/general/load_centri/cfield_imp.F
!||====================================================================
      SUBROUTINE relfram_m1(XG ,VG      ,AREL    ,XFRAME  ,
     2                      VO      , AO      )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real
     .   xg(3), vg(3), arel(3),
     .   xframe(nxframe),  vo(3), ao(3)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N, K
C     REAL
      my_real
     .   rot(9),rot0(9),rotdt05(9),rott05(9),
     .   omegax, omegay, omegaz, nn, cs, sn, ux, uy, uz,
     .   omegaxx, omegaxy, omegaxz, omegayy, omegayz, omegazz,
     .  o(3), om(3), w(3), dwdt(3), wom(3), ve(3), ae(3), ac(3), om2(3),
     .  dt05, drel(3), vrel(3), ag(3), vrrel(3), arrel(3)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
C      ACTUAL FRAME POSITION & ORIENTATION WRT GLOBAL SYSTEM
C-----------------
C      Frame position at time T (O == position of node N1).
       o(1)=xframe(10)
       o(2)=xframe(11)
       o(3)=xframe(12)
C-----------
C      ANGULAR VELOCITY at time T-1/2 and acceleration at time T.
C-----------
       w(1)=xframe(13)
       w(2)=xframe(14)
       w(3)=xframe(15)          
C-----------
C      local coordinates.
C-----------
       om(1)=xg(1)-o(1)
       om(2)=xg(2)-o(2)
       om(3)=xg(3)-o(3)   
C-----------
C      vitesse d'entrainement (T-1/2).
C-----------
       dt05=0.5*dt1
       om2(1)=om(1)-dt05*(vg(1)-vo(1))
       om2(2)=om(2)-dt05*(vg(2)-vo(2))
       om2(3)=om(3)-dt05*(vg(3)-vo(3))
       wom(1)=w(2)*om2(3)-w(3)*om2(2)
       wom(2)=w(3)*om2(1)-w(1)*om2(3)
       wom(3)=w(1)*om2(2)-w(2)*om2(1)
       ve(1)=vo(1)+wom(1)
       ve(2)=vo(2)+wom(2)
       ve(3)=vo(3)+wom(3)
C-----------
C      relative velocity in global frame at time T-1/2.
C-----------
       vrel(1)=vg(1)-ve(1)
       vrel(2)=vg(2)-ve(2)
       vrel(3)=vg(3)-ve(3)
C-----------
C      RELATIVE ACCELERATIONS.
C-----------
       dwdt(1)=xframe(16)
       dwdt(2)=xframe(17)
       dwdt(3)=xframe(18) 
C      second order correction.
C      W(1)=W(1)+DWDT(1)*DT05
C      W(2)=W(2)+DWDT(2)*DT05
C      W(3)=W(3)+DWDT(3)*DT05
C-----------
C      acceleration d'entrainement.
C-----------
       wom(1)=w(2)*om(3)-w(3)*om(2)
       wom(2)=w(3)*om(1)-w(1)*om(3)
       wom(3)=w(1)*om(2)-w(2)*om(1)
       ae(1)=ao(1)+dwdt(2)*om(3)-dwdt(3)*om(2)
     .            +w(2)*wom(3)-w(3)*wom(2)
       ae(2)=ao(2)+dwdt(3)*om(1)-dwdt(1)*om(3)
     .            +w(3)*wom(1)-w(1)*wom(3)
       ae(3)=ao(3)+dwdt(1)*om(2)-dwdt(2)*om(1)
     .            +w(1)*wom(2)-w(2)*wom(1)
C-----------
C      acceleration de Coriolis.
C-----------
C      second order correction.
C      vitesse d'entrainement (T).
C      VE(1)=VO(1)+WOM(1)
C      VE(2)=VO(2)+WOM(2)
C      VE(3)=VO(3)+WOM(3)
C      relative velocity in global frame at time T.
C      VREL(1)=VG(1)-VE(1)
C      VREL(2)=VG(2)-VE(2)
C      VREL(3)=VG(3)-VE(3)
       ac(1)=2.*(w(2)*vrel(3)-w(3)*vrel(2))
       ac(2)=2.*(w(3)*vrel(1)-w(1)*vrel(3))
       ac(3)=2.*(w(1)*vrel(2)-w(2)*vrel(1))
C-----------
C      relative acceleration in global frame at time T.
C-----------
       arel(1)=arel(1)+ae(1)+ac(1)
       arel(2)=arel(2)+ae(2)+ac(2)
       arel(3)=arel(3)+ae(3)+ac(3)
C-----------------------------------------------
 999  CONTINUE
      RETURN
      END