s10defo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s10defo3   ../engine/source/elements/solid/solide10/s10defo3.F
!||--- called by ------------------------------------------------------
!||    s10forc3   ../engine/source/elements/solid/solide10/s10forc3.F
!||====================================================================
      SUBROUTINE s10defo3(
     1   PX,      PY,      PZ,      VX,
     2   VY,      VZ,      DXX,     DXY,
     3   DXZ,     DYX,     DYY,     DYZ,
     4   DZX,     DZY,     DZZ,     D4,
     5   D5,      D6,      WXX,     WYY,
     6   WZZ,     VOLP,    VOLN,    RHO,
     7   RHOO,    NEL,     JHBE,    ISROT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JHBE
      INTEGER, INTENT(IN) :: ISROT
C     REAL
      my_real
     .  VX(MVSIZ,10),VY(MVSIZ,10),VZ(MVSIZ,10),
     .  PX(MVSIZ,10),PY(MVSIZ,10),PZ(MVSIZ,10),
     .   dxx(*), dxy(*), dxz(*),
     .   dyx(*), dyy(*), dyz(*),
     .   dzx(*), dzy(*), dzz(*), d4(*), d5(*), d6(*),
     .   wxx(*), wyy(*), wzz(*),volp(*),voln(*),rho(*),
     .  rhoo(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I,N
C     REAL
      my_real
     .   DT1D2
      my_real 
     .   PXX2,PYY2,PZZ2,PXX2P,PYY2P,PZZ2P,AAA,BBB
C-----------------------------------------------
C   
      IF(isrot /= 1)THEN                                                                 
        DO i=1,nel
          voln(i)=volp(i)
          rhoo(i)=rho(i)
        ENDDO
      ELSE
        DO i=1,nel
c          VOLN(I)=VOLP(I)
          rhoo(i)=rho(i)
        ENDDO
      ENDIF
      DO i=1,nel
       dxx(i)=px(i,1)*vx(i,1)+px(i,2)*vx(i,2)+px(i,3)*vx(i,3)+px(i,4)*vx(i,4)+px(i,5)*vx(i,5)
     .         +px(i,6)*vx(i,6)+px(i,7)*vx(i,7)+px(i,8)*vx(i,8)+px(i,9)*vx(i,9)+px(i,10)*vx(i,10)
       dyy(i)=py(i,1)*vy(i,1)+py(i,2)*vy(i,2)+py(i,3)*vy(i,3)+py(i,4)*vy(i,4)+py(i,5)*vy(i,5)
     .         +py(i,6)*vy(i,6)+py(i,7)*vy(i,7)+py(i,8)*vy(i,8)+py(i,9)*vy(i,9)+py(i,10)*vy(i,10)
       dzz(i)=pz(i,1)*vz(i,1)+pz(i,2)*vz(i,2)+pz(i,3)*vz(i,3)+pz(i,4)*vz(i,4)+pz(i,5)*vz(i,5)
     .         +pz(i,6)*vz(i,6)+pz(i,7)*vz(i,7)+pz(i,8)*vz(i,8)+pz(i,9)*vz(i,9)+pz(i,10)*vz(i,10)
       dxy(i)=py(i,1)*vx(i,1)+py(i,2)*vx(i,2)+py(i,3)*vx(i,3)+py(i,4)*vx(i,4)+py(i,5)*vx(i,5)
     .         +py(i,6)*vx(i,6)+py(i,7)*vx(i,7)+py(i,8)*vx(i,8)+py(i,9)*vx(i,9)+py(i,10)*vx(i,10)
       dxz(i)=pz(i,1)*vx(i,1)+pz(i,2)*vx(i,2)+pz(i,3)*vx(i,3)+pz(i,4)*vx(i,4)+pz(i,5)*vx(i,5)
     .         +pz(i,6)*vx(i,6)+pz(i,7)*vx(i,7)+pz(i,8)*vx(i,8)+pz(i,9)*vx(i,9)+pz(i,10)*vx(i,10)
       dyx(i)=px(i,1)*vy(i,1)+px(i,2)*vy(i,2)+px(i,3)*vy(i,3)+px(i,4)*vy(i,4)+px(i,5)*vy(i,5)
     .         +px(i,6)*vy(i,6)+px(i,7)*vy(i,7)+px(i,8)*vy(i,8)+px(i,9)*vy(i,9)+px(i,10)*vy(i,10)
       dyz(i)=pz(i,1)*vy(i,1)+pz(i,2)*vy(i,2)+pz(i,3)*vy(i,3)+pz(i,4)*vy(i,4)+pz(i,5)*vy(i,5)
     .         +pz(i,6)*vy(i,6)+pz(i,7)*vy(i,7)+pz(i,8)*vy(i,8)+pz(i,9)*vy(i,9)+pz(i,10)*vy(i,10)
       dzx(i)=px(i,1)*vz(i,1)+px(i,2)*vz(i,2)+px(i,3)*vz(i,3)+px(i,4)*vz(i,4)+px(i,5)*vz(i,5)
     .         +px(i,6)*vz(i,6)+px(i,7)*vz(i,7)+px(i,8)*vz(i,8)+px(i,9)*vz(i,9)+px(i,10)*vz(i,10)
       dzy(i)=py(i,1)*vz(i,1)+py(i,2)*vz(i,2)+py(i,3)*vz(i,3)+py(i,4)*vz(i,4)+py(i,5)*vz(i,5)
     .         +py(i,6)*vz(i,6)+py(i,7)*vz(i,7)+py(i,8)*vz(i,8)+py(i,9)*vz(i,9)+py(i,10)*vz(i,10)
      ENDDO
C
      dt1d2=half*dt1
C
      IF(jhbe>=2)THEN
        DO i=1,nel
         dxx(i)  = dxx(i)
     .            -dt1d2*(dxx(i)*dxx(i)+dyx(i)*dyx(i)+dzx(i)*dzx(i))
         dyy(i)  = dyy(i)
     .            -dt1d2*(dyy(i)*dyy(i)+dzy(i)*dzy(i)+dxy(i)*dxy(i))
         dzz(i)  = dzz(i)
     .            -dt1d2*(dzz(i)*dzz(i)+dxz(i)*dxz(i)+dyz(i)*dyz(i))
         aaa = dt1d2*(dxx(i)*dxy(i)+dyx(i)*dyy(i)+dzx(i)*dzy(i))
         dxy(i)  = dxy(i) - aaa
         dyx(i)  = dyx(i) - aaa
         d4(i)   = dxy(i)+dyx(i)
         aaa = dt1d2*(dyy(i)*dyz(i)+dzy(i)*dzz(i)+dxy(i)*dxz(i))
         dyz(i)  = dyz(i) - aaa
         dzy(i)  = dzy(i) - aaa
         d5(i)   = dyz(i)+dzy(i)
         aaa = dt1d2*(dzz(i)*dzx(i)+dxz(i)*dxx(i)+dyz(i)*dyx(i))
         dxz(i)  = dxz(i) - aaa
         dzx(i)  = dzx(i) - aaa
         d6(i)   = dxz(i)+dzx(i)
!
         n = 1
         pxx2 = px(i,n)*px(i,n)
         pyy2 = py(i,n)*py(i,n)
         pzz2 = pz(i,n)*pz(i,n)
         DO n=2,10
           pxx2 = pxx2+px(i,n)*px(i,n)
           pyy2 = pyy2+py(i,n)*py(i,n)
           pzz2 = pzz2+pz(i,n)*pz(i,n)
         END DO
         wzz(i)=dt1*(pyy2*dyx(i)-pxx2*dxy(i))/(pxx2+pyy2)
         wxx(i)=dt1*(pzz2*dzy(i)-pyy2*dyz(i))/(pyy2+pzz2)
         wyy(i)=dt1*(pxx2*dxz(i)-pzz2*dzx(i))/(pzz2+pxx2)
        ENDDO
      ELSE !IF(JHBE>=2)
        DO i=1,nel
         d4(i)   =dxy(i)+dyx(i)
         d5(i)   =dyz(i)+dzy(i)
         d6(i)   =dxz(i)+dzx(i)
         wzz(i)=dt1d2*(dyx(i)-dxy(i))
         wyy(i)=dt1d2*(dxz(i)-dzx(i))
         wxx(i)=dt1d2*(dzy(i)-dyz(i))
        ENDDO
      END IF
C
      RETURN
C
      END