s4alesfem.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s4alesfem         ../engine/source/elements/solid/solide4_sfem/s4alesfem.f
!||--- called by ------------------------------------------------------
!||    alemain           ../engine/source/ale/alemain.F
!||--- calls      -----------------------------------------------------
!||    foat_to_6_float   ../engine/source/system/parit.F
!||    initbuf           ../engine/share/resol/initbuf.F
!||    s4volnod3         ../engine/source/elements/solid/solide4_sfem/s4volnod3.F
!||    spmd_exch_vol     ../engine/source/mpi/nodes/spmd_exch_vol.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod      ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    initbuf_mod       ../engine/share/resol/initbuf.F
!||====================================================================
      SUBROUTINE s4alesfem(IPARG,IXS,X,ELBUF_TAB,SFEM_NODVAR, S_SFEM_NODVAR,PM,
     .                     IAD_ELEM,FR_ELEM)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE initbuf_mod
      USE elbufdef_mod         
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: S_SFEM_NODVAR
      INTEGER IXS(NIXS,*),IPARG(NPARG,*),IAD_ELEM(2,*),FR_ELEM(*)
      my_real x(*),sfem_nodvar(s_sfem_nodvar),pm(npropm,*)
      TYPE (ELBUF_STRUCT_), TARGET, DIMENSION(NGROUP) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NG, I, J, I1, I2, I3, I4, K, LENR,NEL
      INTEGER NC1(MVSIZ),NC2(MVSIZ),NC3(MVSIZ),NC4(MVSIZ)
      INTEGER MAT(MVSIZ)
      my_real mass(mvsiz)
 
      DOUBLE PRECISION VARNOD6(6,2*NUMNOD), MASS6(6,MVSIZ)
C
      TYPE(g_bufel_) ,POINTER :: GBUF
C
      sfem_nodvar(1:2*numnod) = zero
      varnod6(1:6,1:2*numnod) = zero
      mass(1:mvsiz)           = zero
      mass6(1:6,1:mvsiz)      = zero
C----------------------------------------------------
C     COMPUTE NODAL VOLUME & MASS FOR ALL TETRAHEDRON
C----------------------------------------------------
C Boucle parallele dynamique SMP
C
      DO ng = 1,ngroup
        IF(iparg(8, ng)==1) cycle
        IF(iparg(28,ng)/=4) cycle
        CALL initbuf(iparg    ,ng      ,
     2        mtn     ,llt     ,nft     ,iad     ,ity     ,
     3        npt     ,jale    ,ismstr  ,jeul    ,jtur    ,
     4        jthe    ,jlag    ,jmult   ,jhbe    ,jivf    ,
     5        nvaux   ,jpor    ,jcvt    ,jclose  ,jplasol ,
     6        irep    ,iint    ,igtyp   ,israt   ,isrot   ,
     7        icsen   ,isorth  ,isorthg ,ifailure,jsms    )
C
        IF(jeul  == 1) cycle
        IF(jlag == 1) cycle
        IF(isrot <= 2) cycle
        lft=1
        nel = llt
C
        DO i=lft,llt
         j=i+nft
         mat(i)=ixs(1,j)
         nc1(i)=ixs(2,j)
         nc2(i)=ixs(4,j)
         nc3(i)=ixs(7,j)
         nc4(i)=ixs(6,j)
        ENDDO
C
        gbuf => elbuf_tab(ng)%GBUF
        IF(isrot == 3) THEN
          CALL s4volnod3(
     1   varnod6,   x,         nc1,       nc2,
     2   nc3,       nc4,       gbuf%OFF,  gbuf%SMSTR,
     3   nel,       ismstr)
          DO i=lft,llt
            mass(i)=gbuf%RHO(i)/pm(1,mat(i))
          ENDDO
          !Parith-On treatment
          CALL foat_to_6_float(lft  ,llt  ,mass ,mass6 )
          DO i=lft,llt
            i1=nc1(i)+numnod
            i2=nc2(i)+numnod
            i3=nc3(i)+numnod
            i4=nc4(i)+numnod
            !Parith-On treatment
            DO k=1,6
              varnod6(k,i1) = varnod6(k,i1) + mass6(k,i)
              varnod6(k,i2) = varnod6(k,i2) + mass6(k,i)
              varnod6(k,i3) = varnod6(k,i3) + mass6(k,i)
              varnod6(k,i4) = varnod6(k,i4) + mass6(k,i)
            ENDDO
          ENDDO
        ENDIF !ISROT=3
 
      ENDDO !DO=1,NG
 
c EXCHANGE
      IF(nspmd > 1)THEN
        lenr = 2*(iad_elem(1,nspmd+1)-iad_elem(1,1))
        CALL spmd_exch_vol(varnod6(1,1),varnod6(1,numnod+1),iad_elem,
     .                     fr_elem, lenr )  
      ENDIF
 
C Routine assembly PARITH/ON
      DO i=1,numnod
 
         j=i+numnod
         DO k=1,6
          !VOLNOD
           sfem_nodvar(i)        = sfem_nodvar(i)        + varnod6(k,i)
          !SFEM_NODVAR
           sfem_nodvar(i+numnod) = sfem_nodvar(i+numnod) + varnod6(k,i+numnod)
         ENDDO
 
         !RHO0/RHO -> SFEM_NODVAR
         IF(sfem_nodvar(j) /= 0)THEN
           sfem_nodvar(i)=sfem_nodvar(i)/sfem_nodvar(j)
         ENDIF
      ENDDO
C
      RETURN
      END