spmd_gather_dtnoda.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_gather_dtnoda                ../engine/source/mpi/generic/spmd_gather_dtnoda.F
!||--- called by ------------------------------------------------------
!||    find_dt_for_targeted_added_mass   ../engine/source/time_step/find_dt_for_targeted_added_mass.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod               ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
       SUBROUTINE spmd_gather_dtnoda(TAGN,STIFN,MS,WEIGHT,NUM,DT2_L,STF_L,MS_L)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
       my_real
     .   stifn(*),ms(*),dt2_l(*),ms_l(*),stf_l(*)
       INTEGER WEIGHT(*),NUM,TAGN(*)
C-----------------------------------------------
C   L O C A L   V A R I A B L E S
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),IERROR,MS_LOFF,ID_G
      INTEGER SIZ,MS_LTYP,I,K,NG,NREC,MS_LOFF2
 
      DATA ms_loff/7014/
       my_real, DIMENSION(:) , ALLOCATABLE :: bufsr
C
C=======================================================================
       ALLOCATE (bufsr(3*num))     
C  
       IF (ispmd/=0) THEN     
         siz = 0
         DO i=1,numnod
           IF (tagn(i) > 0) THEN
             siz = siz + 3
             bufsr(siz-2) = ms(i)/stifn(i)
             bufsr(siz-1) = stifn(i) 
             bufsr(siz  ) = ms(i)  
           END IF
         END DO 
 
C   a cause de la version simple precision, on ne peux pas metre l'entier
C   dans le buffer flottant car on n a que 2puiss 24 bits dispo ~ 16 Million
C   de noeuds au max
 
         ms_ltyp = ms_loff 
         CALL mpi_send(bufsr,siz,real,it_spmd(1),ms_ltyp,
     .     spmd_comm_world,ierror)
 
       ELSE
          id_g = 0
          DO i=1,numnod
           IF (tagn(i) > 0) THEN
              id_g = id_g + 1 
              dt2_l(id_g) = ms(i)/stifn(i) 
              stf_l(id_g) = stifn(i) 
              ms_l(id_g) = ms(i) 
            ENDIF
          ENDDO
 
          DO i=2,nspmd
C-------------
            ms_ltyp = ms_loff 
            CALL mpi_probe(it_spmd(i),ms_ltyp,
     .                    spmd_comm_world,status,ierror)
              CALL mpi_get_count(status,real,siz,ierror) 
 
C------------ Reception du buffer flottant
 
            CALL mpi_recv(bufsr,siz,real,it_spmd(i),ms_ltyp,
     .                  spmd_comm_world,status,ierror)
     
            nrec = siz
            DO k = 1,nrec,3
              id_g = id_g + 1
              dt2_l(id_g) = bufsr(k)
              stf_l(id_g) = bufsr(k+1)
              ms_l(id_g) = bufsr(k+2) 
            ENDDO
C
          ENDDO
 
       ENDIF
       DEALLOCATE(bufsr)
 
#endif
       RETURN
       END