spmd_flush_accel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    debug_chksm_mod   ../engine/source/mpi/output/spmd_flush_accel.F
!||--- called by ------------------------------------------------------
!||    resol             ../engine/source/engine/resol.F
!||====================================================================
      MODULE debug_chksm_mod
 
      CONTAINS
!! \brief /DEBUG/CHKSM engine option, that flushes the Adler32 checksum of the nodal accelration into to the *1.out file 
!||====================================================================
!||    spmd_flush_accel        ../engine/source/mpi/output/spmd_flush_accel.f
!||--- called by ------------------------------------------------------
!||    resol                   ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    double_array_checksum   ../engine/source/mpi/output/node_checksum.F
!||--- uses       -----------------------------------------------------
!||    checksum_mod            ../engine/source/mpi/output/node_checksum.F
!||    spmd_comm_world_mod     ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_flush_accel(NCYCLE,  ISPMD,   NSPMD, NUMNOD,
     .                          NUMNODG, NUMNODM, A,     ITAB,
     .                          WEIGHT,  NODGLOB)
C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------- 
      USE checksum_mod , ONLY : double_array_checksum
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NCYCLE !< current cycle
      INTEGER, INTENT(IN) :: ISPMD !< MPI rank
      INTEGER, INTENT(IN) :: NSPMD !< number of MPI processes
      INTEGER, INTENT(IN) :: NUMNOD !< number of nodes on the current MPI process 
      INTEGER, INTENT(IN) :: NUMNODG !< total number of nodes 
      INTEGER, INTENT(IN) :: NUMNODM !< maximum number of nodes over the MPI processes 
      INTEGER, INTENT(IN) :: ITAB(NUMNOD) !< user node id
      INTEGER, INTENT(IN) :: WEIGHT(NUMNOD) !< weight of the node (1 on the processor that assembles the forces, 0 elsewhere)
      INTEGER, INTENT(IN) :: NODGLOB(NUMNOD) !< global node id 
      my_real, INTENT(IN) :: a(3,numnod) !< nodal acceleration
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR
#endif
 
      INTEGER :: MSGOFF,MSGOFF0,MSGTYP !< MPI messages
      INTEGER :: I,K,N,NODE_GLOBAL_ID !< loop indices
      INTEGER, DIMENSION(:), ALLOCATABLE :: NODES_TO_SEND
      DOUBLE PRECISION, DIMENSION(:,:), ALLOCATABLE :: AGLOB,NODES_TO_RECV
      INTEGER :: CHECKSUM !< checksum of the nodal acceleration
      DATA msgoff0/176/
      DATA msgoff/177/
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
 
      IF(ispmd == 0) THEN
        ALLOCATE(nodes_to_recv(4,numnodg))
      ENDIF
 
      ALLOCATE(nodes_to_send(max(numnod,numnodm)))
      ALLOCATE(aglob(4,max(numnodm,numnod)))
 
      IF (ispmd/=0) THEN
#ifdef MPI
        n = 0
        DO i = 1, numnod
          IF (weight(i)==1) THEN
            n = n+1
            nodes_to_send(n) = nodglob(i)
            aglob(1,n) = itab(i)
            aglob(2,n) = a(1,i)
            aglob(3,n) = a(2,i)
            aglob(4,n) = a(3,i)
          END IF
        END DO
        msgtyp=msgoff0
        CALL mpi_send(nodes_to_send,n,mpi_integer,
     .                0,msgtyp,
     .                spmd_comm_world,ierror)
        msgtyp=msgoff
        CALL mpi_send(aglob,4*n,mpi_double_precision,
     .                0,msgtyp,
     .                spmd_comm_world,ierror)
#endif
      ELSE ! ISPMD == 0
 
        DO i=1,numnod
          IF (weight(i)==1) THEN
            node_global_id = nodglob(i)
            nodes_to_recv(1,node_global_id) = itab(i)
            nodes_to_recv(2,node_global_id) =  a(1,i)
            nodes_to_recv(3,node_global_id) =  a(2,i)
            nodes_to_recv(4,node_global_id) =  a(3,i)
          ENDIF
        ENDDO
#ifdef MPI
        DO k=2,nspmd
          msgtyp=msgoff0
          CALL mpi_recv(nodes_to_send,numnodm,mpi_integer,
     .                  k-1,msgtyp,
     .                  spmd_comm_world,status,ierror)
          CALL mpi_get_count(status,mpi_integer,n,ierror)
          msgtyp=msgoff
          CALL mpi_recv(aglob,4*n,mpi_double_precision,
     .                  k-1,msgtyp,
     .                  spmd_comm_world,status,ierror)
          DO i=1,n
            node_global_id = nodes_to_send(i)
            nodes_to_recv(1,node_global_id) = aglob(1,i)
            nodes_to_recv(2,node_global_id) = aglob(2,i)
            nodes_to_recv(3,node_global_id) = aglob(3,i)
            nodes_to_recv(4,node_global_id) = aglob(4,i)
          ENDDO
 
        END DO
#endif
        checksum = double_array_checksum(nodes_to_recv,numnodg,4)
        WRITE(iout,*) ncycle, "CHECKSUM:",checksum
 
      ENDIF
      IF(ALLOCATED(nodes_to_send))  DEALLOCATE(nodes_to_send)
      IF(ALLOCATED(aglob))   DEALLOCATE(aglob)
      IF(ALLOCATED(nodes_to_recv)) DEALLOCATE(nodes_to_recv)
      RETURN
      END
      END MODULE debug_chksm_mod