reordr.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    reordr         ../starter/source/elements/solid_2d/quad/reordr.F
!||--- called by ------------------------------------------------------
!||    lce16q3        ../starter/source/elements/solid_2d/quad/lce16q.F
!||    lce16s3        ../starter/source/elements/reader/hm_read_solid.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE reordr(IX, NX, NEL, PM, IPOINT, IPARTS, NGRELE, IGRELEM, NUMMAT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "tablen_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: NX, NEL,NGRELE
      INTEGER :: IX(NX,NEL), IPOINT(2,*),IPARTS(*)
      INTEGER, INTENT(IN) :: NUMMAT
      my_real :: pm(npropm,nummat)
C-----------------------------------------------
      TYPE (GROUP_)  , DIMENSION(NGRELE) :: IGRELEM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IADR(0:MAXLAW+1), NL, M, I, MLAWP1, MT, MLAW, J,K,N,IAD
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      nl=maxlaw
      DO m=0,nl+1
        iadr(m)=0
      ENDDO
C---------------------------------------
C     NUMBER OF ELEMS FOR EACH MATERIAL LAW
C---------------------------------------
      DO i=1,nel
       IF(ix(1,i)<0) THEN
         mlawp1=17+1
       ELSE
         mt=ix(1,i)
         mlawp1=nint(pm(19,mt))+1
       ENDIF
       iadr(mlawp1)=iadr(mlawp1)+1
      ENDDO
C------------------------------------------
C     ELEM ADDRESSE FOR EACH MATERIAL LAW
C     SKIPPING LAW11
C------------------------------------------
      iadr(11+1)=0
      DO m=1,nl
        iadr(m)=iadr(m)+iadr(m-1)
      ENDDO
      iadr(11)=iadr(nl+1)+iadr(nl)
C--------------------------------------------------
C     CALL POINTER FOR EACH MLW
C--------------------------------------------------
      DO i=1,nel
        IF(ix(1,i)<0) THEN
          mlaw=17
        ELSE
          mt=ix(1,i)
          mlaw=nint(pm(19,mt))
        ENDIF
        iadr(mlaw)=iadr(mlaw)+1
        ipoint(1,i)=iadr(mlaw)
      END DO
C------------------------------------------
C     PERUMTATING ELEMS USING LAWS
C------------------------------------------
      DO j=1,nx
        DO i=1,nel
          ipoint(2,i)=ix(j,i)
        END DO
        DO i=1,nel
          ix(j,ipoint(1,i))=ipoint(2,i)
        END DO
      ENDDO
C------------------------------------------
C     PERMUTATING PARTS
C------------------------------------------
      DO i=1,nel
        ipoint(2,i)=iparts(i)
      ENDDO
      DO i=1,nel
        iparts(ipoint(1,i))=ipoint(2,i)
      ENDDO
C------------------------------------------
C     RRENUMBERING ELEMS INSIDE GROUPS
C------------------------------------------
      DO k=1,ngrele
        n = igrelem(k)%NENTITY
        DO i=1,n
          IF (igrelem(k)%ENTITY(i)<=nel)igrelem(k)%ENTITY(i) = ipoint(1,igrelem(k)%ENTITY(i))
        ENDDO
      ENDDO
C------------------------------------------
      RETURN
      END