spmd_i7curvsz.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spmd_i7curvsz         ../engine/source/mpi/interfaces/spmd_i7curvsz.F
!||--- called by ------------------------------------------------------
!||    i7mainf               ../engine/source/interfaces/int07/i7mainf.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90
!||====================================================================
      SUBROUTINE spmd_i7curvsz(NRTM  ,IRECT ,NUMNOD,IAD_ELEM,FR_ELEM,
     2                         ISDSIZ,IRCSIZ,ITAG  ,LENR    ,LENT   ,
     3                         MAXCC )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        USE spmd_comm_world_mod, ONLY : spmd_comm_world
#include      "implicit_f.inc"
C-----------------------------------------------
C   M e s s a g e   P a s s i n g
C-----------------------------------------------
#include "spmd.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NRTM,NUMNOD,LENR,LENT,MAXCC,
     .        IRECT(4,NRTM),ITAG(*),
     .        iad_elem(2,*), fr_elem(*), isdsiz(*), ircsiz(*)
C     REAL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
#ifdef MPI
      INTEGER I ,J ,N1, N2, N3, N4, IERROR, IAD, SIZ, NB,
     .        MSGTYP, LOC_PROC, MSGOFF,
     .        ibufs(lenr), ibufr(lenr),
     .        status(mpi_status_size),req_r(nspmd)
      DATA msgoff/193/
 
C-----------------------------------------------
C
      loc_proc = ispmd+1
C
      iad = 1
      DO i=1,nspmd
        ircsiz(i) = 0
        siz = iad_elem(1,i+1)-iad_elem(1,i)
        IF(siz>0)THEN
          msgtyp = msgoff
          CALL mpi_irecv(
     s      ibufr(iad),siz,mpi_integer,it_spmd(i),msgtyp,
     g      spmd_comm_world,req_r(i),ierror)
            iad = iad + siz
        ENDIF
      END DO
      DO n1=1,numnod
        itag(n1) = 0
      END DO
 
      DO i=1,nrtm
        n1 = irect(1,i)
        n2 = irect(2,i)
        n3 = irect(3,i)
        n4 = irect(4,i)
        itag(n1) = itag(n1) + 1
        itag(n2) = itag(n2) + 1
        itag(n3) = itag(n3) + 1
        itag(n4) = itag(n4) + 1
      END DO
      DO i=1,nspmd
        isdsiz(i) = 0
        siz = iad_elem(1,i+1)-iad_elem(1,i)
        IF(siz>0)THEN
          iad = 1
#include      "vectorize.inc"
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            n1 = fr_elem(j)
            isdsiz(i) = isdsiz(i) + itag(n1)
            ibufs(iad) = itag(n1)
            iad = iad + 1
          END DO
          msgtyp = msgoff
          CALL mpi_send(
     s      ibufs,siz,mpi_integer,it_spmd(i),msgtyp,
     g      spmd_comm_world,ierror)
        END IF
      END DO
C
      isdsiz(nspmd+1) = 0
      ircsiz(nspmd+1) = 0
      iad = 0
      DO i = 1, nspmd
        siz = iad_elem(1,i+1)-iad_elem(1,i)
        IF(siz>0)THEN
          CALL mpi_wait(req_r(i),status,ierror)
          DO j=iad_elem(1,i),iad_elem(1,i+1)-1
            n1 = fr_elem(j)
            iad = iad + 1
            nb = ibufr(iad)
            ircsiz(i) = ircsiz(i) + nb
            itag(n1) = itag(n1) + nb
          END DO
          isdsiz(nspmd+1) = isdsiz(nspmd+1) + isdsiz(i)
          ircsiz(nspmd+1) = ircsiz(nspmd+1) + ircsiz(i)
        END IF
      END DO
C
      lent = 0
      maxcc = 0
      DO n1=1,numnod
        lent = lent + itag(n1)
        maxcc = max(maxcc,itag(n1))
      END DO
C
#endif
      RETURN
      END