spmd_exch_tagncont.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exch_tagncont    ../engine/source/mpi/forces/spmd_exch_tagncont.F
!||--- called by ------------------------------------------------------
!||    resol                 ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                ../engine/source/output/message/message.F
!||    arret                 ../engine/source/system/arret.f
!||--- uses       -----------------------------------------------------
!||    message_mod           ../engine/share/message_module/message_mod.F
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exch_tagncont(TAGNCONT,IAD_ELEM ,FR_ELEM,LENR     )
C--------------------------------------
C--------------------------------------
      USE message_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IAD_ELEM(2,*),FR_ELEM(*), TAGNCONT(NLOADP_HYD_INTER,NUMNOD),LENR
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER MSGTYP,I,NOD,IERROR,MSGOFF,IERROR2,
     .        SIZ,J,K,L,NB_NOD,NP,
     .        STATUS(MPI_STATUS_SIZE),
     .        IAD_SEND(NSPMD+1),IAD_RECV(NSPMD+1),
     .        REQ_R(NSPMD),REQ_S(NSPMD)
      DATA msgoff/120/
      
      INTEGER, DIMENSION(:), ALLOCATABLE :: RBUF,SBUF
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
 
 
      ierror = 0
      ALLOCATE( rbuf(nloadp_hyd_inter*lenr),stat=ierror2)
      ierror = ierror + ierror2
      ALLOCATE( sbuf(nloadp_hyd_inter*lenr),stat=ierror2)
      ierror = ierror + ierror2
              
      IF(ierror/=0) THEN
         CALL ancmsg(msgid=20,anmode=aninfo)
         CALL arret(2)
      END IF   
      l = 1
      iad_recv(1) = 1
      DO i=1,nspmd
        siz = nloadp_hyd_inter*(iad_elem(1,i+1)-iad_elem(1,i))
        IF(siz/=0)THEN
          msgtyp = msgoff
          CALL mpi_irecv(
     s      rbuf(l),siz,mpi_integer,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(i),ierror)
          l = l + siz
        ENDIF
        iad_recv(i+1) = l
      END DO
C
 
 
      l = 1
      iad_send(1) = 1
      DO i=1,nspmd
         DO np=1,nloadp_hyd_inter
#include      "vectorize.inc"
            DO j=iad_elem(1,i),iad_elem(1,i+1)-1
              nod = fr_elem(j)
              sbuf(l  ) =  tagncont(np,nod)
              l = l + 1
            END DO
         ENDDO
C
        iad_send(i+1) = l
      ENDDO
C
C   sending messages
C
      DO i=1,nspmd
C--------------------------------------------------------------------
C Send to N+I mod P 
C-------------------------------------------------------------------
       IF(iad_elem(1,i+1)-iad_elem(1,i)>0)THEN
          msgtyp = msgoff 
          siz = iad_send(i+1)-iad_send(i)
          l = iad_send(i)
          CALL mpi_isend(
     s      sbuf(l),siz,mpi_integer,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_s(i),ierror)
       ENDIF
C--------------------------------------------------------------------
      ENDDO
C
C Counting
C
 
C
      DO i = 1, nspmd
C
        nb_nod = iad_elem(1,i+1)-iad_elem(1,i)
        IF(nb_nod>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          l = iad_recv(i)
 
          DO np=1,nloadp_hyd_inter
#include        "vectorize.inc"
              DO j=iad_elem(1,i),iad_elem(1,i+1)-1
                  nod = fr_elem(j)
                  tagncont(np,nod) = max(tagncont(np,nod), rbuf(l))
                  l = l + 1
               END DO
          ENDDO
 
       ENDIF
C
C
 
      END DO
C
C   wait terminaison isend
C
 
      DO i = 1, nspmd
        IF(iad_elem(1,i+1)-iad_elem(1,i)>0)THEN
          CALL mpi_wait(req_s(i),status,ierror)
        ENDIF
      ENDDO
 
      DEALLOCATE(rbuf,sbuf)
C
#endif
      RETURN
      END