sort_logical_sensors.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sort_logical_sensors   ../starter/source/tools/sensor/sort_logical_sensors.F
!||--- called by ------------------------------------------------------
!||    inisen                 ../starter/source/tools/sensor/inisen.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE sort_logical_sensors(SENSORS)
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Sort AND, OR NOT sensors with their dependencies
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C    SENSOR_TAB     Sensor Structure
C===========================================================================================
C-----------------------------------------------
C   M a c r o s 
C-----------------------------------------------
#define SENS_SENS 3
#define SENS_AND  4
#define SENS_OR   5 
#define SENS_NOT  8
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (SENSORS_),INTENT(INOUT) :: SENSORS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J
      INTEGER SENS_TYPE,SENS_COUNT,IERROR
      INTEGER DEP_LIST(2),NUM_ITEM
      INTEGER,DIMENSION(:),ALLOCATABLE :: SORTED_SENSORS
C-----------------------------------------------
      sensors%LOGICAL_SENSOR_COUNT = 0
 
      ALLOCATE(sorted_sensors(sensors%NSENSOR))
 
      DO i=1,sensors%NSENSOR
 
         SELECT CASE(sensors%SENSOR_TAB(i)%TYPE)
 
            CASE ( sens_sens )
                       dep_list(1) = sensors%SENSOR_TAB(i)%IPARAM(1)
                       dep_list(2) = sensors%SENSOR_TAB(i)%IPARAM(2)
 
                       IF(dep_list(2) == 0 )THEN               ! /SENSOR/SENS can have SENSOR2 non existent.
                           num_item = 1 
                       ELSE
                           num_item = 2 
                       ENDIF
 
                       CALL set_graph_add_set(i, dep_list,num_item)
                       sensors%LOGICAL_SENSOR_COUNT = sensors%LOGICAL_SENSOR_COUNT +1
                       ! print*,I,'-- SENS --',SENSOR_TAB(I)%IPARAM(1),SENSOR_TAB(I)%IPARAM(2)
 
            CASE ( sens_and )
                       dep_list(1) = sensors%SENSOR_TAB(i)%IPARAM(1)
                       dep_list(2) = sensors%SENSOR_TAB(i)%IPARAM(2)
                       num_item = 2 
                       CALL set_graph_add_set(i, dep_list,num_item)
                       sensors%LOGICAL_SENSOR_COUNT = sensors%LOGICAL_SENSOR_COUNT +1
                       ! print*,I,'-- AND --',SENSOR_TAB(I)%IPARAM(1),SENSOR_TAB(I)%IPARAM(2)
 
            CASE ( sens_or )
                       dep_list(1) = sensors%SENSOR_TAB(i)%IPARAM(1)
                       dep_list(2) = sensors%SENSOR_TAB(i)%IPARAM(2)
                       num_item = 2 
                       CALL set_graph_add_set(i, dep_list,num_item)
                       sensors%LOGICAL_SENSOR_COUNT = sensors%LOGICAL_SENSOR_COUNT +1
                       ! print*,I,'--  OR --',SENSOR_TAB(I)%IPARAM(1),SENSOR_TAB(I)%IPARAM(2)
 
            CASE ( sens_not )
                       dep_list(1) = sensors%SENSOR_TAB(i)%IPARAM(1)
                       num_item = 1
                       CALL set_graph_add_set(i, dep_list,num_item)
                       sensors%LOGICAL_SENSOR_COUNT = sensors%LOGICAL_SENSOR_COUNT +1
                       ! print*,I,'-- NOT --',SENSOR_TAB(I)%IPARAM(1)
 
           CASE DEFAULT
                       dep_list(1:2)=0
                       num_item = 0
                       CALL set_graph_add_set(i, dep_list,num_item)
                       ! print*,I,'OTHER'
         END SELECT     
      ENDDO
 
      CALL set_graph_sort(sorted_sensors, ierror)
      CALL set_graph_clean()
 
      ! When IERROR is negative, a Sensor has a circular dependency.
      ! IERROR is set to -ID of Sensor.
      ! -------------------------------------------------------------
      IF (ierror < 0)THEN
         CALL ancmsg(msgid=2095,anmode=aninfo,msgtype=msgerror,i1=-ierror)
      ENDIF
 
      ALLOCATE (sensors%LOGICAL_SENSORS_LIST(sensors%LOGICAL_SENSOR_COUNT))
      sens_count=0
 
 
      ! Create index table with logical sensors only
      ! ---------------------------------------------
      DO i=1,sensors%NSENSOR
        j = sorted_sensors(i)
        sens_type = sensors%SENSOR_TAB(j)%TYPE
 
        IF( sens_type == sens_sens .OR. sens_type == sens_and .OR. 
     *      sens_type == sens_or   .OR. sens_type == sens_not ) THEN
 
            sens_count = sens_count + 1
            sensors%LOGICAL_SENSORS_LIST(sens_count) = j
            ! print*,'>',LOGICAL_SENSORS_LIST(SENS_COUNT),'-',SENSOR_TAB(J)%SENS_ID
        ENDIF
      ENDDO
 
 
      DEALLOCATE(sorted_sensors)
 
      END