spmd_fvb_igath.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    spmd_fvb_igath   ../engine/source/mpi/airbags/spmd_fvb_igath.F
!||--- called by ------------------------------------------------------
!||    fv_up_switch     ../engine/source/airbag/fv_up_switch.F
!||    fvbag1           ../engine/source/airbag/fvbag1.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    fvbag_mod        ../engine/share/modules/fvbag_mod.F
!||====================================================================
      SUBROUTINE spmd_fvb_igath(IFV, ITABS, ITABG)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fvbag_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IFV, ITABS(*), ITABG(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER II, I, ITAG, MSGOFF, REQ(NSPMD-1), IERR,
     .        STAT(MPI_STATUS_SIZE, NSPMD-1), LEN, IADI(NSPMD-1),
     .        IAD, I1, I2, J1, J2, PMAIN, NNT, J, ITAB(NSPMD-1)
      INTEGER, DIMENSION(:), ALLOCATABLE :: IBUF
      DATA msgoff/205/
C
      IF (fvspmd(ifv)%RANK == 0) THEN
C Reception des longueurs
         ii=0
         DO i=1,fvspmd(ifv)%NSPMD - 1
            ii=ii+1
            itag=msgoff+i
            CALL mpi_irecv(itab(ii), 1, mpi_integer, i,
     .                     itag, fvspmd(ifv)%MPI_COMM, req(ii), ierr)
         ENDDO
C
         CALL mpi_waitall(fvspmd(ifv)%NSPMD-1, req, stat, ierr)
C
         len=0
         ii=0
         DO i=1,fvspmd(ifv)%NSPMD-1
            ii=ii+1
            iadi(ii)=len+1
            len=len+2*itab(ii)
         ENDDO
         ALLOCATE(ibuf(len))
C Reception des entiers
         ii=0
         DO i=1,fvspmd(ifv)%NSPMD-1
            ii=ii+1
            itag=msgoff+nspmd+i
            iad=iadi(ii)
            len=2*itab(ii)
            CALL mpi_irecv(ibuf(iad), len, mpi_integer, i,
     .                     itag, fvspmd(ifv)%MPI_COMM, req(ii), ierr)
         ENDDO
C Remplissage du tableau de sortie ITABG
         DO i=1,fvspmd(ifv)%NN_L+fvspmd(ifv)%NNI_L
            i1=fvspmd(ifv)%IBUF_L(1,i)
            i2=fvspmd(ifv)%IBUF_L(2,i)
            itabg(i1)=itabs(i2)
         ENDDO
C
         CALL mpi_waitall(fvspmd(ifv)%NSPMD-1, req, stat, ierr)
C
         ii=0
         DO i=1,fvspmd(ifv)%NSPMD - 1
            ii=ii+1
            iad=iadi(ii)
            DO j=1,itab(ii)
               j1=ibuf(iad-1+j)
               j2=ibuf(iad-1+itab(ii)+j)
               itabg(j1)=j2
            ENDDO
         ENDDO
         DEALLOCATE(ibuf)
      ELSE IF(fvspmd(ifv)%RANK > 0) THEN
         pmain=fvspmd(ifv)%PMAIN
         nnt=fvspmd(ifv)%NN_L+fvspmd(ifv)%NNI_L
         itag=msgoff+fvspmd(ifv)%RANK
         CALL mpi_isend(nnt, 1, mpi_integer, 0,
     .                  itag, fvspmd(ifv)%MPI_COMM, req(1), ierr)
C
         CALL mpi_wait(req(1), stat, ierr)
C
         len=2*nnt
         ALLOCATE(ibuf(len))
         DO i=1,nnt
            ibuf(i)=fvspmd(ifv)%IBUF_L(1,i)
            ii=fvspmd(ifv)%IBUF_L(2,i)
            ibuf(nnt+i)=itabs(ii)
         ENDDO
C
         itag=msgoff+nspmd+fvspmd(ifv)%RANK
         CALL mpi_isend(ibuf, len, mpi_integer, 0,
     .                  itag, fvspmd(ifv)%MPI_COMM, req(2), ierr)
C
         CALL mpi_wait(req(2), stat, ierr)
         DEALLOCATE(ibuf)
      ENDIF
C
#endif
      RETURN
      END