smallgeo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    smallgeo3     ../engine/source/elements/solid/solide/smallgeo3.F
!||--- called by ------------------------------------------------------
!||    s10forc3      ../engine/source/elements/solid/solide10/s10forc3.F
!||    s4forc3       ../engine/source/elements/solid/solide4/s4forc3.F
!||    s8eforc3      ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8zforc3      ../engine/source/elements/solid/solide8z/s8zforc3.F
!||    sforc3        ../engine/source/elements/solid/solide/sforc3.F
!||    szforc3       ../engine/source/elements/solid/solidez/szforc3.F
!||--- calls      -----------------------------------------------------
!||    ancmsg        ../engine/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    dt_mod        ../engine/source/modules/dt_mod.F
!||    message_mod   ../engine/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE smallgeo3(
     1   NGL,     OFFG,    VOLG,    DELTAX,
     2   VOLG0,   ITET,    NEL,     ISMSTR,DT  )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE dt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "mvsiz_p.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: ISMSTR
      INTEGER ITET,NGL(*)
      my_real
     .   offg(*),volg(*),deltax(*), volg0(*)
      TYPE(dt_), INTENT(INOUT) :: DT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,ICOUNT,LIST(MVSIZ)
      my_real
     .   tet_colla(mvsiz),coef,def_v,al,min_aspect,min_defv
C---------------------------------------------
      min_aspect = dt%BRICK_CST_COL_MIN
      min_defv = dt%BRICK_CST_DEFV_MIN
C-
      IF(min_aspect==zero.AND.min_defv==zero) RETURN
      IF(ismstr/=2.AND.ismstr/=12) RETURN
      coef = one
      IF (itet >0) coef = one/1.24/sqr3
C
      IF (min_defv >zero) THEN
       DO i=1,nel
        IF (offg(i)>one.OR.offg(i)==zero) cycle
        def_v = volg(i)/volg0(i)
        IF (def_v < min_defv) THEN
         offg(i) = two
#include "lockon.inc"
         CALL ancmsg(msgid=267,anmode=aninfo,
     .                    i1=ngl(i),
     .                    r1=def_v )
#include "lockoff.inc"
        END IF
       END DO
      END IF !(MIN_DEFV)>ZERO) THEN
C      
      IF (min_aspect>zero) THEN
       icount = 0
       DO i=1,nel
        IF (offg(i)>one.OR.offg(i)==zero) cycle
c       AL = VOLG(I)**(1.0D0/3.0D0)!  EXP(THIRD*LOG(VOLG(I)))
c       TET_COLLA(I)= COEF* (DELTAX(I)/AL)**(3.0D0/2.0D0)!COEF*EXP(THREE_HALF*LOG(DELTAX(I)/AL))
        tet_colla(i) = coef * sqrt(deltax(i)**3 / volg(i))
        IF (tet_colla(i) < min_aspect) THEN
         offg(i) = two
         icount=icount+1
         list(icount)=i
        END IF
       END DO
       IF (icount > 0) THEN
#include "lockon.inc"
          WRITE(iout,1000)
          WRITE(istdo,1000)
        DO j=1,icount
          i=list(j)
          WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),tet_colla(i)
          WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),tet_colla(i)
        ENDDO
         WRITE(iout,*)
         WRITE(istdo,*)
#include "lockoff.inc"
       END IF !(ICOUNT > 0) THEN
      END IF !(MIN_ASPECT)>ZERO) THEN
C
      RETURN
 1000 FORMAT(/
     .    'THE FOLLOWING ELEMENTS WILL BE SWITCHED TO SMALL STRAIN DUE TO BAD ASPECT RATIO' /)
      END