spmd_exchange_grad.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_exchange_grad               ../engine/source/mpi/fluid/spmd_exchange_grad.F
!||--- called by ------------------------------------------------------
!||    ale51_gradient_reconstruction    ../engine/source/ale/alemuscl/ale51_gradient_reconstruction.F
!||    ale51_gradient_reconstruction2   ../engine/source/ale/alemuscl/ale51_gradient_reconstruction2.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod              ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_exchange_grad(DIM,DIM1,DIM2,
     1                       PHI     ,NERCVOIS,NESDVOIS,LERCVOIS,
     2                       LESDVOIS,LENCOM  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
#include "macro.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: DIM,DIM1,DIM2,LENCOM
      INTEGER, INTENT(IN) :: NERCVOIS(SNERCVOIS), NESDVOIS(SNESDVOIS)
      INTEGER, INTENT(IN) :: LERCVOIS(SLERCVOIS), LESDVOIS(SLESDVOIS)
      my_real, DIMENSION(DIM1,DIM2), INTENT(INOUT) :: phi
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER I, NDIM, IDEB, IDEB2, MSGOFF, IERROR,MSGTYP,IAD_RECV(NSPMD),
     .        STATUS(MPI_STATUS_SIZE), REQ_S(NSPMD), REQ_R(NSPMD),
     .        loc_proc, n, nn, nbirecv, irindex(nspmd), ii, index,
     .        len
      DATA msgoff/3004/
      my_real
     .     wa(dim, lencom)
C-----------------------------------------------
C
C Updating Phi on adjacent elements
C
 
      loc_proc = ispmd+1
      ideb = 0
      ideb2 = 0
      nbirecv = 0
      DO i = 1, nspmd
        msgtyp = msgoff 
        iad_recv(i) = ideb2+1
        IF(nercvois(i)>0) THEN
          nbirecv = nbirecv + 1
          irindex(nbirecv) = i
          len = nercvois(i)
          CALL mpi_irecv(
     s        wa(1,ideb2+1),len*dim,real,it_spmd(i),msgtyp,
     g        spmd_comm_world,req_r(nbirecv),ierror)
          ideb2 = ideb2 + len
        ENDIF
      ENDDO
C
      ideb = 0
      DO i = 1, nspmd
        msgtyp = msgoff 
        len = nesdvois(i)
        IF(len>0) THEN
          DO n = 1, len
            nn = lesdvois(ideb+n)
            DO ndim = 1, dim
               wa(ndim,ideb2+n) = phi(nn,ndim) ! nn,dim
            ENDDO
          ENDDO
          CALL mpi_isend(
     s      wa(1,ideb2+1),len*dim,real,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_s(i),ierror)
          ideb = ideb + len
          ideb2 = ideb2 + len
        ENDIF
      ENDDO
C
      DO ii = 1, nbirecv
        CALL mpi_waitany(nbirecv,req_r,index,status,ierror)
        i = irindex(index)
        ideb = iad_recv(i)-1
        DO n = 1, nercvois(i)
          nn = lercvois(ideb+n)
          DO ndim = 1, dim
             phi(nn,ndim) = wa(ndim,ideb+n)
          ENDDO
        ENDDO
      ENDDO
C
      DO i = 1, nspmd
        IF(nesdvois(i)>0) THEN
          CALL mpi_wait(req_s(i),status,ierror)
        ENDIF
      ENDDO
C
 
#endif
      RETURN
      END SUBROUTINE spmd_exchange_grad