s8efmoy3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s8efmoy3   ../engine/source/elements/solid/solide8e/s8efmoy3.F
!||--- called by ------------------------------------------------------
!||    q4forc2    ../engine/source/elements/solid_2d/quad4/q4forc2.F
!||    s8eforc3   ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8sforc3   ../engine/source/elements/solid/solide8s/s8sforc3.F
!||====================================================================
      SUBROUTINE s8efmoy3(
     1   SIGOR,   VOL,     QVIS,    PP,
     2   EINT,    RHO,     Q,       DEFP,
     3   EPSD,    EPSDM,   SIGM,    EINTM,
     4   RHOM,    QM,      DEFPM,   VOLG,
     5   STI,     STIN,    ICP,     OFF,
     6   VOL0,    VOL0G,   G_PLA,   G_EPSD,
     7   EINTTH,  EINTTHM, IEXPAN,  NEL,
     8   CONDE,   CONDEN,  SVIS  ,NODADT_THERM,
     9   G_WPLA,  L_WPLA,  G_WPLA_FLAG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr18_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ICP,G_PLA,G_EPSD,IEXPAN,NEL
      INTEGER, INTENT(IN) :: NODADT_THERM
      my_real
     .   SIGOR(NEL,6),
     .   VOL(*),QVIS(*),PP(*),
     .   EINT(*),RHO(*),Q(*),DEFPM(*),DEFP(*),
     .   SIGM(NEL,6),EINTM(*),RHOM(*),QM(*),EPSD(*),EPSDM(*),
     .   VOLG(*),STI(*),STIN(*),OFF(*),VOL0(*),VOL0G(*),
     .   EINTTH(*),EINTTHM(*),CONDE(*),CONDEN(*)
      my_real, DIMENSION(MVSIZ,6), INTENT(INOUT) :: svis
      INTEGER, INTENT(IN) :: G_WPLA_FLAG
      my_real,DIMENSION(NEL*G_WPLA_FLAG), INTENT(INOUT) :: g_wpla
      my_real,DIMENSION(NEL*G_WPLA_FLAG), INTENT(IN) :: l_wpla
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J
C     REAL
      my_real
     .   p,fac(mvsiz),fac2(mvsiz)
C-----------------------------------------------
C   - post-traitement-valeur moyenne au sens a'=(_/  a dv ) /v
      DO i=1,nel
         fac(i) = off(i)*vol(i)/volg(i)
         fac2(i) = vol(i)/volg(i)
         sigm(i,1) = sigm(i,1) + fac(i) * sigor(i,1)
         sigm(i,2) = sigm(i,2) + fac(i) * sigor(i,2)
         sigm(i,3) = sigm(i,3) + fac(i) * sigor(i,3)
         sigm(i,4) = sigm(i,4) + fac(i) * sigor(i,4)
         sigm(i,5) = sigm(i,5) + fac(i) * sigor(i,5)
         sigm(i,6) = sigm(i,6) + fac(i) * sigor(i,6)
         rhom(i)   = rhom(i)   + fac2(i)* rho(i)
         eintm(i)  = eintm(i)  + eint(i)* vol0(i)/vol0g(i)
         IF (g_wpla_flag > 0)  g_wpla(i) = g_wpla(i) + l_wpla(i)
         qm(i)     = qm(i)     + fac(i) * q(i)
         stin(i)   = stin(i)   + sti(i)
      ENDDO
C
      IF(nodadt_therm == 1) THEN
        DO i=1,nel
          conden(i)= conden(i)+ conde(i)
        ENDDO
      ENDIF
C
      IF (iexpan > 0) THEN
        DO i=1,nel
          eintthm(i) = eintthm(i) + eintth(i)*vol0(i)/vol0g(i)
        ENDDO
      ENDIF
C
      IF (g_pla > 0) THEN
        DO i=1,nel
          defpm(i)  = defpm(i)  + fac(i) * defp(i)
        ENDDO
      ENDIF
c
      IF (g_epsd > 0) THEN
       DO i=1,nel
         epsdm(i) = epsdm(i) + fac(i) * epsd(i)
       ENDDO
      ENDIF
c
      IF (icp == 1) THEN
       DO i=1,nel
        p =zep3*(sigor(i,1)+sigor(i,2)+sigor(i,3)
     .               +svis(i,1)+svis(i,2)+svis(i,3))
        pp(i)     = pp(i)     + fac(i)* (p-qvis(i))
       ENDDO
      ENDIF
C-----------
      RETURN
      END