s4therm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s4therm   ../engine/source/elements/solid/solide4/s4therm.F
!||--- called by ------------------------------------------------------
!||    s4forc3   ../engine/source/elements/solid/solide4/s4forc3.f
!||====================================================================
      SUBROUTINE s4therm(
     1   PM,      IMAT,     VOL,     NC1,
     2   NC2,     NC3,     NC4,     PX1,
     3   PX2,     PX3,     PX4,     PY1,
     4   PY2,     PY3,     PY4,     PZ1,
     5   PZ2,     PZ3,     PZ4,     DT1,
     6   TEMPNC,  TEL,     HEAT,     FPHI,
     7   OFFG,    OFF,     NEL ,THEACCFACT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: IMAT
      INTEGER NC1(*),NC2(*),NC3(*),NC4(*)
      my_real, INTENT(IN) :: THEACCFACT
      my_real
     .    VOL(*), PX1(*), PX2(*), PX3(*), PX4(*), 
     .    PY1(*), PY2(*), PY3(*), PY4(*),
     .    pz1(*), pz2(*), pz3(*), pz4(*),
     .    tempnc(*), fphi(mvsiz,4), pm(npropm,*),heat(*),
     .    dt1,tel(*),off(*),offg(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .  CA, CB, KC, PHIX, PHIY, PHIZ, A
C===================================================================
 
        CA = pm(75,imat)
        cb = pm(76,imat)
        DO i=1,nel
          IF(off(i)==zero.OR.offg(i)<=zero) cycle
 
C 
C - flux
C      
          phix =  tempnc(nc1(i))*px1(i) + tempnc(nc2(i))*px2(i)  +
     .            tempnc(nc3(i))*px3(i) + tempnc(nc4(i))*px4(i)      
          
          phiy =  tempnc(nc1(i))*py1(i) + tempnc(nc2(i))*py2(i)  +
     .            tempnc(nc3(i))*py3(i) + tempnc(nc4(i))*py4(i)  
      
          phiz =  tempnc(nc1(i))*pz1(i) + tempnc(nc2(i))*pz2(i)  +
     .            tempnc(nc3(i))*pz3(i) + tempnc(nc4(i))*pz4(i)        
C      
          kc = (ca + cb*tel(i))*dt1*vol(i)*theaccfact
          phix = kc*phix
          phiy = kc*phiy
          phiz = kc*phiz
C
C nodal thermal force
C
          a = fourth* heat(i)
          fphi(i,1) = a - (phix*px1(i) + phiy*py1(i) + pz1(i)*phiz)
          fphi(i,2) = a - (phix*px2(i) + phiy*py2(i) + pz2(i)*phiz)
          fphi(i,3) = a - (phix*px3(i) + phiy*py3(i) + pz3(i)*phiz)
          fphi(i,4) = a - (phix*px4(i) + phiy*py4(i) + pz4(i)*phiz)
       ENDDO
C 
      RETURN
      END