sorthdir17.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sorthdir17   ../engine/source/elements/solid/solide8z/sorthdir17.F
!||--- called by ------------------------------------------------------
!||    srcoork      ../engine/source/elements/solid/solide8z/srcoork.F
!||====================================================================
      SUBROUTINE sorthdir17(
     1   RX,      RY,      RZ,      SX,
     2   SY,      SZ,      TX,      TY,
     3   TZ,      E1X,     E2X,     E3X,
     4   E1Y,     E2Y,     E3Y,     E1Z,
     5   E2Z,     E3Z,     GAMA,    NEL,
     6   JCVT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: JCVT
      my_real, DIMENSION(NEL), INTENT(IN)    ::
     .   RX, RY, RZ, SX, SY, SZ, TX, TY, TZ,
     .   E1X, E1Y, E1Z, E2X, E2Y, E2Z, E3X, E3Y, E3Z
      my_real, 
     .  DIMENSION(MVSIZ,6), INTENT(INOUT) :: gama
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .  UX,UY,UZ,VX,VY,VZ,WX,WY,WZ,D1,D2,D3,GX,GY,GZ,SUMA,S2,S3
      my_real, 
     .  DIMENSION(6)  :: GAMA0
C=======================================================================
        IF (jcvt== 0) THEN
C------U,V,DW ->R,S,T orthogalized        
         DO i=1,nel                                            
          suma = one/sqrt(rx(i)**2+ry(i)**2+rz(i)**2)
          ux = rx(i)*suma
          uy = ry(i)*suma
          uz = rz(i)*suma             
          wx = uy*sz(i)-uz*sy(i)                 
          wy = uz*sx(i)-ux*sz(i)                 
          wz = ux*sy(i)-uy*sx(i)                 
          suma = one/sqrt(wx*wx + wy*wy + wz*wz)
          wx = wx*suma                 
          wy = wy*suma                 
          wz = wz*suma                 
          vx = wy*uz-wz*uy                 
          vy = wz*ux-wx*uz                 
          vz = wx*uy-wy*ux                 
          suma = one/sqrt(vx*vx + vy*vy + vz*vz)
          vx = vx*suma                 
          vy = vy*suma                 
          vz = vz*suma
C---------refind --_global ortho          
          gama0(1)= gama(i,1)*ux+gama(i,2)*vx+gama(i,3)*wx
          gama0(2)= gama(i,1)*uy+gama(i,2)*vy+gama(i,3)*wy
          gama0(3)= gama(i,1)*uz+gama(i,2)*vz+gama(i,3)*wz
C
          gama0(4)= gama(i,4)*ux+gama(i,5)*vx+gama(i,6)*wx
          gama0(5)= gama(i,4)*uy+gama(i,5)*vy+gama(i,6)*wy
          gama0(6)= gama(i,4)*uz+gama(i,5)*vz+gama(i,6)*wz
C         
          gama(i,1)=
     .      gama0(1)*e1x(i)+gama0(2)*e1y(i)+gama0(3)*e1z(i)
          gama(i,2)=
     .      gama0(1)*e2x(i)+gama0(2)*e2y(i)+gama0(3)*e2z(i)
          gama(i,3)=
     .      gama0(1)*e3x(i)+gama0(2)*e3y(i)+gama0(3)*e3z(i)
          gama(i,4)=
     .      gama0(4)*e1x(i)+gama0(5)*e1y(i)+gama0(6)*e1z(i)
          gama(i,5)=
     .      gama0(4)*e2x(i)+gama0(5)*e2y(i)+gama0(6)*e2z(i)
          gama(i,6)=
     .      gama0(4)*e3x(i)+gama0(5)*e3y(i)+gama0(6)*e3z(i)
         ENDDO                                     
C
        ELSE
          DO i=1,nel
            gama0(1)  = gama(i,1)   
            gama0(2)  = gama(i,2)   
            gama0(3)  = gama(i,3)   
            gama0(4)  = gama(i,4)   
            gama0(5)  = gama(i,5)   
            gama0(6)  = gama(i,6)   
!                                       
            gama(i,1) = gama0(3)                             
            gama(i,2) = gama0(1)                             
            gama(i,3) = gama0(2)
            gama(i,4) = gama0(6)                             
            gama(i,5) = gama0(4)                           
            gama(i,6) = gama0(5)
          ENDDO      
        ENDIF                                      
C-------------
      RETURN
      END