s8jac_i.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    s8jac_i       ../engine/source/elements/solid/solide/s8jac_i.F
!||--- called by ------------------------------------------------------
!||    s8upd11t12    ../engine/source/elements/solid/solide/s8upd11t12.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../engine/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE s8jac_i(
     .              X1   ,X2   ,X3   ,X4   ,X5   ,X6   ,X7   ,X8   ,
     .              Y1   ,Y2   ,Y3   ,Y4   ,Y5   ,Y6   ,Y7   ,Y8   ,
     .              Z1   ,Z2   ,Z3   ,Z4   ,Z5   ,Z6   ,Z7   ,Z8   ,
     .              JAC_I,NEL  )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
C------------------------------------------------------
C------------------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: NEL
      my_real :: JAC_I(10,*)
      DOUBLE PRECISION
     .   X1(*), X2(*), X3(*), X4(*), X5(*), X6(*), X7(*), X8(*),
     .   y1(*), y2(*), y3(*), y4(*), y5(*), y6(*), y7(*), y8(*),
     .   z1(*), z2(*), z3(*), z4(*), z5(*), z6(*), z7(*), z8(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J     
      my_real
     .   JAC1(MVSIZ), JAC2(MVSIZ), JAC3(MVSIZ), 
     .   JAC4(MVSIZ), JAC5(MVSIZ), JAC6(MVSIZ),
     .   jac7(mvsiz), jac8(mvsiz), jac9(mvsiz)
      my_real
     .   det(mvsiz), dett(mvsiz), 
     .   x17(mvsiz), x28(mvsiz), x35(mvsiz), x46(mvsiz),
     .   y17(mvsiz), y28(mvsiz), y35(mvsiz), y46(mvsiz),
     .   z17(mvsiz), z28(mvsiz), z35(mvsiz), z46(mvsiz),
     .   jac_59_68(mvsiz), jac_67_49(mvsiz), jac_48_57(mvsiz),
     .   a17_46(mvsiz),
     .   a28_35(mvsiz),
     .   b17_46(mvsiz),
     .   b28_35(mvsiz),
     .   c17_46(mvsiz),
     .   c28_35(mvsiz)
C=======================================================================
      DO i=1,nel
        x17(i)=x7(i)-x1(i)
        x28(i)=x8(i)-x2(i)
        x35(i)=x5(i)-x3(i)
        x46(i)=x6(i)-x4(i)
C
        y17(i)=y7(i)-y1(i)
        y28(i)=y8(i)-y2(i)
        y35(i)=y5(i)-y3(i)
        y46(i)=y6(i)-y4(i)
C
        z17(i)=z7(i)-z1(i)
        z28(i)=z8(i)-z2(i)
        z35(i)=z5(i)-z3(i)
        z46(i)=z6(i)-z4(i)
      ENDDO
 
      DO i=1,nel
        jac1(i)=x17(i)+x28(i)-x35(i)-x46(i)
        jac2(i)=y17(i)+y28(i)-y35(i)-y46(i)
        jac3(i)=z17(i)+z28(i)-z35(i)-z46(i)
        a17_46(i)=x17(i)+x46(i)
        a28_35(i)=x28(i)+x35(i)
        b17_46(i)=y17(i)+y46(i)
        b28_35(i)=y28(i)+y35(i)
        c17_46(i)=z17(i)+z46(i)
        c28_35(i)=z28(i)+z35(i)
      ENDDO
         
      DO i=1,nel
        jac4(i)=a17_46(i)+a28_35(i)
        jac5(i)=b17_46(i)+b28_35(i)
        jac6(i)=c17_46(i)+c28_35(i)
        jac7(i)=a17_46(i)-a28_35(i)
        jac8(i)=b17_46(i)-b28_35(i)
        jac9(i)=c17_46(i)-c28_35(i)
      ENDDO
 
      DO i=1,nel
        jac_59_68(i)=jac5(i)*jac9(i)-jac6(i)*jac8(i)
        jac_67_49(i)=jac6(i)*jac7(i)-jac4(i)*jac9(i)
        jac_48_57(i)=jac4(i)*jac8(i)-jac5(i)*jac7(i)
      ENDDO
C
      DO i=1,nel
       det(i) =one_over_64*(jac1(i)*jac_59_68(i)+jac2(i)*jac_67_49(i)+jac3(i)*jac_48_57(i))
       dett(i)=one_over_64/max(det(i),em20)
      ENDDO     
C
C Inverse Jacobian Matrix
      DO i=1,nel
        jac_i(1,i)=dett(i)*jac_59_68(i)
        jac_i(4,i)=dett(i)*jac_67_49(i)
        jac_i(7,i)=dett(i)*jac_48_57(i)
        jac_i(2,i)=dett(i)*(-jac2(i)*jac9(i)+jac3(i)*jac8(i))
        jac_i(5,i)=dett(i)*( jac1(i)*jac9(i)-jac3(i)*jac7(i))
        jac_i(8,i)=dett(i)*(-jac1(i)*jac8(i)+jac2(i)*jac7(i))
        jac_i(3,i)=dett(i)*( jac2(i)*jac6(i)-jac3(i)*jac5(i))
        jac_i(6,i)=dett(i)*(-jac1(i)*jac6(i)+jac3(i)*jac4(i))
        jac_i(9,i)=dett(i)*( jac1(i)*jac5(i)-jac2(i)*jac4(i))
      ENDDO
C
      DO i=1,nel
        jac_i(10,i) = det(i)
      ENDDO
C
      RETURN
      END