s10mallgeo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s10mallgeo3   ../engine/source/elements/solid/solide10/s10mallgeo3.F
!||--- called by ------------------------------------------------------
!||    s10forc3      ../engine/source/elements/solid/solide10/s10forc3.f
!||--- uses       -----------------------------------------------------
!||    dt_mod        ../engine/source/modules/dt_mod.F
!||====================================================================
      SUBROUTINE s10mallgeo3(
     1   NGL,     OFFG,    VOLG,    DELTAX,
     2   VOLG0,   RX,      RY,      RZ,
     3   SX,      SY,      SZ,      TX,
     4   TY,      TZ,      LC,     GEO,    
     5   NEL,     NPT, ISMSTR,  ISROT,DT )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE dt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: NPT
      INTEGER, INTENT(IN) :: ISMSTR
      INTEGER, INTENT(IN) :: ISROT
      INTEGER NGL(*)
C     REAL
      my_real, DIMENSION(NPROPG) , INTENT(IN)  :: geo 
      my_real, DIMENSION(MVSIZ) , INTENT(OUT)  :: lc 
      my_real
     .   offg(*),volg(*),deltax(*), volg0(*),
     .   rx(*), ry(*), rz(*), sx(*), sy(*), sz(*),tx(*), ty(*), tz(*)
      TYPE(dt_), INTENT(INOUT) :: DT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,ITET,IDELM,ICST
      my_real
     .   a1,a2,a3,a4,
     .   a1x,a2x,a3x,a4x,a1y,a2y,a3y,a4y,a1z,a2z,a3z,a4z,
     .   vdefmin,vdefmax,aspmin,asptet,min_aspect,min_defv,delm
C---------------------------------------------
      min_aspect = dt%BRICK_CST_COL_MIN
      min_defv = dt%BRICK_CST_DEFV_MIN
      vdefmin = geo(190)
      vdefmax = geo(191)
      aspmin  = geo(192)
      asptet  = geo(193)
      delm = vdefmin +vdefmax+aspmin+asptet
      icst = 1
      IF((min_aspect+min_defv)==zero.AND.
     .   (ismstr==1.OR.ismstr==3.OR.ismstr==11)) icst=0
      idelm = 1
      idelm = dt%IDEL_BRICK
      IF(idelm ==0.AND.delm==zero) idelm = 0
      IF((idelm+icst) >0) THEN
        IF(isrot /= 1)THEN
          DO i=1,nel
            a1x = ry(i)*sz(i)-rz(i)*sy(i)
            a1y = rz(i)*sx(i)-rx(i)*sz(i)
            a1z = rx(i)*sy(i)-ry(i)*sx(i)
            a1 = a1x*a1x+a1y*a1y+a1z*a1z
        
            a2x = sy(i)*tz(i)-sz(i)*ty(i)
            a2y = sz(i)*tx(i)-sx(i)*tz(i)
            a2z = sx(i)*ty(i)-sy(i)*tx(i)
            a2 = a2x*a2x+a2y*a2y+a2z*a2z
        
            a3x = ty(i)*rz(i)-tz(i)*ry(i)
            a3y = tz(i)*rx(i)-tx(i)*rz(i)
            a3z = tx(i)*ry(i)-ty(i)*rx(i)
            a3 = a3x*a3x+a3y*a3y+a3z*a3z
        
            a4x = a1x+a2x+a3x
            a4y = a1y+a2y+a3y
            a4z = a1z+a2z+a3z
            a4 = a4x*a4x+a4y*a4y+a4z*a4z
        
            lc(i) = six*volg(i)/sqrt(max(a1,a2,a3,a4))
          END DO
        ELSE
          DO i=1,nel
           lc(i) = deltax(i)
          END DO
        END IF ! (ISROT == 0)THEN
      END IF ! ((IDELM+ICST) >0) THEN
C      
      RETURN
      END