spmd_exch_idel_seglo.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_exch_idel_seglo        ../engine/source/mpi/interfaces/spmd_exch_idel_seglo.F
!||--- calls      -----------------------------------------------------
!||    i24_remove_global_segment   ../engine/source/interfaces/interf/chkstfn3.F
!||    i25_remove_global_segment   ../engine/source/interfaces/interf/chkstfn3.F
!||--- uses       -----------------------------------------------------
!||    intbufdef_mod               ../common_source/modules/interfaces/intbufdef_mod.F90
!||    spmd_comm_world_mod         ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
        SUBROUTINE spmd_exch_idel_seglo(IPARI,INTBUF_TAB,INDSEGLO,IBUFSEGLO)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE intbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "task_c.inc"
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPARI(NPARI,*),INDSEGLO(*),IBUFSEGLO(*)
 
      TYPE(intbuf_struct_) INTBUF_TAB(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGOFF1 ,MSGOFF2, MSGTYP, LOC_PROC,IERROR,REQ_S1(NSPMD),REQ_S2(NSPMD),
     .        STATUS(MPI_STATUS_SIZE)
      INTEGER RSEGLO(NINTER+1)
C
      INTEGER NRTM,NG,IND_SEG
      INTEGER I,SIZ,IAD
      INTEGER, DIMENSION(:), ALLOCATABLE :: RBUF
C-----------------------------------------------
         DATA msgoff1/125/
         DATA msgoff2/126/
 
 
         loc_proc = ispmd+1
         DO i = 1, nspmd
           IF(i/=loc_proc) THEN
             msgtyp = msgoff1
             CALL mpi_isend(
     c         indseglo,ninter+1,mpi_integer,it_spmd(i),msgtyp,
     g         spmd_comm_world,req_s1(i),ierror) 
 
             siz = indseglo(ninter+1)-indseglo(1)
             IF(siz>0)THEN
               msgtyp = msgoff2
               CALL mpi_isend(
     c           ibufseglo,siz,mpi_integer,it_spmd(i),msgtyp,
     g           spmd_comm_world,req_s2(i),ierror) 
             ENDIF
           ENDIF
         ENDDO
      
         DO i = 1, nspmd
           IF(i/=loc_proc) THEN
             msgtyp = msgoff1
             CALL mpi_recv(
     .         rseglo,ninter+1,mpi_integer,it_spmd(i),msgtyp,
     .         spmd_comm_world,status,ierror)
             
               siz = rseglo(ninter+1)-rseglo(1)
               IF(siz>0)THEN
                 ALLOCATE(rbuf(siz))
                 msgtyp = msgoff2
                 CALL mpi_recv(
     .             rbuf,siz,mpi_integer,it_spmd(i),msgtyp,
     .             spmd_comm_world,status,ierror)
                 
                   DO ng=1,ninter
                      ind_seg=rseglo(ng+1)-rseglo(ng)
                      iad=rseglo(ng)
                      IF(ind_seg >0)THEN
                        IF(ipari(7,ng)==24)THEN
                          nrtm=ipari(4,ng)
                          CALL i24_remove_global_segment(rbuf(iad),ind_seg,ng,nrtm,
     .                                  intbuf_tab(ng)%MSEGLO,intbuf_tab(ng)%MVOISIN,2)
                        ELSEIF(ipari(7,ng)==25)THEN
                          nrtm=ipari(4,ng)
                          CALL i25_remove_global_segment(rbuf(iad),ind_seg,ng,nrtm,
     .                                 intbuf_tab(ng)%MSEGLO,intbuf_tab(ng)%MVOISIN,2)
                        END IF
                      ENDIF   ! IF(IND_SEG >0)
                   ENDDO     ! DO NG=1,NINTER
                 DEALLOCATE(rbuf)
               ENDIF       ! IF(SIZ>0)THEN
           ENDIF           ! IF(I/=LOC_PROC) THEN
         ENDDO
C
C Test reception envoi BUFR
C
      DO i = 1, nspmd
        IF(i/=loc_proc) THEN
          CALL mpi_wait(req_s1(i),status,ierror)
          siz = indseglo(ninter+1)-indseglo(1)
          IF(siz>0)THEN
              CALL mpi_wait(req_s2(i),status,ierror)
          ENDIF
        ENDIF
      ENDDO
C
      RETURN
#endif
      END