split_asspar4.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    split_asspar4   ../engine/source/assembly/split_asspar4.F
!||--- called by ------------------------------------------------------
!||    resol           ../engine/source/engine/resol.F
!||====================================================================
        SUBROUTINE split_asspar4(ADDCNE,NUMNOD,NTHREADS,FIRST,LAST,SADSKY)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
 
!       -----------------------------------------------
!       Global arguments
        INTEGER, INTENT(IN) :: SADSKY,NUMNOD,NTHREADS
        INTEGER, DIMENSION(*), INTENT(IN) :: ADDCNE
        INTEGER, DIMENSION(NTHREADS) :: FIRST,LAST
 
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
!       SADSKY : integer ; dimension of ADDCNE
!       NUMNOD : integer ; Number of node
!       NTHREADS : integer ; number of OpenMP threads
!       ADDCNE : integer ; dimension=NUMNOD+2 (0:NUMNOD+1)
!               address for assembling 
!       FIRST : integer ; dimension=NTHREADS 
!               address of the first node for each thread
!       LAST : integer ; dimension=NTHREADS 
!               address of the last node for each thread
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
!       -----------------------------------------------
        INTEGER :: NC,SUM_NC,ITHREAD,N
        INTEGER, DIMENSION(NTHREADS) :: SUM_NC_THREAD
        my_real :: mean_nc
!       -----------------------------------------------
 
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
!$COMMENT
!       SPLIT_ASSPAR4 description
!       initialization of the bounds for each thread
!       a fixed split (ie. use NUMNOD/NTHREADS bounds 
!       does not guarantee a optimized split in asspar4) 
!       
!       SPLIT_ASSPAR4 organization :
!       - compute the total number of contribution
!       - compute FIRST and LAST bounds according to 
!         the number of contribution
!$ENDCOMMENT
 
        !       FIRST and LAST initializations
        DO ithread=1,nthreads
                first(ithread)= 1+(ithread-1)*numnod/nthreads
                last(ithread)= ithread*numnod/nthreads
        ENDDO 
 
        IF(sadsky>0) THEN
 
                !       compute the total number of contribution + mean
                sum_nc = 0
                DO n = 1,numnod
                        nc = addcne(n+1)-addcne(n)
                        sum_nc = sum_nc + nc
                ENDDO
        
                mean_nc = sum_nc / nthreads
        
                sum_nc = 0
                IF(numnod>0) THEN
                        !       first case : NUMNOD>NTHREADS --> try to split according to the number of contribution
                        IF(numnod>nthreads) THEN
                                ithread = 1
                                first(ithread) = 1
                                !       ------------------------
                                DO n = 1,numnod
                                        nc = addcne(n+1)-addcne(n)
                                        sum_nc = sum_nc + nc
                                        IF(sum_nc> 0.95*mean_nc.AND.(ithread<nthreads+1) ) THEN
                                                sum_nc_thread(ithread) = sum_nc
                                                sum_nc = 0
                                                last(ithread) = n
                                                ithread = ithread + 1
                                                IF(ithread<nthreads+1) first(ithread) = n+1
                                        ENDIF
                                ENDDO  
                                !       ------------------------
                                IF(ithread<nthreads) THEN
                                        !       fail to split according to the nbr of contribution 
                                        !       --> back to a classical splitting (static splitting)
                                        DO ithread=1,nthreads
                                                first(ithread)= 1+(ithread-1)*numnod/nthreads
                                                last(ithread)= ithread*numnod/nthreads
                                        ENDDO
                                ELSE             
                                        !       splitting success : force the last bound                    
                                        ithread = nthreads
                                        last(ithread) = numnod
                                        sum_nc_thread(ithread) = sum_nc
                                ENDIF
                                !       ------------------------
                        ELSE
                                !       ------------------------
                                !       second case : NUMNOD<NTHREADS --> classical splitting (static splitting)
                                DO ithread=1,nthreads
                                        first(ithread)= 1+(ithread-1)*numnod/nthreads
                                        last(ithread)= ithread*numnod/nthreads
                                ENDDO  
                                !       ------------------------
        
                        ENDIF
                ENDIF
        ENDIF
 
        RETURN
        END SUBROUTINE split_asspar4