spmd_i18kine_com_v.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_i18kine_com_v    ../engine/source/mpi/interfaces/spmd_i18kine_com_v.F
!||--- called by ------------------------------------------------------
!||    i18main_kine_2        ../engine/source/interfaces/int18/i18main_kine.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                ../engine/source/output/message/message.F
!||    arret                 ../engine/source/system/arret.F
!||--- uses       -----------------------------------------------------
!||    intbufdef_mod         ../common_source/modules/interfaces/intbufdef_mod.F90
!||    message_mod           ../engine/share/message_module/message_mod.F
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||    tri7box               ../engine/share/modules/tri7box.F
!||====================================================================
      SUBROUTINE spmd_i18kine_com_v(IPARI,INTBUF_TAB,
     *                MTF,A,ITAB)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE tri7box
      USE message_mod
      USE intbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "task_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPARI(NPARI,*),ITAB(*)
C
      my_real
     .  mtf(14,*),a(3,*)
 
      TYPE(intbuf_struct_) INTBUF_TAB(*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),
     *        req_si(nspmd),req_ri(nspmd)
      INTEGER P,LENSD,LENRV,IADS(NSPMD+1),IADR(NSPMD+1),IERROR,
     *        siz,loc_proc,msgtyp,msgoff,ideb(ninter)
      INTEGER NIN,NTY,INACTI
      INTEGER J,L,NB,NN,K,N,NOD,MODE,LEN,ALEN,ND
      my_real ,
     *   DIMENSION(:), ALLOCATABLE :: bbufs, bbufr
      DATA msgoff/153/
C-----------------------------------------------
C Sur la type 18KINE, il faut communiquer les accelerations des nds seconds
 
 
      loc_proc = ispmd+1
      iads = 0
      iadr = 0
      lensd = 0
      lenrv = 0
 
      alen=3
C Comptage des tailles de buffer  Receeption et envoi
      DO p=1,nspmd
         iadr(p)=lenrv+1
         DO nin=1,ninter
           nty=ipari(7,nin)
           inacti =ipari(22,nin)
           IF((nty==7.and.ipari(34,nin)==-2.and.inacti==7).OR.
     .       (nty==22.and.ipari(34,nin)==-2.and.inacti==7))THEN
              lensd = lensd + nsnsi(nin)%P(p)*alen
              lenrv = lenrv + nsnfi(nin)%P(p)*alen
             ENDIF
         ENDDO
      ENDDO
      iadr(nspmd+1)=lenrv+1
      IF(lensd>0)THEN
          ALLOCATE(bbufs(lensd),stat=ierror)
          IF(ierror/=0) THEN
            CALL ancmsg(msgid=20,anmode=aninfo)
            CALL arret(2)
          ENDIF
      ENDIF
 
C Preparation du recieve
      IF(lenrv>0)THEN
          ALLOCATE(bbufr(lenrv),stat=ierror)
          IF(ierror/=0) THEN
            CALL ancmsg(msgid=20,anmode=aninfo)
            CALL arret(2)
          ENDIF
      ENDIF
C Send
      l=1
      ideb=0
      DO p=1, nspmd
       iads(p)=l
       IF (p/= loc_proc) THEN
         DO nin=1,ninter
           nty   =ipari(7,nin)
           inacti =ipari(22,nin)
 
           IF((nty==7.and.ipari(34,nin)==-2.and.inacti==7).OR.
     .       (nty==22.and.ipari(34,nin)==-2.and.inacti==7))THEN
               nb = nsnsi(nin)%P(p)
C Preparation du send
               DO nn=1,nb
                 nd = nsvsi(nin)%P(ideb(nin)+nn)
                 nod=intbuf_tab(nin)%NSV(nd)
                 bbufs(l  )=mtf(1,nod)
                 bbufs(l+1)=mtf(2,nod)
                 bbufs(l+2)=mtf(3,nod)
C MTFI(4-6 ne sont pas des valeurs de cumuls,
c ils sont initialises dans les parties ou on en a besoin
c il est inutile de les communiquer
c                 BBUFS(L+3)=MTF(4,NOD)
c                 BBUFS(L+4)=MTF(5,NOD)
c                 BBUFS(L+5)=MTF(6,NOD)
                 l=l+3
               ENDDO
               ideb(nin)=ideb(nin)+nb
           ENDIF
         ENDDO
 
         siz = l-iads(p)
         IF(siz>0)THEN
              msgtyp = msgoff 
C Send
              CALL mpi_isend(
     .          bbufs(iads(p)),siz,real     ,it_spmd(p),msgtyp,
     .          spmd_comm_world,req_si(p),ierror    )
         ENDIF
       ENDIF
      ENDDO
      iads(nspmd+1)=l
C Recieve
      l=0
      ideb = 0
      DO p=1, nspmd
          l=0
          siz=iadr(p+1)-iadr(p)
          IF (siz > 0) THEN
            msgtyp = msgoff 
            CALL mpi_recv( bbufr(iadr(p)),siz,real,it_spmd(p),msgtyp,
     *                     spmd_comm_world,status,ierror )
           DO nin=1,ninter
             nty   =ipari(7,nin)
             inacti =ipari(22,nin)
 
             nb = nsnfi(nin)%P(p)
 
           IF((nty==7.and.ipari(34,nin)==-2.and.inacti==7).OR.
     .       (nty==22.and.ipari(34,nin)==-2.and.inacti==7))THEN
 
               IF (nb > 0)THEN
                 DO k=1,nb
                    mtfi_v(nin)%P(1,ideb(nin)+k)=bbufr(iadr(p)+l)
                    mtfi_v(nin)%P(2,ideb(nin)+k)=bbufr(iadr(p)+l+1)
                    mtfi_v(nin)%P(3,ideb(nin)+k)=bbufr(iadr(p)+l+2)
c                    MTFI_V(NIN)%P(4,IDEB(NIN)+K)=BBUFR(IADR(P)+L+3)
c                    MTFI_V(NIN)%P(5,IDEB(NIN)+K)=BBUFR(IADR(P)+L+4)
c                    MTFI_V(NIN)%P(6,IDEB(NIN)+K)=BBUFR(IADR(P)+L+5)
                    l=l+3
                 ENDDO
               ENDIF
             ENDIF
             ideb(nin)=ideb(nin)+nb
           ENDDO
          ENDIF
      ENDDO
C Fin du send
      DO p = 1, nspmd
          siz=iads(p+1)-iads(p)
          IF(siz>0) THEN
            CALL mpi_wait(req_si(p),status,ierror)
          ENDIF
      ENDDO
 
      IF (ALLOCATED(bbufs)) DEALLOCATE(bbufs)
      IF (ALLOCATED(bbufr)) DEALLOCATE(bbufr)
#endif
      RETURN
      END