spmd_exch_a_scnd.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_a_scnd      ../engine/source/mpi/elements/spmd_exch_a_scnd.F
!||--- called by ------------------------------------------------------
!||    s10cndamp             ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cndf1              ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cndf2              ../engine/source/elements/solid/solide10/s10cndf.F
!||    s10cnidamp            ../engine/source/elements/solid/solide10/s10cndf.f
!||    s10cnistat            ../engine/source/elements/solid/solide10/s10cndf.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.f90
!||====================================================================
      SUBROUTINE spmd_exch_a_scnd(
     1            A    ,STIFN ,FR_CDNM,IAD_CDNM, LCOMM,ISIZE)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LCOMM, ISIZE, FR_CDNM(*), IAD_CDNM(*)
      my_real
     .        a(3,*),stifn(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,LOC_PROC,NOD,I,J,L,IDEB,IAD,LEN,
     .        nbindex,index,msgoff,siz,ierror,
     .        status(mpi_status_size),
     .        req_s(nspmd),req_r(nspmd),indexi(nspmd)
      DATA msgoff/1178/
      my_real
     .        sbuf(lcomm*isize),rbuf(lcomm*isize)
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
C
      ideb = 1
      l = 0
c      ISIZE = 3
      DO i = 1, nspmd
        len = iad_cdnm(i+1)-iad_cdnm(i)
        IF(len>0) THEN
          siz = len*isize 
          l=l+1
          indexi(l)=i
          msgtyp = msgoff
          CALL mpi_irecv(
     s      rbuf(ideb),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(l),ierror)
          ideb = ideb + siz
        ENDIF
      ENDDO
      nbindex = l
C
      ideb = 1
      DO l = 1, nbindex
        i = indexi(l)
        len = iad_cdnm(i+1) - iad_cdnm(i)
        iad = iad_cdnm(i)-1
        DO j = 1, len
         nod = fr_cdnm(iad+j)
         sbuf(ideb)   = a(1,nod)
         sbuf(ideb+1) = a(2,nod)
         sbuf(ideb+2) = a(3,nod)
         sbuf(ideb+3) = stifn(nod)
         ideb = ideb + isize
        ENDDO
      ENDDO
C
      ideb = 1
      DO l=1,nbindex
        i = indexi(l)
        len = iad_cdnm(i+1)-iad_cdnm(i)
        siz = len*isize
        msgtyp = msgoff
        CALL mpi_isend(
     s    sbuf(ideb),siz,real,it_spmd(i),msgtyp,
     g    spmd_comm_world,req_s(l),ierror)
        ideb = ideb + siz
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_r,index,status,ierror)
        i = indexi(index)
        ideb = 1+(iad_cdnm(i)-1)*isize
        len = iad_cdnm(i+1)-iad_cdnm(i)
        iad = iad_cdnm(i)-1
        DO j = 1, len
         nod = fr_cdnm(iad+j)
         a(1,nod)   = a(1,nod) + rbuf(ideb)
         a(2,nod)   = a(2,nod) + rbuf(ideb+1)
         a(3,nod)   = a(3,nod) + rbuf(ideb+2)
         stifn(nod) = stifn(nod) + rbuf(ideb+3)
         ideb = ideb + isize
        ENDDO
      ENDDO
C
      DO l=1,nbindex
        CALL mpi_waitany(nbindex,req_s,index,status,ierror)
      ENDDO
C
#endif
      RETURN
      END SUBROUTINE