spmd_collectt.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
 
C
!||====================================================================
!||    spmd_collectt         ../engine/source/mpi/output/spmd_collectt.F
!||--- called by ------------------------------------------------------
!||    resol                 ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    inoutfile_mod         ../common_source/modules/inoutfile_mod.F
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_collectt(TEMP, ITAB, WEIGHT,NODGLOB,SIZP0)
      USE inoutfile_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
#include      "chara_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITAB(*),WEIGHT(*),NODGLOB(*),SIZP0
      my_real
     .        temp(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGOFF,MSGOFF0,MSGTYP,INFO,I,K,NG,N,
     .        EMPL,SDNODG(NUMNODM),FILEN
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR
      double precision
     .        aglob(2,numnodm),recglob(2,sizp0)
 
      CHARACTER FILNAM*100,CYCLENUM*7
 
      INTEGER :: LEN_TMP_NAME
      CHARACTER(len=2148) :: TMP_NAME
 
      DATA msgoff0/184/
      DATA msgoff/185/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      WRITE(cyclenum,'(I7.7)')ncycle
      filnam=rootnam(1:rootlen)//'_'//chrun//'_'//cyclenum//'.tdb'
 
      len_tmp_name = outfile_name_len + len_trim(filnam)
      tmp_name=outfile_name(1:outfile_name_len)//filnam(1:len_trim(filnam)) 
       
      OPEN(unit=idbg8,file=tmp_name(1:len_tmp_name),access='SEQUENTIAL',
     .                  form='FORMATTED',status='UNKNOWN')
 
      filen = rootlen+17
      IF (ispmd/=0) THEN
        n = 0
        DO i = 1, numnod
         IF (weight(i)==1) THEN
           n = n+1
           sdnodg(n) = nodglob(i)
           aglob(1,n) = itab(i)
           aglob(2,n) = temp(i)
         END IF
        END DO
        msgtyp=msgoff0
        CALL mpi_send(sdnodg,n,mpi_integer,
     .                it_spmd(1),msgtyp,
     .                spmd_comm_world,ierror)
        msgtyp=msgoff
        CALL mpi_send(aglob,2*n,mpi_double_precision,
     .                it_spmd(1),msgtyp,
     .                spmd_comm_world,ierror)
      ELSE
        DO i=1,numnod
          IF (weight(i)==1) THEN
            empl = nodglob(i)
            recglob(1,empl) = itab(i)
            recglob(2,empl) =  temp(i)
          ENDIF
        ENDDO
 
        DO k=2,nspmd
            msgtyp=msgoff0
            CALL mpi_recv(sdnodg,numnodm,mpi_integer,
     .                    it_spmd(k),msgtyp,
     .                    spmd_comm_world,status,ierror)
 
            CALL mpi_get_count(status,mpi_integer,n,ierror)
 
            msgtyp=msgoff
            CALL mpi_recv(aglob,2*n,mpi_double_precision,
     .                    it_spmd(k),msgtyp,
     .                    spmd_comm_world,status,ierror)
 
            DO i=1,n
              empl = sdnodg(i)
              recglob(1,empl) = aglob(1,i)
              recglob(2,empl) = aglob(2,i)
            ENDDO
 
        END DO
C
        DO i = 1, numnodg
          WRITE(idbg8,'(A,I10,I10,Z20)' )
     .   '>',ncycle,nint(recglob(1,i)),
     .    recglob(2,i)
        END DO
        WRITE (iout,1300)  filnam(1:filen)
        WRITE (istdo,1300) filnam(1:filen)
        CLOSE(unit=idbg8)
 
      END IF
C
 1300   FORMAT (4x,' DEBUG ANALYSIS FILE:',1x,a,' WRITTEN')
#endif
      RETURN
      END