sdlensh3n.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sdlensh3n   ../engine/source/elements/thickshell/solidec/sdlensh3n.F
!||--- called by ------------------------------------------------------
!||    s6cforc3    ../engine/source/elements/thickshell/solide6c/s6cforc3.F
!||====================================================================
      SUBROUTINE sdlensh3n(
     1   VOLN,    LLSH3N,  AREA, X1,      X2,
     2   X3,      X4,      X5,      X6,
     3   Y1,      Y2,      Y3,      Y4,
     4   Y5,      Y6,      Z1,      Z2,
     5   Z3,      Z4,      Z5,      Z6,
     6   NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      my_real, DIMENSION(MVSIZ) , INTENT(OUT)  :: AREA 
      my_real
     .   VOLN(*),LLSH3N(*),
     .   X1(*), X2(*), X3(*), X4(*), X5(*), X6(*),
     .   Y1(*), Y2(*), Y3(*), Y4(*), Y5(*), Y6(*),  
     .   z1(*), z2(*), z3(*), z4(*), z5(*), z6(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, N
      my_real
     .        E1X(MVSIZ), E1Y(MVSIZ), E1Z(MVSIZ),
     .        E2X(MVSIZ), E2Y(MVSIZ), E2Z(MVSIZ),
     .        E3X(MVSIZ), E3Y(MVSIZ), E3Z(MVSIZ),
     .        X31(MVSIZ), Y31(MVSIZ), Z31(MVSIZ),
     .        x32(mvsiz), y32(mvsiz), z32(mvsiz),
     .        x21(mvsiz), y21(mvsiz), z21(mvsiz), 
     .        x2l(mvsiz), x3l(mvsiz), y3l(mvsiz),
     .        xn(3,mvsiz) , yn(3,mvsiz) , zn(3,mvsiz) 
      my_real
     .   al1,al2,al3,almax,sum
C=======================================================================
       DO i=1,nel
          xn(1,i) = half*(x1(i)+x4(i))
          yn(1,i) = half*(y1(i)+y4(i))
          zn(1,i) = half*(z1(i)+z4(i))
          xn(2,i) = half*(x2(i)+x5(i))
          yn(2,i) = half*(y2(i)+y5(i))
          zn(2,i) = half*(z2(i)+z5(i))
          xn(3,i) = half*(x3(i)+x6(i))
          yn(3,i) = half*(y3(i)+y6(i))
          zn(3,i) = half*(z3(i)+z6(i))
       ENDDO 
      DO i=1,nel
        x21(i)=xn(2,i)-xn(1,i)
        y21(i)=yn(2,i)-yn(1,i)
        z21(i)=zn(2,i)-zn(1,i)
        x31(i)=xn(3,i)-xn(1,i)
        y31(i)=yn(3,i)-yn(1,i)
        z31(i)=zn(3,i)-zn(1,i)
        x32(i)=xn(3,i)-xn(2,i)
        y32(i)=yn(3,i)-yn(2,i)
        z32(i)=zn(3,i)-zn(2,i)
      ENDDO
C
      DO i=1,nel
        e1x(i)= x21(i)
        e1y(i)= y21(i)
        e1z(i)= z21(i)
        x2l(i) = sqrt(e1x(i)*e1x(i)+e1y(i)*e1y(i)+e1z(i)*e1z(i))
        e1x(i)=e1x(i)/x2l(i)
        e1y(i)=e1y(i)/x2l(i)
        e1z(i)=e1z(i)/x2l(i)
      ENDDO
C
      DO i=1,nel
        e3x(i)=y31(i)*z32(i)-z31(i)*y32(i)
        e3y(i)=z31(i)*x32(i)-x31(i)*z32(i)
        e3z(i)=x31(i)*y32(i)-y31(i)*x32(i)
        sum = sqrt(e3x(i)*e3x(i)+e3y(i)*e3y(i)+e3z(i)*e3z(i))
        e3x(i)=e3x(i)/sum
        e3y(i)=e3y(i)/sum
        e3z(i)=e3z(i)/sum
        area(i) = half * sum
      ENDDO
C
      DO i=1,nel
        e2x(i)=e3y(i)*e1z(i)-e3z(i)*e1y(i)
        e2y(i)=e3z(i)*e1x(i)-e3x(i)*e1z(i)
        e2z(i)=e3x(i)*e1y(i)-e3y(i)*e1x(i)
        sum = sqrt(e2x(i)*e2x(i)+e2y(i)*e2y(i)+e2z(i)*e2z(i))
        e2x(i)=e2x(i)/sum
        e2y(i)=e2y(i)/sum
        e2z(i)=e2z(i)/sum
        y3l(i)=e2x(i)*x31(i)+e2y(i)*y31(i)+e2z(i)*z31(i)
        x3l(i)=e1x(i)*x31(i)+e1y(i)*y31(i)+e1z(i)*z31(i)
      ENDDO
      DO i=1,nel
        al1 = x2l(i) * x2l(i)      
        al2 = (x3l(i)-x2l(i)) * (x3l(i)-x2l(i)) + y3l(i) * y3l(i)
        al3 = x3l(i) * x3l(i) + y3l(i) * y3l(i)
        almax = max(al1,al2,al3)
        llsh3n(i)= two*area(i) / sqrt(almax)
      ENDDO
C
      RETURN
      END