sortho12.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    sortho12   ../engine/source/elements/solid/solide/sortho12.F
!||--- called by ------------------------------------------------------
!||    srcoor12   ../engine/source/elements/solid/solide/srcoor12.F
!||====================================================================
      SUBROUTINE sortho12(
     1   OFF,     RX,      RY,      RZ,
     2   SX,      SY,      SZ,      TX,
     3   TY,      TZ,      E1X,     E2X,
     4   E3X,     E1Y,     E2Y,     E3Y,
     5   E1Z,     E2Z,     E3Z,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
C     REAL
      my_real, DIMENSION(MVSIZ), INTENT(IN)  ::
     .   RX, RY, RZ, SX, SY, SZ, TX, TY, TZ,OFF
      my_real, DIMENSION(MVSIZ), INTENT(OUT) ::
     .   e1x, e1y, e1z, e2x, e2y, e2z, e3x, e3y, e3z
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,N,NITER
C     REAL
      my_real
     .   aa,bb
      my_real, DIMENSION(MVSIZ) ::
     .   ux, uy, uz, vx, vy, vz, wx, wy, wz
      DATA niter/3/
C=======================================================================
c     norme r s t
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 50 i=1,nel
       IF (off(i) <= one ) cycle 
      aa = sqrt(rx(i)*rx(i) + ry(i)*ry(i) + rz(i)*rz(i))
      if ( aa/=zero) aa = one / aa
      ux(i) = rx(i) * aa
      uy(i) = ry(i) * aa
      uz(i) = rz(i) * aa
      aa = sqrt(sx(i)*sx(i) + sy(i)*sy(i) + sz(i)*sz(i))
      if ( aa/=zero) aa = one / aa
      vx(i) = sx(i) * aa
      vy(i) = sy(i) * aa
      vz(i) = sz(i) * aa
      aa = sqrt(tx(i)*tx(i) + ty(i)*ty(i) + tz(i)*tz(i))
      if ( aa/=zero) aa = one / aa
      wx(i) = tx(i) * aa
      wy(i) = ty(i) * aa
      wz(i) = tz(i) * aa
 50   CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
c     iterations
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      n=0
111   CONTINUE
      n=n+1
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 100 i=1,nel
       IF (off(i) <= one ) cycle 
       e1x(i) = vy(i) * wz(i) - vz(i) * wy(i) + ux(i)
       e1y(i) = vz(i) * wx(i) - vx(i) * wz(i) + uy(i)
       e1z(i) = vx(i) * wy(i) - vy(i) * wx(i) + uz(i)
c
       e2x(i) = wy(i) * uz(i) - wz(i) * uy(i) + vx(i)
       e2y(i) = wz(i) * ux(i) - wx(i) * uz(i) + vy(i)
       e2z(i) = wx(i) * uy(i) - wy(i) * ux(i) + vz(i)
c
       e3x(i) = uy(i) * vz(i) - uz(i) * vy(i) + wx(i)
       e3y(i) = uz(i) * vx(i) - ux(i) * vz(i) + wy(i)
       e3z(i) = ux(i) * vy(i) - uy(i) * vx(i) + wz(i)
c
       bb = sqrt(e1x(i)*e1x(i) + e1y(i)*e1y(i) + e1z(i)*e1z(i))
       if ( bb/=zero) bb = one / bb
       ux(i) = e1x(i) * bb
       uy(i) = e1y(i) * bb
       uz(i) = e1z(i) * bb
c
       bb = sqrt(e2x(i)*e2x(i) + e2y(i)*e2y(i) + e2z(i)*e2z(i))
       if ( bb/=zero) bb = one / bb
       vx(i) = e2x(i) * bb
       vy(i) = e2y(i) * bb
       vz(i) = e2z(i) * bb
c
       bb = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
       if ( bb/=zero) bb = one / bb
       wx(i) = e3x(i) * bb
       wy(i) = e3y(i) * bb
       wz(i) = e3z(i) * bb
c
 100  CONTINUE
      IF (n < niter) GOTO 111
c     norme et orthogonalisation
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 200 i=1,nel
       IF (off(i) <= one ) cycle 
      e1x(i) = ux(i)
      e1y(i) = uy(i)
      e1z(i) = uz(i)
c
      e3x(i) = e1y(i) * vz(i) - e1z(i) * vy(i)
      e3y(i) = e1z(i) * vx(i) - e1x(i) * vz(i)
      e3z(i) = e1x(i) * vy(i) - e1y(i) * vx(i)
c
      aa = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
      if ( aa/=zero) aa = one / aa
      e3x(i) = e3x(i) * aa
      e3y(i) = e3y(i) * aa
      e3z(i) = e3z(i) * aa
c
      e2x(i) = e3y(i) * e1z(i) - e3z(i) * e1y(i)
      e2y(i) = e3z(i) * e1x(i) - e3x(i) * e1z(i)
      e2z(i) = e3x(i) * e1y(i) - e3y(i) * e1x(i)
 200  CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      RETURN
      END