slapy2.f

Go to the documentation of this file.

*> \brief \b SLAPY2 returns sqrt(x2+y2).
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SLAPY2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slapy2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slapy2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slapy2.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION SLAPY2( X, Y )
*
*       .. Scalar Arguments ..
*       REAL               X, Y
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLAPY2 returns sqrt(x**2+y**2), taking care not to cause unnecessary
*> overflow and unnecessary underflow.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] X
*> \verbatim
*>          X is REAL
*> \endverbatim
*>
*> \param[in] Y
*> \verbatim
*>          Y is REAL
*>          X and Y specify the values x and y.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup OTHERauxiliary
*
*  =====================================================================
      REAL             function slapy2( x, y )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      REAL               x, y
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               zero
      parameter( zero = 0.0e0 )
      REAL               one
      parameter( one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      REAL               w, xabs, yabs, z, hugeval
      LOGICAL            x_is_nan, y_is_nan
*     ..
*     .. External Functions ..
      LOGICAL            sisnan
      EXTERNAL           sisnan
*     ..
*     .. External Subroutines ..
      REAL               slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
      x_is_nan = sisnan( x )
      y_is_nan = sisnan( y )
      IF ( x_is_nan ) slapy2 = x
      IF ( y_is_nan ) slapy2 = y
      hugeval = slamch( 'Overflow' )
*
      IF ( .NOT.( x_is_nan.OR.y_is_nan ) ) THEN
         xabs = abs( x )
         yabs = abs( y )
         w = max( xabs, yabs )
         z = min( xabs, yabs )
         IF( z.EQ.zero .OR. w.GT.hugeval ) THEN
            slapy2 = w
         ELSE
            slapy2 = w*sqrt( one+( z / w )**2 )
         END IF
      END IF
      RETURN
*
*     End of SLAPY2
*
      END