sktcons2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sktcons2       ../engine/source/elements/solid/solide8z/sktcons2.F
!||--- called by ------------------------------------------------------
!||    mmstifs        ../engine/source/elements/solid/solide8z/mmstifs.F
!||--- calls      -----------------------------------------------------
!||    sktvonm4       ../engine/source/elements/solid/solide8z/sktvonm4.F
!||--- uses       -----------------------------------------------------
!||    imp_ktan       ../engine/share/modules/impbufdef_mod.F
!||    imp_ktan_def   ../engine/share/modules/impbufdef_mod.F
!||====================================================================
      SUBROUTINE sktcons2(
     1   JFT,     JLT,     CC,      LAMDA,
     2   G,       CG,      G33,     IR,
     3   IS,      IT,      NEL,     MTN)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE imp_ktan
      USE imp_ktan_def
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "impl1_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: MTN
      INTEGER JFT, JLT  ,IR,IS,IT
C     REAL
      my_real
     .   lamda(*),g(*),cc(3,3,*),cg(3,3,*),g33(3,3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,MX,J,K,IPLAST
C     REAL
      my_real
     .   nu,sig(6,mvsiz),alpha(mvsiz),g2,tt,tv
      TYPE(l_ktbufep_)    , POINTER :: LBUF
      TYPE(mlaw_tag_)     , POINTER :: MTAG
C-----------------------------------------------
        mtag => ktbuf_str(ng_imp)%MLAW_TAG(mtn)
        lbuf => ktbuf_str(ng_imp)%KTBUFEP(ir,is,it)
        IF (mtag%L_A_KT>0) THEN
         DO i=jft,jlt
c ...... SIG contains normalized deviatoric stresses ...
          j=6*(i-1)
          sig(1,i)= lbuf%SIGE(j+1)
          sig(2,i)= lbuf%SIGE(j+2)
          sig(3,i)= lbuf%SIGE(j+3)
          sig(4,i)= lbuf%SIGE(j+4)
          sig(5,i)= lbuf%SIGE(j+5)
          sig(6,i)= lbuf%SIGE(j+6)
c .....  ALPHA(I) is the alpha constant of the radial return..
          alpha(i)= lbuf%A_KT(i)
         ENDDO
        ELSE
         DO i=jft,jlt
          alpha(i)= one
         ENDDO
        END IF !(MTAG%L_A_KT>0) THEN
        DO i=jft,jlt
         tv=lamda(i)+two_third*g(i)*(one-alpha(i))
         tt=tv+two*g(i)*alpha(i)
         cc(1,1,i)=tt
         cc(2,2,i)=tt
         cc(3,3,i)=tt
         cc(1,2,i)=tv
         cc(1,3,i)=tv
         cc(2,3,i)=tv
         cc(2,1,i)=tv
         cc(3,1,i)=tv
         cc(3,2,i)=tv
        ENDDO
         DO j = 1, 3 
         DO k = 1, 3 
          DO i=jft,jlt
           cg(j,k,i)=zero
           g33(j,k,i)=zero
          ENDDO
         ENDDO
         ENDDO
        DO i=jft,jlt
         g2 = g(i)*alpha(i)
         g33(1,1,i)=g2
         g33(2,2,i)=g2
         g33(3,3,i)=g2
        ENDDO
        CALL sktvonm4(1 ,nel ,cc  ,sig  ,cg  ,
     .                g33 ,alpha  )
C
      RETURN
      END