s8edefot3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s8edefot3   ../engine/source/elements/solid/solide8e/s8edefot3.F
!||--- called by ------------------------------------------------------
!||    s8eforc3    ../engine/source/elements/solid/solide8e/s8eforc3.F
!||--- calls      -----------------------------------------------------
!||    jacob_j33   ../engine/source/elements/solid/solide8e/jacob_j33.F
!||====================================================================
      SUBROUTINE s8edefot3(
     1   PX1,     PX2,     PX3,     PX4,
     2   PX5,     PX6,     PX7,     PX8,
     3   PY1,     PY2,     PY3,     PY4,
     4   PY5,     PY6,     PY7,     PY8,
     5   PZ1,     PZ2,     PZ3,     PZ4,
     6   PZ5,     PZ6,     PZ7,     PZ8,
     7   BXY1,    BXY2,    BXY3,    BXY4,
     8   BXY5,    BXY6,    BXY7,    BXY8,
     9   BYX1,    BYX2,    BYX3,    BYX4,
     A   BYX5,    BYX6,    BYX7,    BYX8,
     B   BXZ1,    BXZ2,    BXZ3,    BXZ4,
     C   BXZ5,    BXZ6,    BXZ7,    BXZ8,
     D   BZX1,    BZX2,    BZX3,    BZX4,
     E   BZX5,    BZX6,    BZX7,    BZX8,
     F   BYZ1,    BYZ2,    BYZ3,    BYZ4,
     G   BYZ5,    BYZ6,    BYZ7,    BYZ8,
     H   BZY1,    BZY2,    BZY3,    BZY4,
     I   BZY5,    BZY6,    BZY7,    BZY8,
     J   BXX1,    BXX2,    BXX3,    BXX4,
     K   BXX5,    BXX6,    BXX7,    BXX8,
     L   BYY1,    BYY2,    BYY3,    BYY4,
     M   BYY5,    BYY6,    BYY7,    BYY8,
     N   BZZ1,    BZZ2,    BZZ3,    BZZ4,
     O   BZZ5,    BZZ6,    BZZ7,    BZZ8,
     P   PXY1,    PXY2,    PXY3,    PXY4,
     Q   PXY5,    PXY6,    PXY7,    PXY8,
     R   PYX1,    PYX2,    PYX3,    PYX4,
     S   PYX5,    PYX6,    PYX7,    PYX8,
     T   PXZ1,    PXZ2,    PXZ3,    PXZ4,
     U   PXZ5,    PXZ6,    PXZ7,    PXZ8,
     V   PZX1,    PZX2,    PZX3,    PZX4,
     W   PZX5,    PZX6,    PZX7,    PZX8,
     X   PYZ1,    PYZ2,    PYZ3,    PYZ4,
     Y   PYZ5,    PYZ6,    PYZ7,    PYZ8,
     Z   PZY1,    PZY2,    PZY3,    PZY4,
     1   PZY5,    PZY6,    PZY7,    PZY8,
     2   VX1,     VX2,     VX3,     VX4,
     3   VX5,     VX6,     VX7,     VX8,
     4   VY1,     VY2,     VY3,     VY4,
     5   VY5,     VY6,     VY7,     VY8,
     6   VZ1,     VZ2,     VZ3,     VZ4,
     7   VZ5,     VZ6,     VZ7,     VZ8,
     8   DXX,     DXY,     DXZ,     DYX,
     9   DYY,     DYZ,     DZX,     DZY,
     A   DZZ,     ICP,     DET0,    JFAC,
     B   NU,      I_SH,    IDEGE,   DXX_A,
     C   DYY_A,   DZZ_A,   OFFG,    NEL,
     D   ISMSTR,  MTN,     DIV0)
C                                                                     12
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: ISMSTR,MTN
      INTEGER ICP,I_SH,IDEGE(*)
C     REAL
      my_real
     .   VX1(*), VX2(*), VX3(*), VX4(*), VX5(*), VX6(*), VX7(*), VX8(*),
     .   VY1(*), VY2(*), VY3(*), VY4(*), VY5(*), VY6(*), VY7(*), VY8(*),
     .   VZ1(*), VZ2(*), VZ3(*), VZ4(*), VZ5(*), VZ6(*), VZ7(*), VZ8(*),
     .   PX1(*), PX2(*), PX3(*), PX4(*),
     .   PX5(*), PX6(*), PX7(*), PX8(*),
     .   PY1(*), PY2(*), PY3(*), PY4(*),
     .   PY5(*), PY6(*), PY7(*), PY8(*),
     .   PZ1(*), PZ2(*), PZ3(*), PZ4(*), 
     .   PZ5(*), PZ6(*), PZ7(*), PZ8(*),
     .   DXX(*), DXY(*), DXZ(*),
     .   DYX(*), DYY(*), DYZ(*),
     .   DZX(*), DZY(*), DZZ(*),DXX_A(*),DYY_A(*),DZZ_A(*),
     .   PXY1(MVSIZ),PXY2(MVSIZ),PXY3(MVSIZ),PXY4(MVSIZ),
     .   PXY5(MVSIZ),PXY6(MVSIZ),PXY7(MVSIZ),PXY8(MVSIZ),
     .   PYX1(MVSIZ),PYX2(MVSIZ),PYX3(MVSIZ),PYX4(MVSIZ),
     .   PYX5(MVSIZ),PYX6(MVSIZ),PYX7(MVSIZ),PYX8(MVSIZ),
     .   PXZ1(MVSIZ),PXZ2(MVSIZ),PXZ3(MVSIZ),PXZ4(MVSIZ),
     .   PXZ5(MVSIZ),PXZ6(MVSIZ),PXZ7(MVSIZ),PXZ8(MVSIZ),
     .   PZX1(MVSIZ),PZX2(MVSIZ),PZX3(MVSIZ),PZX4(MVSIZ),
     .   PZX5(MVSIZ),PZX6(MVSIZ),PZX7(MVSIZ),PZX8(MVSIZ),
     .   PYZ1(MVSIZ),PYZ2(MVSIZ),PYZ3(MVSIZ),PYZ4(MVSIZ),
     .   PYZ5(MVSIZ),PYZ6(MVSIZ),PYZ7(MVSIZ),PYZ8(MVSIZ),
     .   PZY1(MVSIZ),PZY2(MVSIZ),PZY3(MVSIZ),PZY4(MVSIZ),
     .   PZY5(MVSIZ),PZY6(MVSIZ),PZY7(MVSIZ),PZY8(MVSIZ),
     .   BXY1(*),BXY2(*),BXY3(*),BXY4(*),
     .   BXY5(*),BXY6(*),BXY7(*),BXY8(*),
     .   BYX1(*),BYX2(*),BYX3(*),BYX4(*),
     .   BYX5(*),BYX6(*),BYX7(*),BYX8(*),
     .   BXZ1(*),BXZ2(*),BXZ3(*),BXZ4(*),
     .   BXZ5(*),BXZ6(*),BXZ7(*),BXZ8(*),
     .   BZX1(*),BZX2(*),BZX3(*),BZX4(*),
     .   BZX5(*),BZX6(*),BZX7(*),BZX8(*),
     .   BYZ1(*),BYZ2(*),BYZ3(*),BYZ4(*),
     .   BYZ5(*),BYZ6(*),BYZ7(*),BYZ8(*),
     .   BZY1(*),BZY2(*),BZY3(*),BZY4(*),
     .   BZY5(*),BZY6(*),BZY7(*),BZY8(*),
     .   BXX1(*),BXX2(*),BXX3(*),BXX4(*),
     .   BXX5(*),BXX6(*),BXX7(*),BXX8(*),
     .   BYY1(*),BYY2(*),BYY3(*),BYY4(*),
     .   BYY5(*),BYY6(*),BYY7(*),BYY8(*),
     .   BZZ1(*),BZZ2(*),BZZ3(*),BZZ4(*),
     .   BZZ5(*),BZZ6(*),BZZ7(*),BZZ8(*),DET0(*),JFAC(*),NU(*),OFFG(*)
      my_real, DIMENSION(MVSIZ), INTENT(IN) :: DIV0
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   det(mvsiz),fac,base
C-----------------------------------------------
C---- this sub_routine has been called 2 times, one for Ismstr=10,12 another for 11
      IF (ismstr==11.AND.i_sh>0) THEN
       DO i=1,nel
       dxy(i) =pxy1(i)*vx1(i)+pxy2(i)*vx2(i)
     +        +pxy3(i)*vx3(i)+pxy4(i)*vx4(i)
     +        +pxy5(i)*vx5(i)+pxy6(i)*vx6(i)
     +        +pxy7(i)*vx7(i)+pxy8(i)*vx8(i)
       dxz(i) =pxz1(i)*vx1(i)+pxz2(i)*vx2(i)
     +        +pxz3(i)*vx3(i)+pxz4(i)*vx4(i)
     +        +pxz5(i)*vx5(i)+pxz6(i)*vx6(i)
     +        +pxz7(i)*vx7(i)+pxz8(i)*vx8(i)
       dyx(i) =pyx1(i)*vy1(i)+pyx2(i)*vy2(i)
     +        +pyx3(i)*vy3(i)+pyx4(i)*vy4(i)
     +        +pyx5(i)*vy5(i)+pyx6(i)*vy6(i)
     +        +pyx7(i)*vy7(i)+pyx8(i)*vy8(i)
       dyz(i) =pyz1(i)*vy1(i)+pyz2(i)*vy2(i)
     +        +pyz3(i)*vy3(i)+pyz4(i)*vy4(i)
     +        +pyz5(i)*vy5(i)+pyz6(i)*vy6(i)
     +        +pyz7(i)*vy7(i)+pyz8(i)*vy8(i)
       dzx(i) =pzx1(i)*vz1(i)+pzx2(i)*vz2(i)
     +        +pzx3(i)*vz3(i)+pzx4(i)*vz4(i)
     +        +pzx5(i)*vz5(i)+pzx6(i)*vz6(i)
     +        +pzx7(i)*vz7(i)+pzx8(i)*vz8(i)
       dzy(i) =pzy1(i)*vz1(i)+pzy2(i)*vz2(i)
     +        +pzy3(i)*vz3(i)+pzy4(i)*vz4(i)
     +        +pzy5(i)*vz5(i)+pzy6(i)*vz6(i)
     +        +pzy7(i)*vz7(i)+pzy8(i)*vz8(i)
       ENDDO
      ELSE
       DO i=1,nel
         IF (ismstr==12.AND.offg(i)>one) cycle
         dxy(i) =py1(i)*vx1(i)+py2(i)*vx2(i)+py3(i)*vx3(i)+py4(i)*vx4(i)
     +          +py5(i)*vx5(i)+py6(i)*vx6(i)+py7(i)*vx7(i)+py8(i)*vx8(i)
         dxz(i) =pz1(i)*vx1(i)+pz2(i)*vx2(i)+pz3(i)*vx3(i)+pz4(i)*vx4(i)
     +          +pz5(i)*vx5(i)+pz6(i)*vx6(i)+pz7(i)*vx7(i)+pz8(i)*vx8(i)
         dyx(i) =px1(i)*vy1(i)+px2(i)*vy2(i)+px3(i)*vy3(i)+px4(i)*vy4(i)
     +          +px5(i)*vy5(i)+px6(i)*vy6(i)+px7(i)*vy7(i)+px8(i)*vy8(i)
         dyz(i) =pz1(i)*vy1(i)+pz2(i)*vy2(i)+pz3(i)*vy3(i)+pz4(i)*vy4(i)
     +          +pz5(i)*vy5(i)+pz6(i)*vy6(i)+pz7(i)*vy7(i)+pz8(i)*vy8(i)
         dzx(i) =px1(i)*vz1(i)+px2(i)*vz2(i)+px3(i)*vz3(i)+px4(i)*vz4(i)
     +          +px5(i)*vz5(i)+px6(i)*vz6(i)+px7(i)*vz7(i)+px8(i)*vz8(i)
         dzy(i) =py1(i)*vz1(i)+py2(i)*vz2(i)+py3(i)*vz3(i)+py4(i)*vz4(i)
     +          +py5(i)*vz5(i)+py6(i)*vz6(i)+py7(i)*vz7(i)+py8(i)*vz8(i)
       ENDDO
      END IF !(ISMSTR==11) THEN
C
      IF (icp==11) THEN
#include   "nofusion.inc"
       DO i=1,nel
        dxx(i) =bxx1(i)*vx1(i)+bxx2(i)*vx2(i)+bxx3(i)*vx3(i)+
     .          bxx4(i)*vx4(i)+bxx5(i)*vx5(i)+bxx6(i)*vx6(i)+
     .          bxx7(i)*vx7(i)+bxx8(i)*vx8(i)
        dyy(i) =byy1(i)*vy1(i)+byy2(i)*vy2(i)+byy3(i)*vy3(i)+
     .          byy4(i)*vy4(i)+byy5(i)*vy5(i)+byy6(i)*vy6(i)+
     .          byy7(i)*vy7(i)+byy8(i)*vy8(i)
        dzz(i) =bzz1(i)*vz1(i)+bzz2(i)*vz2(i)+bzz3(i)*vz3(i)+
     .          bzz4(i)*vz4(i)+bzz5(i)*vz5(i)+bzz6(i)*vz6(i)+
     .          bzz7(i)*vz7(i)+bzz8(i)*vz8(i)
        dyy(i) =dyy(i)+bxy1(i)*vx1(i)+bxy2(i)*vx2(i)
     +        +bxy3(i)*vx3(i)+bxy4(i)*vx4(i)
     +        +bxy5(i)*vx5(i)+bxy6(i)*vx6(i)
     +        +bxy7(i)*vx7(i)+bxy8(i)*vx8(i)
        dzz(i) =dzz(i)+bxz1(i)*vx1(i)+bxz2(i)*vx2(i)
     +        +bxz3(i)*vx3(i)+bxz4(i)*vx4(i)
     +        +bxz5(i)*vx5(i)+bxz6(i)*vx6(i)
     +        +bxz7(i)*vx7(i)+bxz8(i)*vx8(i)
        dxx(i) =dxx(i)+byx1(i)*vy1(i)+byx2(i)*vy2(i)
     +        +byx3(i)*vy3(i)+byx4(i)*vy4(i)
     +        +byx5(i)*vy5(i)+byx6(i)*vy6(i)
     +        +byx7(i)*vy7(i)+byx8(i)*vy8(i)
        dzz(i) =dzz(i)+byz1(i)*vy1(i)+byz2(i)*vy2(i)
     +        +byz3(i)*vy3(i)+byz4(i)*vy4(i)
     +        +byz5(i)*vy5(i)+byz6(i)*vy6(i)
     +        +byz7(i)*vy7(i)+byz8(i)*vy8(i)
        dxx(i) =dxx(i)+bzx1(i)*vz1(i)+bzx2(i)*vz2(i)
     +        +bzx3(i)*vz3(i)+bzx4(i)*vz4(i)
     +        +bzx5(i)*vz5(i)+bzx6(i)*vz6(i)
     +        +bzx7(i)*vz7(i)+bzx8(i)*vz8(i)
        dyy(i) =dyy(i)+bzy1(i)*vz1(i)+bzy2(i)*vz2(i)
     +        +bzy3(i)*vz3(i)+bzy4(i)*vz4(i)
     +        +bzy5(i)*vz5(i)+bzy6(i)*vz6(i)
     +        +bzy7(i)*vz7(i)+bzy8(i)*vz8(i)
       ENDDO
      ELSE
       DO i=1,nel
         IF (ismstr==12.AND.offg(i)>one) cycle
         dxx(i) =px1(i)*vx1(i)+px2(i)*vx2(i)+px3(i)*vx3(i)+px4(i)*vx4(i)
     .          +px5(i)*vx5(i)+px6(i)*vx6(i)+px7(i)*vx7(i)+px8(i)*vx8(i)
         dyy(i) =py1(i)*vy1(i)+py2(i)*vy2(i)+py3(i)*vy3(i)+py4(i)*vy4(i)
     .          +py5(i)*vy5(i)+py6(i)*vy6(i)+py7(i)*vy7(i)+py8(i)*vy8(i)
         dzz(i) =pz1(i)*vz1(i)+pz2(i)*vz2(i)+pz3(i)*vz3(i)+pz4(i)*vz4(i)
     .          +pz5(i)*vz5(i)+pz6(i)*vz6(i)+pz7(i)*vz7(i)+pz8(i)*vz8(i)
       ENDDO
      END IF !(ICP==11) THEN
C   
      IF (i_sh>1) THEN
       IF (ismstr==11) THEN
#include   "nofusion.inc"
       DO i=1,nel
        dyy(i) =dyy(i)+bxy1(i)*vx1(i)+bxy2(i)*vx2(i)
     +        +bxy3(i)*vx3(i)+bxy4(i)*vx4(i)
     +        +bxy5(i)*vx5(i)+bxy6(i)*vx6(i)
     +        +bxy7(i)*vx7(i)+bxy8(i)*vx8(i)
        dzz(i) =dzz(i)+bxz1(i)*vx1(i)+bxz2(i)*vx2(i)
     +        +bxz3(i)*vx3(i)+bxz4(i)*vx4(i)
     +        +bxz5(i)*vx5(i)+bxz6(i)*vx6(i)
     +        +bxz7(i)*vx7(i)+bxz8(i)*vx8(i)
        dxx(i) =dxx(i)+byx1(i)*vy1(i)+byx2(i)*vy2(i)
     +        +byx3(i)*vy3(i)+byx4(i)*vy4(i)
     +        +byx5(i)*vy5(i)+byx6(i)*vy6(i)
     +        +byx7(i)*vy7(i)+byx8(i)*vy8(i)
        dzz(i) =dzz(i)+byz1(i)*vy1(i)+byz2(i)*vy2(i)
     +        +byz3(i)*vy3(i)+byz4(i)*vy4(i)
     +        +byz5(i)*vy5(i)+byz6(i)*vy6(i)
     +        +byz7(i)*vy7(i)+byz8(i)*vy8(i)
        dxx(i) =dxx(i)+bzx1(i)*vz1(i)+bzx2(i)*vz2(i)
     +        +bzx3(i)*vz3(i)+bzx4(i)*vz4(i)
     +        +bzx5(i)*vz5(i)+bzx6(i)*vz6(i)
     +        +bzx7(i)*vz7(i)+bzx8(i)*vz8(i)
        dyy(i) =dyy(i)+bzy1(i)*vz1(i)+bzy2(i)*vz2(i)
     +        +bzy3(i)*vz3(i)+bzy4(i)*vz4(i)
     +        +bzy5(i)*vz5(i)+bzy6(i)*vz6(i)
     +        +bzy7(i)*vz7(i)+bzy8(i)*vz8(i)
       ENDDO
       ELSE
         DO i=1,nel
           dyy_a(i) =bxy1(i)*vx1(i)+bxy2(i)*vx2(i)
     +              +bxy3(i)*vx3(i)+bxy4(i)*vx4(i)
     +              +bxy5(i)*vx5(i)+bxy6(i)*vx6(i)
     +              +bxy7(i)*vx7(i)+bxy8(i)*vx8(i)
     +              +bzy1(i)*vz1(i)+bzy2(i)*vz2(i)
     +              +bzy3(i)*vz3(i)+bzy4(i)*vz4(i)
     +              +bzy5(i)*vz5(i)+bzy6(i)*vz6(i)
     +              +bzy7(i)*vz7(i)+bzy8(i)*vz8(i)
           dzz_a(i) =bxz1(i)*vx1(i)+bxz2(i)*vx2(i)
     +              +bxz3(i)*vx3(i)+bxz4(i)*vx4(i)
     +              +bxz5(i)*vx5(i)+bxz6(i)*vx6(i)
     +              +bxz7(i)*vx7(i)+bxz8(i)*vx8(i)
     +              +byz1(i)*vy1(i)+byz2(i)*vy2(i)
     +              +byz3(i)*vy3(i)+byz4(i)*vy4(i)
     +              +byz5(i)*vy5(i)+byz6(i)*vy6(i)
     +              +byz7(i)*vy7(i)+byz8(i)*vy8(i)
           dxx_a(i) =byx1(i)*vy1(i)+byx2(i)*vy2(i)
     +              +byx3(i)*vy3(i)+byx4(i)*vy4(i)
     +              +byx5(i)*vy5(i)+byx6(i)*vy6(i)
     +              +byx7(i)*vy7(i)+byx8(i)*vy8(i)
     +              +bzx1(i)*vz1(i)+bzx2(i)*vz2(i)
     +              +bzx3(i)*vz3(i)+bzx4(i)*vz4(i)
     +              +bzx5(i)*vz5(i)+bzx6(i)*vz6(i)
     +              +bzx7(i)*vz7(i)+bzx8(i)*vz8(i)
         ENDDO
       END IF !(ISMSTR==11) THEN
      END IF !(I_SH>1) THEN
C      
      IF (icp==1) THEN
       IF (ismstr==11) THEN
        DO i=1,nel
         fac=two_third*nu(i)
         IF (idege(i)>10.OR.min(dxx(i),dyy(i),dzz(i))<-zep85) fac=em02
         base = dxx(i)+dyy(i)+dzz(i)
         jfac(i)=fac*(div0(i)-base)
         dxx(i) = dxx(i)+jfac(i)
         dyy(i) = dyy(i)+jfac(i)
         dzz(i) = dzz(i)+jfac(i)
        ENDDO
       ELSEIF (mtn==1) THEN
         CALL jacob_j33(
     1   det,     dxx,     dxy,     dxz,
     2   dyx,     dyy,     dyz,     dzx,
     3   dzy,     dzz,     nel)
        DO i=1,nel
         fac=two_third*nu(i)
         base = det0(i)/max(em20,det(i))
         IF (min(dxx(i),dyy(i),dzz(i))<-zep85) fac=fac*fac
         jfac(i)=exp(fac*log(max(em20,base)))
        ENDDO
        DO i=1,nel
         IF(idege(i)>10.OR.(ismstr==12.AND.offg(i)>one)) cycle
         dxx(i) = jfac(i)*dxx(i)+jfac(i)-one
         dyy(i) = jfac(i)*dyy(i)+jfac(i)-one
         dzz(i) = jfac(i)*dzz(i)+jfac(i)-one
         dxy(i) = jfac(i)*dxy(i)
         dyx(i) = jfac(i)*dyx(i)
         dzx(i) = jfac(i)*dzx(i)
         dxz(i) = jfac(i)*dxz(i)
         dyz(i) = jfac(i)*dyz(i)
         dzy(i) = jfac(i)*dzy(i)
        ENDDO
       ELSE
         CALL jacob_j33(
     1   det,     dxx,     dxy,     dxz,
     2   dyx,     dyy,     dyz,     dzx,
     3   dzy,     dzz,     nel)
C-----F'=FAC*F=MF'+[1]-->MF'=FAC*MF+(FAC-ONE)*[1]
        DO i=1,nel
         fac=two_third*nu(i)
         base = det0(i)/max(em20,det(i))
         IF(ismstr==12.AND.offg(i)>one) base=one
         jfac(i)=exp(fac*log(max(em20,base)))
        ENDDO
        DO i=1,nel
         IF(idege(i)>10.OR.(ismstr==12.AND.offg(i)>one)) cycle
         dxx(i) = jfac(i)*dxx(i)+jfac(i)-one
         dyy(i) = jfac(i)*dyy(i)+jfac(i)-one
         dzz(i) = jfac(i)*dzz(i)+jfac(i)-one
         dxy(i) = jfac(i)*dxy(i)
         dyx(i) = jfac(i)*dyx(i)
         dzx(i) = jfac(i)*dzx(i)
         dxz(i) = jfac(i)*dxz(i)
         dyz(i) = jfac(i)*dyz(i)
         dzy(i) = jfac(i)*dzy(i)
        ENDDO
       END IF !(ISMSTR==11) THEN
      END IF !(ICP==1) THEN
C
      RETURN
      END