spmd_exch_i24_gap.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_exch_i24_gap     ../engine/source/mpi/interfaces/spmd_exch_i24_gap.F
!||--- called by ------------------------------------------------------
!||    i24pxfem              ../engine/source/interfaces/int24/i24pxfem.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exch_i24_gap(
     1           WA,IAD_ELEM ,FR_ELEM,SIZE  ,LENR  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IAD_ELEM(2,*),FR_ELEM(*), SIZE, LENR
      my_real
     .        wa(2,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,LOC_PROC,IERROR, MSGOFF,
     .        siz,j,k,l,nb_nod,
     .        status(mpi_status_size),
     .        iad_send(nspmd+1),iad_recv(nspmd+1),
     .        req_r(nspmd),req_s(nspmd)
      DATA msgoff/232/
 
      my_real
     .        rbuf(size*lenr ),
     .        sbuf(size*lenr )
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      loc_proc = ispmd + 1
      l = 1
      iad_recv(1) = 1
      DO i=1,nspmd
        siz = size*(iad_elem(1,i+1)-iad_elem(1,i))
        IF(siz/=0)THEN
          msgtyp = msgoff
          CALL mpi_irecv(
     s      rbuf(l),siz,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(i),ierror)
          l = l + siz
        ENDIF
        iad_recv(i+1) = l
      END DO
      l = 1
      iad_send(1) = 1
C
      DO i=1,nspmd
C preparation envoi  partie fixe (elem) a proc I
#include  "vectorize.inc"
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            nod = fr_elem(j)
            sbuf(l     ) =  wa(1,nod)
            sbuf(l + 1 ) =  wa(2,nod)
            l = l + SIZE
          END DO
C
         iad_send(i+1) = l
      ENDDO
C
C   echange messages
C
      DO i=1,nspmd
C--------------------------------------------------------------------
C envoi a N+I mod P
C   test si msg necessaire a envoyer a completer par test interface
       IF(iad_elem(1,i+1)-iad_elem(1,i)>0)THEN
          msgtyp = msgoff
          siz = iad_send(i+1)-iad_send(i)
          l = iad_send(i)
          CALL mpi_isend(
     .      sbuf(l),siz,real,it_spmd(i),msgtyp,
     .      spmd_comm_world,req_s(i),ierror)
       ENDIF
C--------------------------------------------------------------------
      ENDDO
C
C decompactage
C
      DO i = 1, nspmd
C   test si msg necessaire a envoyer a completer par test interface
        nb_nod = iad_elem(1,i+1)-iad_elem(1,i)
        IF(nb_nod>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          l = iad_recv(i)
C
#include    "vectorize.inc"
            DO j=iad_elem(1,i),iad_elem(1,i+1)-1
              nod = fr_elem(j)
              wa(1,nod) = max(wa(1,nod),rbuf(l))
              wa(2,nod) = max(wa(2,nod),rbuf(l+1))
              l = l + SIZE
            END DO
C ---
        ENDIF
      ENDDO
C
C   wait terminaison isend
C
      DO i = 1, nspmd
        IF(iad_elem(1,i+1)-iad_elem(1,i)>0)THEN
          CALL mpi_wait(req_s(i),status,ierror)
        ENDIF
      ENDDO
C
#endif
      RETURN
      END