s8etherm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s8etherm           ../engine/source/elements/solid/solide8e/s8etherm.F
!||--- called by ------------------------------------------------------
!||    s8cforc3           ../engine/source/elements/thickshell/solide8c/s8cforc3.F
!||    s8eforc3           ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8zforc3           ../engine/source/elements/solid/solide8z/s8zforc3.F
!||--- uses       -----------------------------------------------------
!||    matparam_def_mod   ../common_source/modules/mat_elem/matparam_def_mod.F90
!||====================================================================
      SUBROUTINE s8etherm(MAT_PARAM,
     1   VOL,     NI,
     2   NC1,     NC2,     NC3,     NC4,
     3   NC5,     NC6,     NC7,     NC8,
     4   PX1,     PX2,     PX3,     PX4,
     5   PY1,     PY2,     PY3,     PY4,
     6   PZ1,     PZ2,     PZ3,     PZ4,
     7   PX5,     PX6,     PX7,     PX8,
     8   PY5,     PY6,     PY7,     PY8,
     9   PZ5,     PZ6,     PZ7,     PZ8,
     A   DT1,     TEMPNC,  TEL,     HEAT,
     B   FPHI,    OFFG,    OFF,     PARTSAV,
     C   IPARTS,  VOL0,    NEL,     THEACCFACT)
!-----------------------------------------------
!   m o d u l e s
!-----------------------------------------------
      use matparam_def_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      my_real, INTENT(IN) :: THEACCFACT
      INTEGER IPARTS(*),
     .        NC1(MVSIZ),NC2(MVSIZ),NC3(MVSIZ),NC4(MVSIZ),
     .        NC5(MVSIZ),NC6(MVSIZ),NC7(MVSIZ),NC8(MVSIZ)
C     REAL
      my_real
     .    VOL(*), PX1(MVSIZ), PY1(MVSIZ),PZ1(MVSIZ),
     .            PX2(MVSIZ), PY2(MVSIZ),PZ2(MVSIZ),
     .            PX3(MVSIZ), PY3(MVSIZ),PZ3(MVSIZ),
     .            PX4(MVSIZ), PY4(MVSIZ),PZ4(MVSIZ),
     .            PX5(MVSIZ), PY5(MVSIZ),PZ5(MVSIZ),
     .            px6(mvsiz), py6(mvsiz),pz6(mvsiz),
     .            px7(mvsiz), py7(mvsiz),pz7(mvsiz),
     .            px8(mvsiz), py8(mvsiz),pz8(mvsiz),        
     .    ni(8),tempnc(*), fphi(mvsiz,8), heat(*),
     .    dt1, tel(*), off(*), offg(*)
      my_real partsav(npsav,*),vol0(*)
      type (matparam_struct_)   ,intent(in) :: mat_param
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, M
      my_real CA, CB, KC, PHIX, PHIY, PHIZ, RHOCP, T0
!=======================================================================
      CA    = mat_param%THERM%AS    !< thermal conductivity coefficient A for solid phase
      cb    = mat_param%THERM%BS    !< thermal conductivity coefficient B for solid phase
      rhocp = mat_param%THERM%RHOCP
      t0    = mat_param%THERM%TINI
!
      DO i=1,nel
       IF(off(i)==zero.OR.offg(i)<=zero) cycle
C 
C - flux
          phix =  tempnc(nc1(i))*px1(i) + tempnc(nc2(i))*px2(i)  +
     .            tempnc(nc3(i))*px3(i) + tempnc(nc4(i))*px4(i)  +
     .            tempnc(nc5(i))*px5(i) + tempnc(nc6(i))*px6(i)  +
     .            tempnc(nc7(i))*px7(i) + tempnc(nc8(i))*px8(i)       
          
          phiy =  tempnc(nc1(i))*py1(i) + tempnc(nc2(i))*py2(i)  +
     .            tempnc(nc3(i))*py3(i) + tempnc(nc4(i))*py4(i)  +
     .            tempnc(nc5(i))*py5(i) + tempnc(nc6(i))*py6(i)  +
     .            tempnc(nc7(i))*py7(i) + tempnc(nc8(i))*py8(i)
      
          phiz =  tempnc(nc1(i))*pz1(i) + tempnc(nc2(i))*pz2(i)  +
     .            tempnc(nc3(i))*pz3(i) + tempnc(nc4(i))*pz4(i)  +
     .            tempnc(nc5(i))*pz5(i) + tempnc(nc6(i))*pz6(i)  +
     .            tempnc(nc7(i))*pz7(i) + tempnc(nc8(i))*pz8(i) 
C
        kc = (ca + cb*tel(i))*dt1*vol(i)*theaccfact          
        phix = kc*phix
        phiy = kc*phiy
        phiz = kc*phiz
C  
C nodal thermal force
C
          fphi(i,1) = fphi(i,1) +
     .          heat(i)*ni(1) - (phix*px1(i) + phiy*py1(i) + phiz*pz1(i))
          fphi(i,2) = fphi(i,2) +
     .          heat(i)*ni(2) - (phix*px2(i) + phiy*py2(i) + phiz*pz2(i))
          fphi(i,3) = fphi(i,3) +
     .          heat(i)*ni(3) - (phix*px3(i) + phiy*py3(i) + phiz*pz3(i))
          fphi(i,4) = fphi(i,4) +
     .          heat(i)*ni(4) - (phix*px4(i) + phiy*py4(i) + phiz*pz4(i))
          fphi(i,5) = fphi(i,5) +
     .          heat(i)*ni(5) - (phix*px5(i) + phiy*py5(i) + phiz*pz5(i))
          fphi(i,6) = fphi(i,6) +
     .          heat(i)*ni(6) - (phix*px6(i) + phiy*py6(i) + phiz*pz6(i))
          fphi(i,7) = fphi(i,7) +
     .          heat(i)*ni(7) - (phix*px7(i) + phiy*py7(i) + phiz*pz7(i))
          fphi(i,8) = fphi(i,8) +
     .          heat(i)*ni(8) - (phix*px8(i) + phiy*py8(i) + phiz*pz8(i))
      ENDDO
C
      DO i=1,nel
         IF(off(i)==zero.OR.offg(i)<=zero) cycle
         m   = iparts(i)
         partsav(28,m)=partsav(28,m) + rhocp*vol0(i)*(tel(i)-t0) + heat(i)
      ENDDO
C 
      RETURN
      END