sldege.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
      
!||====================================================================
!||    sldege    ../engine/source/elements/solid/solide/sldege.F
!||--- called by ------------------------------------------------------
!||    sdlen3    ../engine/source/elements/solid/solide/sdlen3.F
!||--- calls      -----------------------------------------------------
!||    deges4v   ../engine/source/elements/solid/solide/deges4v.F
!||    idege     ../engine/source/elements/solid/solide/idege.F
!||====================================================================
      SUBROUTINE sldege(
     1   X1,      X2,      X3,      X4,
     2   X5,      X6,      X7,      X8,
     3   Y1,      Y2,      Y3,      Y4,
     4   Y5,      Y6,      Y7,      Y8,
     5   Z1,      Z2,      Z3,      Z4,
     6   Z5,      Z6,      Z7,      Z8,
     7   AREA,    AREAM,   VOLG,    NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      my_real
     .   X1(*), X2(*), X3(*), X4(*), X5(*), X6(*), X7(*), X8(*),
     .   Y1(*), Y2(*), Y3(*), Y4(*), Y5(*), Y6(*), Y7(*), Y8(*),  
     .   Z1(*), Z2(*), Z3(*), Z4(*), Z5(*), Z6(*), Z7(*), Z8(*),
     .   AREA(MVSIZ,6),AREAM(*),VOLG(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IDEG(MVSIZ),J,IDET4(MVSIZ),IT(MVSIZ)
      INTEGER :: N_INDX
      INTEGER, DIMENSION(MVSIZ) :: INDX
      my_real FAC(MVSIZ),V_G
C-----------------------------------------------
      IDEG(1:MVSIZ)=0
      do j=1,6
       DO i=1,nel
        IF(area(i,j)<em30) ideg(i)=ideg(i)+1
       ENDDO
      ENDDO
C
      n_indx = 0
      DO i=1,nel
C-------due to the fact that AREA_Max*L is far from V for Dege---
       IF(ideg(i) > 0) THEN
                aream(i) =em20
C----tetra 4  ,pyrami    
                IF (ideg(i)>=2) THEN
                 fac(i)=one_over_9
                ELSE
                 fac(i)=fourth
                END IF
                n_indx = n_indx + 1
                indx(n_indx) = i
        ENDIF
      ENDDO
      idet4(1:mvsiz) = 1
      it(1:mvsiz) = 0
      IF(n_indx>0) THEN
        CALL idege(x1,x2,x3,x4,y1,y2,y3,y4,
     .             z1,z2,z3,z4,area(1,1),aream,fac,idet4,it,indx,n_indx)
        CALL idege(x5,x6,x7,x8,y5,y6,y7,y8,
     .             z5,z6,z7,z8,area(1,2),aream,fac,idet4,it,indx,n_indx)
        CALL idege(x1,x2,x6,x5,y1,y2,y6,y5,
     .             z1,z2,z6,z5,area(1,3),aream,fac,idet4,it,indx,n_indx)
        CALL idege(x2,x3,x7,x6,y2,y3,y7,y6,
     .             z2,z3,z7,z6,area(1,4),aream,fac,idet4,it,indx,n_indx)
        CALL idege(x3,x4,x8,x7,y3,y4,y8,y7,
     .             z3,z4,z8,z7,area(1,5),aream,fac,idet4,it,indx,n_indx)
        CALL idege(x4,x1,x5,x8,y4,y1,y5,y8,
     .             z4,z1,z5,z8,area(1,6),aream,fac,idet4,it,indx,n_indx)
        
#include      "vectorize.inc"
          DO j=1,n_indx
                i = indx(j)
C--------suposse here V=0.5*A_max*L for penta  =0.333A_max*L for Pyram 
                IF (it(i) ==0  ) aream(i)=fac(i)*aream(i)
C--------add special treat for tetra4, as V is not right values
                IF (idet4(i) ==1 ) THEN
                        CALL deges4v(v_g,
     .                  x1(i), x2(i), x3(i), x4(i), x5(i), x6(i), x7(i), x8(i),
     .                  y1(i), y2(i), y3(i), y4(i), y5(i), y6(i), y7(i), y8(i),
     .                  z1(i), z2(i), z3(i), z4(i), z5(i), z6(i), z7(i), z8(i))
                          fac(i)=third*volg(i)/v_g
                        aream(i)=fac(i)*fac(i)*aream(i)
                  END IF
        ENDDO
      ENDIF
C
      RETURN
      END