sgcoor3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sgcoor3    ../engine/source/elements/solid/solide/sgcoor3.F
!||--- called by ------------------------------------------------------
!||    s4forc3    ../engine/source/elements/solid/solide4/s4forc3.F
!||    s8eforc3   ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8zforc3   ../engine/source/elements/solid/solide8z/s8zforc3.F
!||    sforc3     ../engine/source/elements/solid/solide/sforc3.F
!||    szforc3    ../engine/source/elements/solid/solidez/szforc3.F
!||====================================================================
      SUBROUTINE sgcoor3(
     1   TIME,    NPE,     X,       IXS,
     2   X0,      Y0,      Z0,      VX0,
     3   VY0,     VZ0,     SAV,     D,
     4   OFF,     OFF0,    NEL,     XDP,
     5   MTN,     ISMSTR)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr18_c.inc"
#include      "scr05_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: MTN
      INTEGER, INTENT(IN) :: ISMSTR
      INTEGER NPE,NEL
      INTEGER IXS(NIXS,*)
C     REAL
      my_real
     .  x(3,*),time,d(3,*),off(*),off0(*),
     .  vx0(mvsiz,npe),vy0(mvsiz,npe),vz0(mvsiz,npe)
      DOUBLE PRECISION 
     .   X0(MVSIZ,NPE), Y0(MVSIZ,NPE), Z0(MVSIZ,NPE),
     .  sav(nel,3*(npe-1)),xdp(3,*),xd,yd,zd
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,NPE1,N,N2,N3
      INTEGER NC(MVSIZ,NPE)
C     REAL
C-----------------------------------------------
C
      npe1=npe-1
      IF (npe==4) THEN
       DO i=1,nel
        nc(i,1)=ixs(2,i)
        nc(i,2)=ixs(4,i)
        nc(i,3)=ixs(7,i)
        nc(i,4)=ixs(6,i)
       ENDDO
      ELSE
       DO n=1,npe
        DO i=1,nel
         nc(i,n)=ixs(n+1,i)
        ENDDO
       ENDDO
      ENDIF 
C----------------------------
C     NODAL COORDINATES INITIALES    |
C----------------------------
      DO n=1,npe1
       n2 = n + npe1
       n3 = n2 + npe1
       DO i=1,nel
        x0(i,n)=sav(i,n)
        y0(i,n)=sav(i,n2)
        z0(i,n)=sav(i,n3)
       ENDDO
      ENDDO 
C--------ISMSTR == 12 diff format of SAV 
      IF (ismstr == 12.AND.idtmin(1)==3 .AND.mtn==1) THEN
         DO n=1,npe1
           n2 = 3*(n-1)+1
           DO i=1,nel
            IF (off(i) <= one ) cycle 
            x0(i,n)=sav(i,n2)
            y0(i,n)=sav(i,n2+1)
            z0(i,n)=sav(i,n2+2)
           ENDDO
         ENDDO
      END IF !(ISMSTR == 12.AND.IDTMIN(1)==3) THEN
C----------------------------
C     DISPLACEMENT     |
C----------------------------
      IF(iresp==1)THEN
       DO n=1,npe1
        DO i=1,nel
         n2 = nc(i,n)
         n3 = nc(i,npe)
         xd =xdp(1,n2)-xdp(1,n3)-x0(i,n)
         yd =xdp(2,n2)-xdp(2,n3)-y0(i,n)
         zd =xdp(3,n2)-xdp(3,n3)-z0(i,n)
         vx0(i,n) = xd
         vy0(i,n) = yd
         vz0(i,n) = zd
        ENDDO
       ENDDO 
      ELSE      
      DO n=1,npe1
       DO i=1,nel
        n2 = nc(i,n)
        n3 = nc(i,npe)
        vx0(i,n)=x(1,n2)-x(1,n3)-x0(i,n)
        vy0(i,n)=x(2,n2)-x(2,n3)-y0(i,n)
        vz0(i,n)=x(3,n2)-x(3,n3)-z0(i,n)
       ENDDO
      ENDDO 
      END IF !(IRESP==1)THEN
C      
      DO i=1,nel
       x0(i,npe)=zero
       y0(i,npe)=zero
       z0(i,npe)=zero
       vx0(i,npe)=zero
       vy0(i,npe)=zero
       vz0(i,npe)=zero
      ENDDO
C      
      IF (ismstr == 12.AND.idtmin(1)==3) THEN
        DO i=1,nel
         off0(i)=off(i)
        ENDDO
C-------law1 special two increment        
       IF (mtn/=1) THEN
         DO n=1,npe1
          DO i=1,nel
           IF (off(i) <= one ) cycle 
            vx0(i,n)=d(1,nc(i,n))-d(1,nc(i,npe)) 
            vy0(i,n)=d(2,nc(i,n))-d(2,nc(i,npe))  
            vz0(i,n)=d(3,nc(i,n))-d(3,nc(i,npe)) 
          ENDDO
         ENDDO
         DO n=1,npe1
           n2 = 3*(n-1)+1
           DO i=1,nel
            IF (off(i) <= one ) cycle 
            x0(i,n)=sav(i,n2)
            y0(i,n)=sav(i,n2+1)
            z0(i,n)=sav(i,n2+2)
           ENDDO
         ENDDO
       END IF
      END IF !(ISMSTR == 10.AND.IDTMIN(1)==3) THEN
C
      RETURN
      END