spmd_exch_a_seatbelt.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_a_seatbelt   ../engine/source/mpi/seatbelts/spmd_exch_a_seatbelt.F
!||--- called by ------------------------------------------------------
!||    kine_seatbelt_force    ../engine/source/tools/seatbelts/kine_seatbelt_force.f
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    seatbelt_mod           ../common_source/modules/seatbelt_mod.F
!||    spmd_comm_world_mod    ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exch_a_seatbelt(A,STIFN,BUF_EXCH)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE seatbelt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real ,INTENT(IN) :: buf_exch(n_anchor_remote_send,4)
      my_real ,INTENT(INOUT) :: a(3,numnod),stifn(numnod)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR,
     .        SIZ,J,K,L,NB_NOD,
     .        STATUS(MPI_STATUS_SIZE),
     .        IAD_SEND(NSPMD+1),IAD_RECV(NSPMD+1),
     .        REQ_R(NSPMD),REQ_S(NSPMD),OFFSET  
      my_real
     .        rbuf(4*n_anchor_remote),sbuf(4*n_anchor_remote_send)  
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
C
      IF (n_anchor_remote > 0) THEN
        l = 1
        iad_recv(1) = 1      
        DO i=1,nspmd
          siz = 4*(anchor_remote%ADD_PROC(i+1)-anchor_remote%ADD_PROC(i))
          IF(siz/=0)THEN
            msgtyp = 10000 + nspmd*(i-1) + loc_proc
            CALL mpi_irecv(
     s           rbuf(l),siz,real,it_spmd(i),msgtyp,
     g           spmd_comm_world,req_r(i),ierror)
            l = l + siz
          ENDIF
          iad_recv(i+1) = l
        END DO
      ENDIF
C
      IF (n_anchor_remote_send > 0) THEN
        l = 1
        iad_send(1) = 1  
        DO i=1,nspmd
C preparation envoi  partie fixe (elem) a proc I
#include      "vectorize.inc"
          DO j=anchor_remote_send%ADD_PROC(i),anchor_remote_send%ADD_PROC(i+1)-1
            nod = anchor_remote_send%NODE(j)
            sbuf(l  ) =  buf_exch(nod,1)
            sbuf(l+1) =  buf_exch(nod,2)
            sbuf(l+2) =  buf_exch(nod,3)
            sbuf(l+3) =  buf_exch(nod,4)
            l = l + 4
          END DO
          iad_send(i+1) = l
        ENDDO
C
C   echange messages
C
        DO i=1,nspmd
C--------------------------------------------------------------------
C envoi a N+I mod P
         IF(anchor_remote_send%ADD_PROC(i+1)-anchor_remote_send%ADD_PROC(i) > 0)THEN
            msgtyp = 10000 + nspmd*(loc_proc-1) + i
            siz = iad_send(i+1)-iad_send(i)
            l = iad_send(i)
            CALL mpi_isend(
     s        sbuf(l),siz,real,it_spmd(i),msgtyp,
     g        spmd_comm_world,req_s(i),ierror)
         ENDIF
C--------------------------------------------------------------------
        ENDDO
C
      ENDIF
C
C decompactage
C
      IF (n_anchor_remote > 0) THEN
        DO i = 1, nspmd
          nb_nod = anchor_remote%ADD_PROC(i+1)-anchor_remote%ADD_PROC(i)
          IF(nb_nod>0)THEN
            CALL mpi_wait(req_r(i),status,ierror)
            l = iad_recv(i)
#include        "vectorize.inc"
            DO j=anchor_remote%ADD_PROC(i),anchor_remote%ADD_PROC(i+1)-1
              nod = anchor_remote%NODE(j)
              a(1,nod) = a(1,nod) + rbuf(l)
              a(2,nod) = a(2,nod) + rbuf(l+1)
              a(3,nod) = a(3,nod) + rbuf(l+2)
              stifn(nod) = stifn(nod) + rbuf(l+3)          
              l = l + 4
            END DO
C ---
          ENDIF
        END DO
      ENDIF
C
C   wait terminaison isend
C
      IF (n_anchor_remote_send > 0) THEN
        DO i = 1, nspmd
          IF(anchor_remote_send%ADD_PROC(i+1)-anchor_remote_send%ADD_PROC(i) > 0)THEN
            CALL mpi_wait(req_s(i),status,ierror)
          ENDIF       
        ENDDO
      ENDIF
C
#endif
      RETURN
      END