s8etemper.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s8etemper   ../engine/source/elements/solid/solide8e/s8etemper.F
!||--- called by ------------------------------------------------------
!||    eloff       ../engine/source/elements/eloff.F
!||====================================================================
      SUBROUTINE s8etemper(TEMP, TEMPEL, NELA, NPTR, NPTS, NPTT,
     .                     NC1, NC2, NC3, NC4, NC5, NC6, NC7, NC8 )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NELA, NPTR, NPTS, NPTT
      INTEGER NC1(*), NC2(*), NC3(*), NC4(*), NC5(*), NC6(*), NC7(*), NC8(*)
      my_real temp(*), tempel(mvsiz,*)                      
C
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J
      INTEGER IR,IS,IT,IP
C
      my_real rp,sp,tp,sm,rm,tm,ksi,eta,zeta
      my_real ni(8),a_gauss(9,9)
 
      DATA a_gauss / 
     1 0.               ,0.               ,0.               ,
     1 0.               ,0.               ,0.               ,
     1 0.               ,0.               ,0.               ,
     2 -.577350269189626,0.577350269189626,0.               ,
     2 0.               ,0.               ,0.               ,
     2 0.               ,0.               ,0.               ,
     3 -.774596669241483,0.               ,0.774596669241483,
     3 0.               ,0.               ,0.               ,
     3 0.               ,0.               ,0.               ,
     4 -.861136311594053,-.339981043584856,0.339981043584856,
     4 0.861136311594053,0.               ,0.               ,
     4 0.               ,0.               ,0.               ,
     5 -.906179845938664,-.538469310105683,0.               ,
     5 0.538469310105683,0.906179845938664,0.               ,
     5 0.               ,0.               ,0.               ,
     6 -.932469514203152,-.661209386466265,-.238619186083197,
     6 0.238619186083197,0.661209386466265,0.932469514203152,
     6 0.               ,0.               ,0.               ,
     7 -.949107912342759,-.741531185599394,-.405845151377397,
     7 0.               ,0.405845151377397,0.741531185599394,
     7 0.949107912342759,0.               ,0.               ,
     8 -.960289856497536,-.796666477413627,-.525532409916329,
     8 -.183434642495650,0.183434642495650,0.525532409916329,
     8 0.796666477413627,0.960289856497536,0.               ,
     9 -.968160239507626,-.836031107326636,-.613371432700590,
     9 -.324253423403809,0.               ,0.324253423403809,
     9 0.613371432700590,0.836031107326636,0.968160239507626/
C------------------------------------------------------------------------------
      DO ir=1,nptr
       DO is=1,npts
        DO it=1,nptt
           ip = ir + ( (is-1) + (it-1)*npts )*nptr
           ksi = a_gauss(ir,nptr)
           eta = a_gauss(is,npts)
           zeta= a_gauss(it,nptt)
           rp = one + ksi            
           sp = one + eta            
           tp = one + zeta           
           rm = one - ksi            
           sm = one - eta            
           tm = one - zeta
           ni(1) = one_over_8*rm*sm*tm
           ni(2) = one_over_8*rp*sm*tm
           ni(3) = one_over_8*rp*sp*tm
           ni(4) = one_over_8*rm*sp*tm
           ni(5) = one_over_8*rm*sm*tp
           ni(6) = one_over_8*rp*sm*tp
           ni(7) = one_over_8*rp*sp*tp
           ni(8) = one_over_8*rm*sp*tp
           DO i=1,nela
             tempel(i,ip)= ni(1)*temp(nc1(i)) +  ni(2)*temp(nc2(i)) +
     .                     ni(3)*temp(nc3(i)) +  ni(4)*temp(nc4(i)) +
     .                     ni(5)*temp(nc5(i)) +  ni(6)*temp(nc6(i)) +
     .                     ni(7)*temp(nc7(i)) +  ni(8)*temp(nc8(i))  
           ENDDO
        ENDDO  ! IT=1,NPTT
       ENDDO   ! IS=1,NPTS
      ENDDO    ! IR=1,NPTR
C
      RETURN
      END