s4jac_i.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s4jac_i       ../engine/source/elements/solid/solide4/s4jac_i.F
!||--- called by ------------------------------------------------------
!||    s4upd11t12    ../engine/source/elements/solid/solide4/s4upd11t12.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../engine/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE s4jac_i(
     .              X1   ,X2   ,X3   ,X4   ,
     .              Y1   ,Y2   ,Y3   ,Y4   ,
     .              Z1   ,Z2   ,Z3   ,Z4   ,
     .              JAC_I,NEL  )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL
      my_real
     .   JAC_I(10,*)
      DOUBLE PRECISION
     .   x1(*), x2(*), x3(*), x4(*), 
     .   y1(*), y2(*), y3(*), y4(*), 
     .   z1(*), z2(*), z3(*), z4(*) 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .   B1(MVSIZ), B2(MVSIZ), B3(MVSIZ), B4(MVSIZ), 
     .   C1(MVSIZ), C2(MVSIZ), C3(MVSIZ), C4(MVSIZ),
     .   d1(mvsiz), d2(mvsiz), d3(mvsiz), d4(mvsiz),vol(mvsiz)
      double precision
     .   x41, y41, z41, x42, y42, z42, x43, y43, z43,b1dp,c1dp,d1dp,voldp
      my_real
     .   d ,px1,px2,px3,px4,py1,py2,py3,py4,pz1,pz2,pz3,pz4
C=======================================================================
      DO i=1,nel
       x43 = x4(i) - x3(i)
       y43 = y4(i) - y3(i)
       z43 = z4(i) - z3(i)
       x41 = x4(i) - x1(i)
       y41 = y4(i) - y1(i)
       z41 = z4(i) - z1(i)
       x42 = x4(i) - x2(i)
       y42 = y4(i) - y2(i)
       z42 = z4(i) - z2(i)
C
       b1dp  =  y43*z42 - y42*z43
       b1(i) =  b1dp
       b2(i) =  y41*z43 - y43*z41
       b3(i) =  y42*z41 - y41*z42
       b4(i) =  -(b1(i) + b2(i) + b3(i))
C
       c1dp  =  z43*x42 - z42*x43
       c1(i) =  c1dp
       c2(i) =  z41*x43 - z43*x41
       c3(i) =  z42*x41 - z41*x42
       c4(i) =  -(c1(i) + c2(i) + c3(i))
C
       d1dp  =  x43*y42 - x42*y43
       d1(i) =  d1dp
       d2(i) =  x41*y43 - x43*y41
       d3(i) =  x42*y41 - x41*y42
       d4(i) =  -(d1(i) + d2(i) + d3(i))
C
       voldp = (x41*b1dp + y41*c1dp + z41*d1dp)*one_over_6
       vol(i) = voldp
      ENDDO
C
      DO i=1,nel
        d = one/vol(i)/six
        px1=-b1(i)*d
        py1=-c1(i)*d
        pz1=-d1(i)*d
        px2=-b2(i)*d
        py2=-c2(i)*d
        pz2=-d2(i)*d
        px3=-b3(i)*d
        py3=-c3(i)*d
        pz3=-d3(i)*d
        px4=-b4(i)*d
        py4=-c4(i)*d
        pz4=-d4(i)*d
        jac_i(1,i) = px1
        jac_i(2,i) = px2
        jac_i(3,i) = px3
        jac_i(4,i) = py1
        jac_i(5,i) = py2
        jac_i(6,i) = py3
        jac_i(7,i) = pz1
        jac_i(8,i) = pz2
        jac_i(9,i) = pz3
        jac_i(10,i) = vol(i)
      ENDDO
C-----------
      RETURN
      END