spmd_i18kine_msf_com_poff.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_i18kine_msf_com_poff   ../engine/source/mpi/interfaces/spmd_i18kine_msf_com_poff.F
!||--- called by ------------------------------------------------------
!||    i18main_kine_1              ../engine/source/interfaces/int18/i18main_kine.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod         ../engine/source/mpi/spmd_comm_world.F90
!||    tri7box                     ../engine/share/modules/tri7box.F
!||====================================================================
      SUBROUTINE spmd_i18kine_msf_com_poff(MTF,IAD_ELEM,FR_ELEM,ITAB)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE tri7box
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "task_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IAD_ELEM(2,*),FR_ELEM(*),ITAB(*)
      my_real
     *    mtf(14,*)
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER STATUS(MPI_STATUS_SIZE),
     *        REQ_SI(NSPMD),REQ_RI(NSPMD)
      INTEGER P, LENRV, IADS(NSPMD+1), IADR(NSPMD+1), IERROR, 
     * SIZ,LOC_PROC,MSGTYP,J,L,NOD,NB,MSGOFF
      my_real ,
     *  DIMENSION(:), ALLOCATABLE :: bbufs,bbufr
      DATA msgoff/154/
C--------------------------------------------------------------------
      lenrv = (iad_elem(1,nspmd+1)-iad_elem(1,1))*9
      ALLOCATE (bbufs(lenrv),bbufr(lenrv))
      loc_proc=ispmd+1
C Preparation of recv
      iadr(1) = 1
      l=1
      DO p=1,nspmd
        iadr(p) = l
        siz = (iad_elem(1,p+1)-iad_elem(1,p))*9
        IF(siz/=0)THEN
          msgtyp = msgoff 
          CALL mpi_irecv(
     s      bbufr(l),siz,real,it_spmd(p),msgtyp,
     g      spmd_comm_world,req_ri(p),ierror)
            l = l + siz
        ENDIF
      END DO
      iadr(nspmd+1) = l
 
C   echange messages
C
      l=1
      DO p=1,nspmd
         iads(p)=l
         DO j=iad_elem(1,p),iad_elem(1,p+1)-1
            nod = fr_elem(j)
            bbufs(l  ) = mtf(1,nod)
            bbufs(l+1) = mtf(2,nod)
            bbufs(l+2) = mtf(3,nod)
            bbufs(l+3) = mtf(4,nod)
            bbufs(l+4) = mtf(5,nod)
            bbufs(l+5) = mtf(6,nod)
            bbufs(l+6) = mtf(7,nod)
            bbufs(l+7) = mtf(8,nod)
            bbufs(l+8) = mtf(9,nod)
            l = l + 9
         ENDDO
      ENDDO
      iads(nspmd+1)=l
 
       DO p=1,nspmd
       IF(iad_elem(1,p+1)-iad_elem(1,p)>0)THEN
          msgtyp = msgoff 
          siz = iads(1+p)-iads(p)
          l = iads(p)
          CALL mpi_isend(
     s      bbufs(l),siz,real,it_spmd(p),msgtyp,
     g      spmd_comm_world,req_si(p),ierror)
       ENDIF
      ENDDO
 
C--------------------------------------------------------------------
C Recv
 
      DO p = 1, nspmd
C   test if msg requires to send to complete by test interface
        nb = iad_elem(1,p+1)-iad_elem(1,p)
        IF(nb>0)THEN
          CALL mpi_wait(req_ri(p),status,ierror)
          l=iadr(p)
          DO j=iad_elem(1,p),iad_elem(1,p+1)-1
              nod = fr_elem(j)
              mtf(1,nod)=mtf(1,nod)+bbufr(l)
              mtf(2,nod)=mtf(2,nod)+bbufr(l+1)
              mtf(3,nod)=mtf(3,nod)+bbufr(l+2)
              mtf(4,nod)=mtf(4,nod)+bbufr(l+3)
              mtf(5,nod)=mtf(5,nod)+bbufr(l+4)
              mtf(6,nod)=mtf(6,nod)+bbufr(l+5)
              mtf(7,nod)=mtf(7,nod)+bbufr(l+6)
              mtf(8,nod)=mtf(8,nod)+bbufr(l+7)
              mtf(9,nod)=mtf(9,nod)+bbufr(l+8)
              l=l+9
          ENDDO
        ENDIF
      ENDDO
C End of send
      DO p = 1, nspmd
          siz=iads(p+1)-iads(p)
          IF(siz>0) THEN
            CALL mpi_wait(req_si(p),status,ierror)
          ENDIF
      ENDDO
 
#endif 
      RETURN
      END